matita/matita/contribs/lambdadelta/basic_2/substitution/cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/cl_shift.ma".
  16 include "basic_2/relocation/ldrop_append.ma".
  17 include "basic_2/substitution/lsubr.ma".
  18
  19 (* CONTEXT-SENSITIVE PARALLEL SUBSTITUTION FOR TERMS ************************)
  20
  21 inductive cpss: lenv → relation term ≝
  22 | cpss_atom : ∀I,L. cpss L (⓪{I}) (⓪{I})
  23 | cpss_delta: ∀L,K,V,V2,W2,i.
  24               ⇩[0, i] L ≡ K. ⓓV → cpss K V V2 →
  25               ⇧[0, i + 1] V2 ≡ W2 → cpss L (#i) W2
  26 | cpss_bind : ∀a,I,L,V1,V2,T1,T2.
  27               cpss L V1 V2 → cpss (L. ⓑ{I} V1) T1 T2 →
  28               cpss L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  29 | cpss_flat : ∀I,L,V1,V2,T1,T2.
  30               cpss L V1 V2 → cpss L T1 T2 →
  31               cpss L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  32 .
  33
  34 interpretation "context-sensitive parallel substitution (term)"
  35    'PSubstStar L T1 T2 = (cpss L T1 T2).
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma cpss_lsubr_trans: lsub_trans … cpss lsubr.
  40 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  41 [ //
  42 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  43   elim (lsubr_fwd_ldrop2_abbr … HL12 … HLK1) -HL12 -HLK1 /3 width=6/
  44 | /4 width=1/
  45 | /3 width=1/
  46 ]
  47 qed-.
  48
  49 (* Basic_1: was by definition: subst1_refl *)
  50 lemma cpss_refl: ∀T,L. L ⊢ T ▶* T.
  51 #T elim T -T //
  52 #I elim I -I /2 width=1/
  53 qed.
  54
  55 (* Basic_1: was only: subst1_ex *)
  56 lemma cpss_delift: ∀K,V,T1,L,d. ⇩[0, d] L ≡ (K. ⓓV) →
  57                    ∃∃T2,T. L ⊢ T1 ▶* T2 & ⇧[d, 1] T ≡ T2.
  58 #K #V #T1 elim T1 -T1
  59 [ * #i #L #d #HLK /2 width=4/
  60   elim (lt_or_eq_or_gt i d) #Hid /3 width=4/
  61   destruct
  62   elim (lift_total V 0 (i+1)) #W #HVW
  63   elim (lift_split … HVW i i) // /3 width=6/
  64 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  65   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  66   [ elim (IHU1 (L. ⓑ{I} W1) (d+1)) -IHU1 /2 width=1/ -HLK /3 width=9/
  67   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  68   ]
  69 ]
  70 qed-.
  71
  72 lemma cpss_append: l_appendable_sn … cpss.
  73 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/
  74 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  75 lapply (ldrop_fwd_length_lt2 … HK0) #H
  76 @(cpss_delta … (L@@K0) V1 … HVW2) //
  77 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  78 qed.
  79
  80 (* Basic inversion lemmas ***************************************************)
  81
  82 fact cpss_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ∀I. T1 = ⓪{I} →
  83                          T2 = ⓪{I} ∨
  84                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  85                                      K ⊢ V ▶* V2 &
  86                                      ⇧[O, i + 1] V2 ≡ T2 &
  87                                      I = LRef i.
  88 #L #T1 #T2 * -L -T1 -T2
  89 [ #I #L #J #H destruct /2 width=1/
  90 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #I #H destruct /3 width=8/
  91 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  92 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  93 ]
  94 qed-.
  95
  96 lemma cpss_inv_atom1: ∀I,L,T2. L ⊢ ⓪{I} ▶* T2 →
  97                       T2 = ⓪{I} ∨
  98                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  99                                   K ⊢ V ▶* V2 &
 100                                   ⇧[O, i + 1] V2 ≡ T2 &
 101                                   I = LRef i.
 102 /2 width=3 by cpss_inv_atom1_aux/ qed-.
 103
 104 (* Basic_1: was only: subst1_gen_sort *)
 105 lemma cpss_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ▶* T2 → T2 = ⋆k.
 106 #L #T2 #k #H
 107 elim (cpss_inv_atom1 … H) -H //
 108 * #K #V #V2 #i #_ #_ #_ #H destruct
 109 qed-.
 110
 111 (* Basic_1: was only: subst1_gen_lref *)
 112 lemma cpss_inv_lref1: ∀L,T2,i. L ⊢ #i ▶* T2 →
 113                       T2 = #i ∨
 114                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 115                                 K ⊢ V ▶* V2 &
 116                                 ⇧[O, i + 1] V2 ≡ T2.
 117 #L #T2 #i #H
 118 elim (cpss_inv_atom1 … H) -H /2 width=1/
 119 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 120 qed-.
 121
 122 lemma cpss_inv_gref1: ∀L,T2,p. L ⊢ §p ▶* T2 → T2 = §p.
 123 #L #T2 #p #H
 124 elim (cpss_inv_atom1 … H) -H //
 125 * #K #V #V2 #i #_ #_ #_ #H destruct
 126 qed-.
 127
 128 fact cpss_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 129                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 →
 130                          ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 131                                   L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 132                                   U2 = ⓑ{a,I} V2. T2.
 133 #L #U1 #U2 * -L -U1 -U2
 134 [ #I #L #b #J #W1 #U1 #H destruct
 135 | #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W1 #U1 #H destruct
 136 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W1 #U1 #H destruct /2 width=5/
 137 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W1 #U1 #H destruct
 138 ]
 139 qed-.
 140
 141 lemma cpss_inv_bind1: ∀a,I,L,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶* U2 →
 142                       ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 143                                L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 144                                U2 = ⓑ{a,I} V2. T2.
 145 /2 width=3 by cpss_inv_bind1_aux/ qed-.
 146
 147 fact cpss_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 148                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 →
 149                          ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 150                                   U2 =  ⓕ{I} V2. T2.
 151 #L #U1 #U2 * -L -U1 -U2
 152 [ #I #L #J #W1 #U1 #H destruct
 153 | #L #K #V #V2 #W2 #i #_ #_ #_ #J #W1 #U1 #H destruct
 154 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 155 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5/
 156 ]
 157 qed-.
 158
 159 lemma cpss_inv_flat1: ∀I,L,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶* U2 →
 160                       ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 161                                U2 =  ⓕ{I} V2. T2.
 162 /2 width=3 by cpss_inv_flat1_aux/ qed-.
 163
 164 (* Basic forward lemmas *****************************************************)
 165
 166 lemma cpss_fwd_tw: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ♯{T1} ≤ ♯{T2}.
 167 #L #T1 #T2 #H elim H -L -T1 -T2 normalize
 168 /3 width=1 by monotonic_le_plus_l, le_plus/ (**) (* auto is too slow without trace *)
 169 qed-.
 170
 171 lemma cpss_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ▶* T →
 172                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 173 #L1 @(lenv_ind_dx … L1) -L1 normalize
 174 [ #L #T1 #T #HT1
 175   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 176 | #I #L1 #V1 #IH #L #T1 #X
 177   >shift_append_assoc normalize #H
 178   elim (cpss_inv_bind1 … H) -H
 179   #V0 #T0 #_ #HT10 #H destruct
 180   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 181   >append_length >HL12 -HL12
 182   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 183 ]
 184 qed-.
 185
 186 (* Basic_1: removed theorems 27:
 187             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 188             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 189             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 190             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 191             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 192             subst0_confluence_lift subst0_tlt
 193             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 194             subst1_gen_lift_eq subst1_confluence_neq
 195 *)