matita/matita/contribs/lambdadelta/basic_2/substitution/fsups.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/suptermstar_6.ma".
  16 include "basic_2/relocation/fsupq.ma".
  17
  18 (* STAR-ITERATED SUPCLOSURE *************************************************)
  19
  20 definition fsups: tri_relation genv lenv term ≝ tri_TC … fsupq.
  21
  22 interpretation "star-iterated structural successor (closure)"
  23    'SupTermStar G1 L1 T1 G2 L2 T2 = (fsups G1 L1 T1 G2 L2 T2).
  24
  25 (* Basic eliminators ********************************************************)
  26
  27 lemma fsups_ind: ∀G1,L1,T1. ∀R:relation3 …. R G1 L1 T1 →
  28                  (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃⸮ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  29                  ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ → R G2 L2 T2.
  30 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  31 @(tri_TC_star_ind … IH1 IH2 G2 L2 T2 H) //
  32 qed-.
  33
  34 lemma fsups_ind_dx: ∀G2,L2,T2. ∀R:relation3 …. R G2 L2 T2 →
  35                     (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃* ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  36                     ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ → R G1 L1 T1.
  37 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  38 @(tri_TC_star_ind_dx … IH1 IH2 G1 L1 T1 H) //
  39 qed-.
  40
  41 (* Basic properties *********************************************************)
  42
  43 lemma fsups_refl: tri_reflexive … fsups.
  44 /2 width=1 by tri_inj/ qed.
  45
  46 lemma fsupq_fsups: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄.
  47 /2 width=1 by tri_inj/ qed.
  48
  49 lemma fsups_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
  50                     ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄.
  51 /2 width=5 by tri_step/ qed.
  52
  53 lemma fsups_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊃* ⦃G2, L2, T2⦄ →
  54                     ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄.
  55 /2 width=5 by tri_TC_strap/ qed.
  56
  57 lemma fsups_ldrop: ∀G1,G2,K1,K2,T1,T2. ⦃G1, K1, T1⦄ ⊃* ⦃G2, K2, T2⦄ →
  58                    ∀L1,U1,e. ⇩[0, e] L1 ≡ K1 → ⇧[0, e] T1 ≡ U1 →
  59                    ⦃G1, L1, U1⦄ ⊃* ⦃G2, K2, T2⦄.
  60 #G1 #G2 #K1 #K2 #T1 #T2 #H @(fsups_ind … H) -G2 -K2 -T2
  61 /3 width=5 by fsups_strap1, fsupq_fsups, fsupq_drop/
  62 qed-.
  63
  64 (* Basic forward lemmas *****************************************************)
  65
  66 lemma fsups_fwd_fw: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ → ♯{G2, L2, T2} ≤ ♯{G1, L1, T1}.
  67 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fsups_ind … H) -L2 -T2
  68 /3 width=3 by fsupq_fwd_fw, transitive_le/
  69 qed-.