matita/matita/contribs/lambdadelta/basic_2/static/rex_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_cext2.ma".
  16 include "basic_2/relocation/drops_sex.ma".
  17 include "basic_2/static/frees_drops.ma".
  18 include "basic_2/static/rex.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition f_dedropable_sn: predicate (relation3 lenv term term) ≝
  23                             λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≘ K1 →
  24                             ∀K2,T. K1 ⪤[R, T] K2 → ∀U. ⬆*[f] T ≘ U →
  25                             ∃∃L2. L1 ⪤[R, U] L2 & ⬇*[b, f] L2 ≘ K2 & L1 ≡[f] L2.
  26
  27 definition f_dropable_sn: predicate (relation3 lenv term term) ≝
  28                           λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≘ K1 → 𝐔⦃f⦄ →
  29                           ∀L2,U. L1 ⪤[R, U] L2 → ∀T. ⬆*[f] T ≘ U →
  30                           ∃∃K2. K1 ⪤[R, T] K2 & ⬇*[b, f] L2 ≘ K2.
  31
  32 definition f_dropable_dx: predicate (relation3 lenv term term) ≝
  33                           λR. ∀L1,L2,U. L1 ⪤[R, U] L2 →
  34                           ∀b,f,K2. ⬇*[b, f] L2 ≘ K2 → 𝐔⦃f⦄ → ∀T. ⬆*[f] T ≘ U →
  35                           ∃∃K1. ⬇*[b, f] L1 ≘ K1 & K1 ⪤[R, T] K2.
  36
  37 definition f_transitive_next: relation3 … ≝ λR1,R2,R3.
  38                               ∀f,L,T. L ⊢ 𝐅*⦃T⦄ ≘ f →
  39                               ∀g,I,K,n. ⬇*[n] L ≘ K.ⓘ{I} → ↑g = ⫱*[n] f →
  40                               sex_transitive (cext2 R1) (cext2 R2) (cext2 R3) (cext2 R1) cfull g K I.
  41
  42 (* Properties with generic slicing for local environments *******************)
  43
  44 lemma rex_liftable_dedropable_sn: ∀R. (∀L. reflexive ? (R L)) →
  45                                   d_liftable2_sn … lifts R → f_dedropable_sn R.
  46 #R #H1R #H2R #b #f #L1 #K1 #HLK1 #K2 #T * #f1 #Hf1 #HK12 #U #HTU
  47 elim (frees_total L1 U) #f2 #Hf2
  48 lapply (frees_fwd_coafter … Hf2 … HLK1 … HTU … Hf1) -HTU #Hf
  49 elim (sex_liftable_co_dedropable_sn … HLK1 … HK12 … Hf) -f1 -K1
  50 /3 width=6 by cext2_d_liftable2_sn, cfull_lift_sn, ext2_refl, ex3_intro, ex2_intro/
  51 qed-.
  52
  53 lemma rex_trans_next: ∀R1,R2,R3. rex_transitive R1 R2 R3 → f_transitive_next R1 R2 R3.
  54 #R1 #R2 #R3 #HR #f #L1 #T #Hf #g #I1 #K1 #n #HLK #Hgf #I #H
  55 generalize in match HLK; -HLK elim H -I1 -I
  56 [ #I #_ #L2 #_ #I2 #H
  57   lapply (ext2_inv_unit_sn … H) -H #H destruct
  58   /2 width=1 by ext2_unit/
  59 | #I #V1 #V #HV1 #HLK1 #L2 #HL12 #I2 #H
  60   elim (ext2_inv_pair_sn … H) -H #V2 #HV2 #H destruct
  61   elim (frees_inv_drops_next … Hf … HLK1 … Hgf) -f -HLK1 #f #Hf #Hfg
  62   /5 width=5 by ext2_pair, sle_sex_trans, ex2_intro/
  63 ]
  64 qed.
  65
  66 (* Inversion lemmas with generic slicing for local environments *************)
  67
  68 (* Basic_2A1: uses: llpx_sn_inv_lift_le llpx_sn_inv_lift_be llpx_sn_inv_lift_ge *)
  69 (* Basic_2A1: was: llpx_sn_drop_conf_O *)
  70 lemma rex_dropable_sn: ∀R. f_dropable_sn R.
  71 #R #b #f #L1 #K1 #HLK1 #H1f #L2 #U * #f2 #Hf2 #HL12 #T #HTU
  72 elim (frees_total K1 T) #f1 #Hf1
  73 lapply (frees_fwd_coafter … Hf2 … HLK1 … HTU … Hf1) -HTU #H2f
  74 elim (sex_co_dropable_sn … HLK1 … HL12 … H2f) -f2 -L1
  75 /3 width=3 by ex2_intro/
  76 qed-.
  77
  78 (* Basic_2A1: was: llpx_sn_drop_trans_O *)
  79 (* Note: the proof might be simplified *)
  80 lemma rex_dropable_dx: ∀R. f_dropable_dx R.
  81 #R #L1 #L2 #U * #f2 #Hf2 #HL12 #b #f #K2 #HLK2 #H1f #T #HTU
  82 elim (drops_isuni_ex … H1f L1) #K1 #HLK1
  83 elim (frees_total K1 T) #f1 #Hf1
  84 lapply (frees_fwd_coafter … Hf2 … HLK1 … HTU … Hf1) -K1 #H2f
  85 elim (sex_co_dropable_dx … HL12 … HLK2 … H2f) -L2
  86 /4 width=9 by frees_inv_lifts, ex2_intro/
  87 qed-.
  88
  89 (* Basic_2A1: uses: llpx_sn_inv_lift_O *)
  90 lemma rex_inv_lifts_bi: ∀R,L1,L2,U. L1 ⪤[R, U] L2 → ∀b,f. 𝐔⦃f⦄ →
  91                         ∀K1,K2. ⬇*[b, f] L1 ≘ K1 → ⬇*[b, f] L2 ≘ K2 →
  92                         ∀T. ⬆*[f] T ≘ U → K1 ⪤[R, T] K2.
  93 #R #L1 #L2 #U #HL12 #b #f #Hf #K1 #K2 #HLK1 #HLK2 #T #HTU
  94 elim (rex_dropable_sn … HLK1 … HL12 … HTU) -L1 -U // #Y #HK12 #HY
  95 lapply (drops_mono … HY … HLK2) -b -f -L2 #H destruct //
  96 qed-.
  97
  98 lemma rex_inv_lref_pair_sn: ∀R,L1,L2,i. L1 ⪤[R, #i] L2 → ∀I,K1,V1. ⬇*[i] L1 ≘ K1.ⓑ{I}V1 →
  99                             ∃∃K2,V2. ⬇*[i] L2 ≘ K2.ⓑ{I}V2 & K1 ⪤[R, V1] K2 & R K1 V1 V2.
 100 #R #L1 #L2 #i #HL12 #I #K1 #V1 #HLK1 elim (rex_dropable_sn … HLK1 … HL12 (#0)) -HLK1 -HL12 //
 101 #Y #HY #HLK2 elim (rex_inv_zero_pair_sn … HY) -HY
 102 #K2 #V2 #HK12 #HV12 #H destruct /2 width=5 by ex3_2_intro/
 103 qed-.
 104
 105 lemma rex_inv_lref_pair_dx: ∀R,L1,L2,i. L1 ⪤[R, #i] L2 → ∀I,K2,V2. ⬇*[i] L2 ≘ K2.ⓑ{I}V2 →
 106                             ∃∃K1,V1. ⬇*[i] L1 ≘ K1.ⓑ{I}V1 & K1 ⪤[R, V1] K2 & R K1 V1 V2.
 107 #R #L1 #L2 #i #HL12 #I #K2 #V2 #HLK2 elim (rex_dropable_dx … HL12 … HLK2 … (#0)) -HLK2 -HL12 //
 108 #Y #HLK1 #HY elim (rex_inv_zero_pair_dx … HY) -HY
 109 #K1 #V1 #HK12 #HV12 #H destruct /2 width=5 by ex3_2_intro/
 110 qed-.
 111
 112 lemma rex_inv_lref_unit_sn: ∀R,L1,L2,i. L1 ⪤[R, #i] L2 → ∀I,K1. ⬇*[i] L1 ≘ K1.ⓤ{I} →
 113                             ∃∃f,K2. ⬇*[i] L2 ≘ K2.ⓤ{I} & K1 ⪤[cext2 R, cfull, f] K2 & 𝐈⦃f⦄.
 114 #R #L1 #L2 #i #HL12 #I #K1 #HLK1 elim (rex_dropable_sn … HLK1 … HL12 (#0)) -HLK1 -HL12 //
 115 #Y #HY #HLK2 elim (rex_inv_zero_unit_sn … HY) -HY
 116 #f #K2 #Hf #HK12 #H destruct /2 width=5 by ex3_2_intro/
 117 qed-.
 118
 119 lemma rex_inv_lref_unit_dx: ∀R,L1,L2,i. L1 ⪤[R, #i] L2 → ∀I,K2. ⬇*[i] L2 ≘ K2.ⓤ{I} →
 120                             ∃∃f,K1. ⬇*[i] L1 ≘ K1.ⓤ{I} & K1 ⪤[cext2 R, cfull, f] K2 & 𝐈⦃f⦄.
 121 #R #L1 #L2 #i #HL12 #I #K2 #HLK2 elim (rex_dropable_dx … HL12 … HLK2 … (#0)) -HLK2 -HL12 //
 122 #Y #HLK1 #HY elim (rex_inv_zero_unit_dx … HY) -HY
 123 #f #K2 #Hf #HK12 #H destruct /2 width=5 by ex3_2_intro/
 124 qed-.