matita/matita/contribs/lambdadelta/basic_2/substitution/fsupp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/suptermplus_6.ma".
  16 include "basic_2/relocation/fsup.ma".
  17
  18 (* PLUS-ITERATED SUPCLOSURE *************************************************)
  19
  20 definition fsupp: tri_relation genv lenv term ≝ tri_TC … fsup.
  21
  22 interpretation "plus-iterated structural successor (closure)"
  23    'SupTermPlus G1 L1 T1 G2 L2 T2 = (fsupp G1 L1 T1 G2 L2 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma fsup_fsupp: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄.
  28 /2 width=1/ qed.
  29
  30 lemma fsupp_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  31                     ⦃G1, L1, T1⦄ ⊃+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃ ⦃G2, L2, T2⦄ →
  32                     ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄.
  33 /2 width=5/ qed.
  34
  35 lemma fsupp_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  36                     ⦃G1, L1, T1⦄ ⊃ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃+ ⦃G2, L2, T2⦄ →
  37                     ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄.
  38 /2 width=5/ qed.
  39
  40 lemma fsupp_lref: ∀I,G,L,K,V,i. ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃G, L, #i⦄ ⊃+ ⦃G, K, V⦄.
  41 /3 width=2/ qed.
  42
  43 lemma fsupp_pair_sn: ∀I,G,L,V,T. ⦃G, L, ②{I}V.T⦄ ⊃+ ⦃G, L, V⦄.
  44 /2 width=1/ qed.
  45
  46 lemma fsupp_bind_dx: ∀a,I,G,L,V,T. ⦃G, L, ⓑ{a,I}V.T⦄ ⊃+ ⦃G, L.ⓑ{I}V, T⦄.
  47 /2 width=1/ qed.
  48
  49 lemma fsupp_flat_dx: ∀I,G,L,V,T. ⦃G, L, ⓕ{I}V.T⦄ ⊃+ ⦃G, L, T⦄.
  50 /2 width=1/ qed.
  51
  52 lemma fsupp_flat_dx_pair_sn: ∀I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.②{I2}V2.T⦄ ⊃+ ⦃G, L, V2⦄.
  53 /2 width=5/ qed.
  54
  55 lemma fsupp_bind_dx_flat_dx: ∀a,G,I1,I2,L,V1,V2,T. ⦃G, L, ⓑ{a,I1}V1.ⓕ{I2}V2.T⦄ ⊃+ ⦃G, L.ⓑ{I1}V1, T⦄.
  56 /2 width=5/ qed.
  57
  58 lemma fsupp_flat_dx_bind_dx: ∀a,I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.ⓑ{a,I2}V2.T⦄ ⊃+ ⦃G, L.ⓑ{I2}V2, T⦄.
  59 /2 width=5/ qed.
  60
  61 (* Basic eliminators ********************************************************)
  62
  63 lemma fsupp_ind: ∀G1,L1,T1. ∀R:relation3 ….
  64                  (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  65                  (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  66                  ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → R G2 L2 T2.
  67 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  68 @(tri_TC_ind … IH1 IH2 G2 L2 T2 H)
  69 qed-.
  70
  71 lemma fsupp_ind_dx: ∀G2,L2,T2. ∀R:relation3 ….
  72                     (∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ → R G1 L1 T1) →
  73                     (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊃ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃+ ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  74                     ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → R G1 L1 T1.
  75 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  76 @(tri_TC_ind_dx … IH1 IH2 G1 L1 T1 H)
  77 qed-.
  78
  79 (* Basic forward lemmas *****************************************************)
  80
  81 lemma fsupp_fwd_fw: ∀G1,G2,L1,L2,T1,T2.
  82                     ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → ♯{G2, L2, T2} < ♯{G1, L1, T1}.
  83 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fsupp_ind … H) -G2 -L2 -T2
  84 /3 width=3 by fsup_fwd_fw, transitive_lt/
  85 qed-.
  86
  87 (* Advanced eliminators *****************************************************)
  88
  89 lemma fsupp_wf_ind: ∀R:relation3 …. (
  90                        ∀G1,L1,T1. (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  91                        ∀G2,L2,T2. G1 = G2 → L1 = L2 → T1 = T2 → R G2 L2 T2
  92                     ) → ∀G1,L1,T1. R G1 L1 T1.
  93 #R #HR @(f3_ind … fw) #n #IHn #G1 #L1 #T1 #H destruct /4 width=7 by fsupp_fwd_fw/
  94 qed-.