matita/matita/contribs/lambdadelta/basic_2/substitution/fsupp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/suptermplus_4.ma".
  16 include "basic_2/relocation/fsup.ma".
  17
  18 (* PLUS-ITERATED SUPCLOSURE *************************************************)
  19
  20 definition fsupp: bi_relation lenv term ≝ bi_TC … fsup.
  21
  22 interpretation "plus-iterated structural successor (closure)"
  23    'SupTermPlus L1 T1 L2 T2 = (fsupp L1 T1 L2 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma fsup_fsupp: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄.
  28 /2 width=1/ qed.
  29
  30 lemma fsupp_strap1: ∀L1,L,L2,T1,T,T2. ⦃L1, T1⦄ ⊃+ ⦃L, T⦄ → ⦃L, T⦄ ⊃ ⦃L2, T2⦄ →
  31                     ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄.
  32 /2 width=4/ qed.
  33
  34 lemma fsupp_strap2: ∀L1,L,L2,T1,T,T2. ⦃L1, T1⦄ ⊃ ⦃L, T⦄ → ⦃L, T⦄ ⊃+ ⦃L2, T2⦄ →
  35                     ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄.
  36 /2 width=4/ qed.
  37
  38 lemma fsupp_lref: ∀I,K,V,i,L. ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃L, #i⦄ ⊃+ ⦃K, V⦄.
  39 /3 width=2/ qed.
  40
  41 lemma fsupp_pair_sn: ∀I,L,V,T. ⦃L, ②{I}V.T⦄ ⊃+ ⦃L, V⦄.
  42 /2 width=1/ qed.
  43
  44 lemma fsupp_bind_dx: ∀a,K,I,V,T. ⦃K, ⓑ{a,I}V.T⦄ ⊃+ ⦃K.ⓑ{I}V, T⦄.
  45 /2 width=1/ qed.
  46
  47 lemma fsupp_flat_dx: ∀I,L,V,T. ⦃L, ⓕ{I}V.T⦄ ⊃+ ⦃L, T⦄.
  48 /2 width=1/ qed.
  49
  50 lemma fsupp_flat_dx_pair_sn: ∀I1,I2,L,V1,V2,T. ⦃L, ⓕ{I1}V1.②{I2}V2.T⦄ ⊃+ ⦃L, V2⦄.
  51 /2 width=4/ qed.
  52
  53 lemma fsupp_bind_dx_flat_dx: ∀a,I1,I2,L,V1,V2,T. ⦃L, ⓑ{a,I1}V1.ⓕ{I2}V2.T⦄ ⊃+ ⦃L.ⓑ{I1}V1, T⦄.
  54 /2 width=4/ qed.
  55
  56 lemma fsupp_flat_dx_bind_dx: ∀a,I1,I2,L,V1,V2,T. ⦃L, ⓕ{I1}V1.ⓑ{a,I2}V2.T⦄ ⊃+ ⦃L.ⓑ{I2}V2, T⦄.
  57 /2 width=4/ qed.
  58
  59 (* Basic eliminators ********************************************************)
  60
  61 lemma fsupp_ind: ∀L1,T1. ∀R:relation2 lenv term.
  62                  (∀L2,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → R L2 T2) →
  63                  (∀L,T,L2,T2. ⦃L1, T1⦄ ⊃+ ⦃L, T⦄ → ⦃L, T⦄ ⊃ ⦃L2, T2⦄ → R L T → R L2 T2) →
  64                  ∀L2,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ → R L2 T2.
  65 #L1 #T1 #R #IH1 #IH2 #L2 #T2 #H
  66 @(bi_TC_ind … IH1 IH2 ? ? H)
  67 qed-.
  68
  69 lemma fsupp_ind_dx: ∀L2,T2. ∀R:relation2 lenv term.
  70                     (∀L1,T1. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → R L1 T1) →
  71                     (∀L1,L,T1,T. ⦃L1, T1⦄ ⊃ ⦃L, T⦄ → ⦃L, T⦄ ⊃+ ⦃L2, T2⦄ → R L T → R L1 T1) →
  72                     ∀L1,T1. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ → R L1 T1.
  73 #L2 #T2 #R #IH1 #IH2 #L1 #T1 #H
  74 @(bi_TC_ind_dx … IH1 IH2 ? ? H)
  75 qed-.
  76
  77 (* Basic forward lemmas *****************************************************)
  78
  79 lemma fsupp_fwd_fw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ → ♯{L2, T2} < ♯{L1, T1}.
  80 #L1 #L2 #T1 #T2 #H @(fsupp_ind … H) -L2 -T2
  81 /3 width=3 by fsup_fwd_fw, transitive_lt/
  82 qed-.
  83
  84 (* Advanced eliminators *****************************************************)
  85
  86 lemma fsupp_wf_ind: ∀R:relation2 lenv term. (
  87                        ∀L1,T1. (∀L2,T2. ⦃L1, T1⦄ ⊃+ ⦃L2, T2⦄ → R L2 T2) →
  88                        ∀L2,T2. L1 = L2 → T1 = T2 → R L2 T2
  89                     ) → ∀L1,T1. R L1 T1.
  90 #R #HR @(f2_ind … fw) #n #IHn #L1 #T1 #H destruct /4 width=5 by fsupp_fwd_fw/
  91 qed-.