matita/matita/contribs/lambdadelta/basic_2/static/lsubc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lrsubeqc_4.ma".
  16 include "basic_2/static/aaa.ma".
  17 include "basic_2/static/gcp_cr.ma".
  18
  19 (* LOCAL ENVIRONMENT REFINEMENT FOR GENERIC REDUCIBILITY ********************)
  20
  21 inductive lsubc (RP) (G): relation lenv ≝
  22 | lsubc_atom: lsubc RP G (⋆) (⋆)
  23 | lsubc_pair: ∀I,L1,L2,V. lsubc RP G L1 L2 → lsubc RP G (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  24 | lsubc_beta: ∀L1,L2,V,W,A. ⦃G, L1, V⦄ ϵ[RP] 〚A〛 → ⦃G, L1, W⦄ ϵ[RP] 〚A〛 → ⦃G, L2⦄ ⊢ W ⁝ A →
  25               lsubc RP G L1 L2 → lsubc RP G (L1. ⓓⓝW.V) (L2.ⓛW)
  26 .
  27
  28 interpretation
  29   "local environment refinement (generic reducibility)"
  30   'LRSubEqC RP G L1 L2 = (lsubc RP G L1 L2).
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact lsubc_inv_atom1_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → L1 = ⋆ → L2 = ⋆.
  35 #RP #G #L1 #L2 * -L1 -L2
  36 [ //
  37 | #I #L1 #L2 #V #_ #H destruct
  38 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  39 ]
  40 qed-.
  41
  42 (* Basic_1: was just: csubc_gen_sort_r *)
  43 lemma lsubc_inv_atom1: ∀RP,G,L2. G ⊢ ⋆ ⫃[RP] L2 → L2 = ⋆.
  44 /2 width=5 by lsubc_inv_atom1_aux/ qed-.
  45
  46 fact lsubc_inv_pair1_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → ∀I,K1,X. L1 = K1.ⓑ{I}X →
  47                           (∃∃K2. G ⊢ K1 ⫃[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  48                           ∃∃K2,V,W,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  49                                       G ⊢ K1 ⫃[RP] K2 &
  50                                       L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  51 #RP #G #L1 #L2 * -L1 -L2
  52 [ #I #K1 #V #H destruct
  53 | #J #L1 #L2 #V #HL12 #I #K1 #W #H destruct /3 width=3 by ex2_intro, or_introl/
  54 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K1 #V #H destruct /3 width=10 by ex7_4_intro, or_intror/
  55 ]
  56 qed-.
  57
  58 (* Basic_1: was: csubc_gen_head_r *)
  59 lemma lsubc_inv_pair1: ∀RP,I,G,K1,L2,X. G ⊢ K1.ⓑ{I}X ⫃[RP] L2 →
  60                        (∃∃K2. G ⊢ K1 ⫃[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  61                        ∃∃K2,V,W,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  62                                    G ⊢ K1 ⫃[RP] K2 &
  63                                    L2 = K2.ⓛW & X = ⓝW.V & I = Abbr.
  64 /2 width=3 by lsubc_inv_pair1_aux/ qed-.
  65
  66 fact lsubc_inv_atom2_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → L2 = ⋆ → L1 = ⋆.
  67 #RP #G #L1 #L2 * -L1 -L2
  68 [ //
  69 | #I #L1 #L2 #V #_ #H destruct
  70 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  71 ]
  72 qed-.
  73
  74 (* Basic_1: was just: csubc_gen_sort_l *)
  75 lemma lsubc_inv_atom2: ∀RP,G,L1. G ⊢ L1 ⫃[RP] ⋆ → L1 = ⋆.
  76 /2 width=5 by lsubc_inv_atom2_aux/ qed-.
  77
  78 fact lsubc_inv_pair2_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → ∀I,K2,W. L2 = K2.ⓑ{I} W →
  79                           (∃∃K1. G ⊢ K1 ⫃[RP] K2 & L1 = K1. ⓑ{I} W) ∨
  80                           ∃∃K1,V,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  81                                     G ⊢ K1 ⫃[RP] K2 &
  82                                     L1 = K1.ⓓⓝW.V & I = Abst.
  83 #RP #G #L1 #L2 * -L1 -L2
  84 [ #I #K2 #W #H destruct
  85 | #J #L1 #L2 #V #HL12 #I #K2 #W #H destruct /3 width=3 by ex2_intro, or_introl/
  86 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K2 #W #H destruct /3 width=8 by ex6_3_intro, or_intror/
  87 ]
  88 qed-.
  89
  90 (* Basic_1: was just: csubc_gen_head_l *)
  91 lemma lsubc_inv_pair2: ∀RP,I,G,L1,K2,W. G ⊢ L1 ⫃[RP] K2.ⓑ{I} W →
  92                        (∃∃K1. G ⊢ K1 ⫃[RP] K2 & L1 = K1.ⓑ{I} W) ∨
  93                        ∃∃K1,V,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  94                                  G ⊢ K1 ⫃[RP] K2 &
  95                                  L1 = K1.ⓓⓝW.V & I = Abst.
  96 /2 width=3 by lsubc_inv_pair2_aux/ qed-.
  97
  98 (* Basic properties *********************************************************)
  99
 100 (* Basic_1: was just: csubc_refl *)
 101 lemma lsubc_refl: ∀RP,G,L. G ⊢ L ⫃[RP] L.
 102 #RP #G #L elim L -L /2 width=1 by lsubc_pair/
 103 qed.
 104
 105 (* Basic_1: removed theorems 3:
 106             csubc_clear_conf csubc_getl_conf csubc_csuba
 107 *)