matita/matita/contribs/lambdadelta/basic_2/static/rex_fsle.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/sex_length.ma".
  16 include "basic_2/static/fsle_fsle.ma".
  17 include "basic_2/static/rex_drops.ma".
  18 include "basic_2/static/rex_rex.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition R_fsge_compatible: predicate (relation3 …) ≝ λRN.
  23                               ∀L,T1,T2. RN L T1 T2 → ⦃L, T2⦄ ⊆ ⦃L, T1⦄.
  24
  25 definition rex_fsge_compatible: predicate (relation3 …) ≝ λRN.
  26                                 ∀L1,L2,T. L1 ⪤[RN, T] L2 → ⦃L2, T⦄ ⊆ ⦃L1, T⦄.
  27
  28 definition rex_fsle_compatible: predicate (relation3 …) ≝ λRN.
  29                                 ∀L1,L2,T. L1 ⪤[RN, T] L2 → ⦃L1, T⦄ ⊆ ⦃L2, T⦄.
  30
  31 (* Basic inversions with free variables inclusion for restricted closures ***)
  32
  33 lemma frees_sex_conf: ∀R. rex_fsge_compatible R →
  34                       ∀L1,T,f1. L1 ⊢ 𝐅*⦃T⦄ ≘ f1 →
  35                       ∀L2. L1 ⪤[cext2 R, cfull, f1] L2 →
  36                       ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≘ f2 & f2 ⊆ f1.
  37 #R #HR #L1 #T #f1 #Hf1 #L2 #H1L
  38 lapply (HR L1 L2 T ?) /2 width=3 by ex2_intro/ #H2L
  39 @(fsle_frees_trans_eq … H2L … Hf1) /3 width=4 by sex_fwd_length, sym_eq/
  40 qed-.
  41
  42 (* Properties with free variables inclusion for restricted closures *********)
  43
  44 (* Note: we just need lveq_inv_refl: ∀L,n1,n2. L ≋ⓧ*[n1, n2] L → ∧∧ 0 = n1 & 0 = n2 *)
  45 lemma fsge_rex_trans: ∀R,L1,T1,T2. ⦃L1, T1⦄ ⊆ ⦃L1, T2⦄ →
  46                       ∀L2. L1 ⪤[R, T2] L2 → L1 ⪤[R, T1] L2.
  47 #R #L1 #T1 #T2 * #n1 #n2 #f1 #f2 #Hf1 #Hf2 #Hn #Hf #L2 #HL12
  48 elim (lveq_inj_length … Hn ?) // #H1 #H2 destruct
  49 /4 width=5 by rex_inv_frees, sle_sex_trans, ex2_intro/
  50 qed-.
  51
  52 lemma rex_sym: ∀R. rex_fsge_compatible R →
  53                (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
  54                ∀T. symmetric … (rex R T).
  55 #R #H1R #H2R #T #L1 #L2
  56 * #f1 #Hf1 #HL12
  57 elim (frees_sex_conf … Hf1 … HL12) -Hf1 //
  58 /5 width=5 by sle_sex_trans, sex_sym, cext2_sym, ex2_intro/
  59 qed-.
  60
  61 lemma rex_pair_sn_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  62                          rex_fsge_compatible R1 →
  63                          ∀L1,L2,V. L1 ⪤[R1, V] L2 → ∀I,T.
  64                          ∃∃L. L1 ⪤[R1, ②{I}V.T] L & L ⪤[R2, V] L2.
  65 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #V * #f #Hf #HL12 * [ #p ] #I #T
  66 [ elim (frees_total L1 (ⓑ{p,I}V.T)) #g #Hg
  67   elim (frees_inv_bind … Hg) #y1 #y2 #H #_ #Hy
  68 | elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  69   elim (frees_inv_flat … Hg) #y1 #y2 #H #_ #Hy
  70 ]
  71 lapply(frees_mono … H … Hf) -H #H1
  72 lapply (sor_eq_repl_back1 … Hy … H1) -y1 #Hy
  73 lapply (sor_inv_sle_sn … Hy) -y2 #Hfg
  74 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #L #HL1 #HL2
  75 lapply (sle_sex_trans … HL1 … Hfg) // #H
  76 elim (frees_sex_conf … Hf … H) -Hf -H
  77 /4 width=7 by sle_sex_trans, ex2_intro/
  78 qed-.
  79
  80 lemma rex_flat_dx_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  81                          rex_fsge_compatible R1 →
  82                          ∀L1,L2,T. L1 ⪤[R1, T] L2 → ∀I,V.
  83                          ∃∃L. L1 ⪤[R1, ⓕ{I}V.T] L & L ⪤[R2, T] L2.
  84 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #I #V
  85 elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  86 elim (frees_inv_flat … Hg) #y1 #y2 #_ #H #Hy
  87 lapply(frees_mono … H … Hf) -H #H2
  88 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
  89 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
  90 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #L #HL1 #HL2
  91 lapply (sle_sex_trans … HL1 … Hfg) // #H
  92 elim (frees_sex_conf … Hf … H) -Hf -H
  93 /4 width=7 by sle_sex_trans, ex2_intro/
  94 qed-.
  95
  96 lemma rex_bind_dx_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  97                          rex_fsge_compatible R1 →
  98                          ∀I,L1,L2,V1,T. L1.ⓑ{I}V1 ⪤[R1, T] L2 → ∀p.
  99                          ∃∃L,V. L1 ⪤[R1, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ⪤[R2, T] L2 & R1 L1 V1 V.
 100 #R1 #R2 #HR1 #HR2 #HR #I #L1 #L2 #V1 #T * #f #Hf #HL12 #p
 101 elim (frees_total L1 (ⓑ{p,I}V1.T)) #g #Hg
 102 elim (frees_inv_bind … Hg) #y1 #y2 #_ #H #Hy
 103 lapply(frees_mono … H … Hf) -H #H2
 104 lapply (tl_eq_repl … H2) -H2 #H2
 105 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
 106 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
 107 lapply (sle_inv_tl_sn … Hfg) -Hfg #Hfg
 108 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #Y #H #HL2
 109 lapply (sle_sex_trans … H … Hfg) // #H0
 110 elim (sex_inv_next1 … H) -H #Z #L #HL1 #H
 111 elim (ext2_inv_pair_sn … H) -H #V #HV #H1 #H2 destruct
 112 elim (frees_sex_conf … Hf … H0) -Hf -H0
 113 /4 width=7 by sle_sex_trans, ex3_2_intro, ex2_intro/
 114 qed-.
 115
 116 lemma rex_bind_dx_split_void: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
 117                               rex_fsge_compatible R1 →
 118                               ∀L1,L2,T. L1.ⓧ ⪤[R1, T] L2 → ∀p,I,V.
 119                               ∃∃L. L1 ⪤[R1, ⓑ{p,I}V.T] L & L.ⓧ ⪤[R2, T] L2.
 120 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #p #I #V
 121 elim (frees_total L1 (ⓑ{p,I}V.T)) #g #Hg
 122 elim (frees_inv_bind_void … Hg) #y1 #y2 #_ #H #Hy
 123 lapply(frees_mono … H … Hf) -H #H2
 124 lapply (tl_eq_repl … H2) -H2 #H2
 125 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
 126 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
 127 lapply (sle_inv_tl_sn … Hfg) -Hfg #Hfg
 128 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #Y #H #HL2
 129 lapply (sle_sex_trans … H … Hfg) // #H0
 130 elim (sex_inv_next1 … H) -H #Z #L #HL1 #H
 131 elim (ext2_inv_unit_sn … H) -H #H destruct
 132 elim (frees_sex_conf … Hf … H0) -Hf -H0
 133 /4 width=7 by sle_sex_trans, ex2_intro/ (* note: 2 ex2_intro *)
 134 qed-.
 135
 136 (* Main properties with free variables inclusion for restricted closures ****)
 137
 138 theorem rex_conf: ∀R1,R2.
 139                   rex_fsge_compatible R1 →
 140                   rex_fsge_compatible R2 →
 141                   R_confluent2_rex R1 R2 R1 R2 →
 142                   ∀T. confluent2 … (rex R1 T) (rex R2 T).
 143 #R1 #R2 #HR1 #HR2 #HR12 #T #L0 #L1 * #f1 #Hf1 #HL01 #L2 * #f #Hf #HL02
 144 lapply (frees_mono … Hf1 … Hf) -Hf1 #Hf12
 145 lapply (sex_eq_repl_back … HL01 … Hf12) -f1 #HL01
 146 elim (sex_conf … HL01 … HL02) /2 width=3 by ex2_intro/ [ | -HL01 -HL02 ]
 147 [ #L #HL1 #HL2
 148   elim (frees_sex_conf … Hf … HL01) // -HR1 -HL01 #f1 #Hf1 #H1
 149   elim (frees_sex_conf … Hf … HL02) // -HR2 -HL02 #f2 #Hf2 #H2
 150   lapply (sle_sex_trans … HL1 … H1) // -HL1 -H1 #HL1
 151   lapply (sle_sex_trans … HL2 … H2) // -HL2 -H2 #HL2
 152   /3 width=5 by ex2_intro/
 153 | #g * #I0 [2: #V0 ] #K0 #n #HLK0 #Hgf #Z1 #H1 #Z2 #H2 #K1 #HK01 #K2 #HK02
 154   [ elim (ext2_inv_pair_sn … H1) -H1 #V1 #HV01 #H destruct
 155     elim (ext2_inv_pair_sn … H2) -H2 #V2 #HV02 #H destruct
 156     elim (frees_inv_drops_next … Hf … HLK0 … Hgf) -Hf -HLK0 -Hgf #g0 #Hg0 #H0
 157     lapply (sle_sex_trans … HK01 … H0) // -HK01 #HK01
 158     lapply (sle_sex_trans … HK02 … H0) // -HK02 #HK02
 159     elim (HR12 … HV01 … HV02 K1 … K2) /3 width=3 by ext2_pair, ex2_intro/
 160   | lapply (ext2_inv_unit_sn … H1) -H1 #H destruct
 161     lapply (ext2_inv_unit_sn … H2) -H2 #H destruct
 162     /3 width=3 by ext2_unit, ex2_intro/
 163   ]
 164 ]
 165 qed-.
 166
 167 theorem rex_trans_fsle: ∀R1,R2,R3.
 168                         rex_fsle_compatible R1 → f_transitive_next R1 R2 R3 →
 169                         ∀L1,L,T. L1 ⪤[R1, T] L →
 170                         ∀L2. L ⪤[R2, T] L2 → L1 ⪤[R3, T] L2.
 171 #R1 #R2 #R3 #H1R #H2R #L1 #L #T #H
 172 lapply (H1R … H) -H1R #H0
 173 cases H -H #f1 #Hf1 #HL1 #L2 * #f2 #Hf2 #HL2
 174 lapply (fsle_inv_frees_eq … H0 … Hf1 … Hf2) -H0 -Hf2
 175 /4 width=14 by sex_trans_gen, sex_fwd_length, sle_sex_trans, ex2_intro/
 176 qed-.