matita/matita/contribs/lambdadelta/basic_2/substitution/frsup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/cl_weight.ma".
  16 include "basic_2/substitution/lift.ma".
  17
  18 (* RESTRICTED SUPCLOSURE ****************************************************)
  19
  20 inductive frsup: bi_relation lenv term ≝
  21 | frsup_bind_sn: ∀a,I,L,V,T. frsup L (ⓑ{a,I}V.T) L V
  22 | frsup_bind_dx: ∀a,I,L,V,T. frsup L (ⓑ{a,I}V.T) (L.ⓑ{I}V) T
  23 | frsup_flat_sn: ∀I,L,V,T.   frsup L (ⓕ{I}V.T) L V
  24 | frsup_flat_dx: ∀I,L,V,T.   frsup L (ⓕ{I}V.T) L T
  25 .
  26
  27 interpretation
  28    "restricted structural predecessor (closure)"
  29    'RestSupTerm L1 T1 L2 T2 = (frsup L1 T1 L2 T2).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 fact frsup_inv_atom1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ →
  34                           ∀J. T1 = ⓪{J} → ⊥.
  35 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2
  36 [ #a #I #L #V #T #J #H destruct
  37 | #a #I #L #V #T #J #H destruct
  38 | #I #L #V #T #J #H destruct
  39 | #I #L #V #T #J #H destruct
  40 ]
  41 qed-.
  42
  43 lemma frsup_inv_atom1: ∀J,L1,L2,T2. ⦃L1, ⓪{J}⦄ ⧁ ⦃L2, T2⦄ → ⊥.
  44 /2 width=7 by frsup_inv_atom1_aux/ qed-.
  45
  46 fact frsup_inv_bind1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ →
  47                           ∀b,J,W,U. T1 = ⓑ{b,J}W.U →
  48                           (L2 = L1 ∧ T2 = W) ∨
  49                           (L2 = L1.ⓑ{J}W ∧ T2 = U).
  50 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2
  51 [ #a #I #L #V #T #b #J #W #U #H destruct /3 width=1/
  52 | #a #I #L #V #T #b #J #W #U #H destruct /3 width=1/
  53 | #I #L #V #T #b #J #W #U #H destruct
  54 | #I #L #V #T #b #J #W #U #H destruct
  55 ]
  56 qed-.
  57
  58 lemma frsup_inv_bind1: ∀b,J,L1,L2,W,U,T2. ⦃L1, ⓑ{b,J}W.U⦄ ⧁ ⦃L2, T2⦄ →
  59                        (L2 = L1 ∧ T2 = W) ∨
  60                        (L2 = L1.ⓑ{J}W ∧ T2 = U).
  61 /2 width=4 by frsup_inv_bind1_aux/ qed-.
  62
  63 fact frsup_inv_flat1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ →
  64                           ∀J,W,U. T1 = ⓕ{J}W.U →
  65                           L2 = L1 ∧ (T2 = W ∨ T2 = U).
  66 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2
  67 [ #a #I #L #V #T #J #W #U #H destruct
  68 | #a #I #L #V #T #J #W #U #H destruct
  69 | #I #L #V #T #J #W #U #H destruct /3 width=1/
  70 | #I #L #V #T #J #W #U #H destruct /3 width=1/
  71 ]
  72 qed-.
  73
  74 lemma frsup_inv_flat1: ∀J,L1,L2,W,U,T2. ⦃L1, ⓕ{J}W.U⦄ ⧁ ⦃L2, T2⦄ →
  75                        L2 = L1 ∧ (T2 = W ∨ T2 = U).
  76 /2 width=4 by frsup_inv_flat1_aux/ qed-.
  77
  78 (* Basic forward lemmas *****************************************************)
  79
  80 lemma frsup_fwd_fw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → #{L2, T2} < #{L1, T1}.
  81 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2 /width=1/
  82 qed-.
  83
  84 lemma frsup_fwd_lw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → #{L1} ≤ #{L2}.
  85 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2 /width=1/
  86 qed-.
  87
  88 lemma frsup_fwd_tw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → #{T2} < #{T1}.
  89 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2 /width=1/ /2 width=1 by le_minus_to_plus/
  90 qed-.
  91
  92 lemma frsup_fwd_append: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → ∃L. L2 = L1 @@ L.
  93 #L1 #L2 #T1 #T2 * -L1 -L2 -T1 -T2
  94 [ #a
  95 | #a #I #L #V #_ @(ex_intro … (⋆.ⓑ{I}V)) //
  96 ]
  97 #I #L #V #T @(ex_intro … (⋆)) //
  98 qed-.
  99
 100 (* Advanced forward lemmas **************************************************)
 101
 102 lemma lift_frsup_trans: ∀T1,U1,d,e. ⇧[d, e] T1 ≡ U1 →
 103                         ∀L,K,U2. ⦃L, U1⦄ ⧁ ⦃L @@ K, U2⦄ →
 104                         ∃T2. ⇧[d + |K|, e] T2 ≡ U2.
 105 #T1 #U1 #d #e * -T1 -U1 -d -e
 106 [5: #a #I #V1 #W1 #T1 #U1 #d #e #HVW1 #HTU1 #L #K #X #H
 107     elim (frsup_inv_bind1 … H) -H *
 108     [ -HTU1 #H1 #H2 destruct
 109       >(append_inv_refl_dx … H1) -L -K normalize /2 width=2/
 110     | -HVW1 #H1 #H2 destruct
 111       >(append_inv_pair_dx … H1) -L -K normalize /2 width=2/
 112     ]
 113 |6: #I #V1 #W1 #T1 #U1 #d #e #HVW1 #HUT1 #L #K #X #H
 114     elim (frsup_inv_flat1 … H) -H #H1 * #H2 destruct
 115     >(append_inv_refl_dx … H1) -L -K normalize /2 width=2/
 116 ]
 117 #i #d #e [2,3: #_ ] #L #K #X #H
 118 elim (frsup_inv_atom1 … H)
 119 qed-.