matita/matita/contribs/lambdadelta/basic_2/static/lsubr_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops.ma".
  16 include "basic_2/static/lsubr.ma".
  17
  18 (* RESTRICTED REFINEMENT FOR LOCAL ENVIRONMENTS *****************************)
  19
  20 (* Forward lemmas with generic slicing for local environments ***************)
  21
  22 (* Basic_2A1: includes: lsubr_fwd_drop2_pair *)
  23 lemma lsubr_fwd_drops2_pair: ∀L1,L2. L1 ⫃ L2 →
  24                              ∀I,K2,W,c,f. 𝐔⦃f⦄ → ⬇*[c, f] L2 ≡ K2.ⓑ{I}W →
  25                              (∃∃K1. K1 ⫃ K2 & ⬇*[c, f] L1 ≡ K1.ⓑ{I}W) ∨
  26                              ∃∃K1,V. K1 ⫃ K2 & ⬇*[c, f] L1 ≡ K1.ⓓⓝW.V & I = Abst.
  27 #L1 #L2 #H elim H -L1 -L2
  28 [ #L #I #K2 #W #c #f #_ #H
  29   elim (drops_inv_atom1 … H) -H #H destruct
  30 | #J #L1 #L2 #V #HL12 #IHL12 #I #K2 #W #c #f #Hf #H
  31   elim (drops_inv_pair1_isuni … Hf H) -H * #g #HLK2 try #H destruct [ -IHL12 | -HL12 ]
  32   [ /4 width=4 by drops_refl, ex2_intro, or_introl/
  33   | elim (IHL12 … HLK2) -IHL12 -HLK2 /2 width=3 by isuni_inv_next/ *
  34     /4 width=4 by drops_drop, ex3_2_intro, ex2_intro, or_introl, or_intror/
  35   ]
  36 | #L1 #L2 #V1 #V2 #HL12 #IHL12 #I #K2 #W #c #f #Hf #H
  37   elim (drops_inv_pair1_isuni … Hf H) -H * #g #HLK2 try #H destruct [ -IHL12 | -HL12 ]
  38   [ /4 width=4 by drops_refl, ex3_2_intro, or_intror/
  39   | elim (IHL12 … HLK2) -IHL12 -HLK2 /2 width=3 by isuni_inv_next/ *
  40     /4 width=4 by drops_drop, ex3_2_intro, ex2_intro, or_introl, or_intror/
  41   ]
  42 ]
  43 qed-.
  44
  45 (* Basic_2A1: includes: lsubr_fwd_drop2_abbr *)
  46 lemma lsubr_fwd_drops2_abbr: ∀L1,L2. L1 ⫃ L2 →
  47                              ∀K2,V,c,f.  𝐔⦃f⦄ → ⬇*[c, f] L2 ≡ K2.ⓓV →
  48                              ∃∃K1. K1 ⫃ K2 & ⬇*[c, f] L1 ≡ K1.ⓓV.
  49 #L1 #L2 #HL12 #K2 #V #c #f #Hf #HLK2
  50 elim (lsubr_fwd_drops2_pair … HL12 … Hf HLK2) -L2 -Hf // *
  51 #K1 #W #_ #_ #H destruct
  52 qed-.