matita/matita/contribs/lambdadelta/basic_2/substitution/ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/cl_weight.ma".
  16 include "basic_2/substitution/lift.ma".
  17 include "basic_2/substitution/lsubr.ma".
  18
  19 (* LOCAL ENVIRONMENT SLICING ************************************************)
  20
  21 (* Basic_1: includes: drop_skip_bind *)
  22 inductive ldrop: nat → nat → relation lenv ≝
  23 | ldrop_atom : ∀d,e. ldrop d e (⋆) (⋆)
  24 | ldrop_pair : ∀L,I,V. ldrop 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  25 | ldrop_ldrop: ∀L1,L2,I,V,e. ldrop 0 e L1 L2 → ldrop 0 (e + 1) (L1. ⓑ{I} V) L2
  26 | ldrop_skip : ∀L1,L2,I,V1,V2,d,e.
  27                ldrop d e L1 L2 → ⇧[d,e] V2 ≡ V1 →
  28                ldrop (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  29 .
  30
  31 interpretation "local slicing" 'RDrop d e L1 L2 = (ldrop d e L1 L2).
  32
  33 definition l_liftable: (lenv → relation term) → Prop ≝
  34                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,d,e. ⇩[d, e] L ≡ K →
  35                        ∀U1. ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 → R L U1 U2.
  36
  37 definition l_deliftable_sn: (lenv → relation term) → Prop ≝
  38                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,d,e. ⇩[d, e] L ≡ K →
  39                             ∀T1. ⇧[d, e] T1 ≡ U1 →
  40                             ∃∃T2. ⇧[d, e] T2 ≡ U2 & R K T1 T2.
  41
  42 definition dropable_sn: relation lenv → Prop ≝
  43                         λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀L2. R L1 L2 →
  44                         ∃∃K2. R K1 K2 & ⇩[d, e] L2 ≡ K2.
  45
  46 definition dedropable_sn: relation lenv → Prop ≝
  47                           λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀K2. R K1 K2 →
  48                           ∃∃L2. R L1 L2 & ⇩[d, e] L2 ≡ K2.
  49
  50 definition dropable_dx: relation lenv → Prop ≝
  51                         λR. ∀L1,L2. R L1 L2 → ∀K2,e. ⇩[0, e] L2 ≡ K2 →
  52                         ∃∃K1. ⇩[0, e] L1 ≡ K1 & R K1 K2.
  53
  54 (* Basic inversion lemmas ***************************************************)
  55
  56 fact ldrop_inv_refl_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  57 #d #e #L1 #L2 * -d -e -L1 -L2
  58 [ //
  59 | //
  60 | #L1 #L2 #I #V #e #_ #_ >commutative_plus normalize #H destruct
  61 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  62 ]
  63 qed.
  64
  65 (* Basic_1: was: drop_gen_refl *)
  66 lemma ldrop_inv_refl: ∀L1,L2. ⇩[0, 0] L1 ≡ L2 → L1 = L2.
  67 /2 width=5/ qed-.
  68
  69 fact ldrop_inv_atom1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → L1 = ⋆ →
  70                           L2 = ⋆.
  71 #d #e #L1 #L2 * -d -e -L1 -L2
  72 [ //
  73 | #L #I #V #H destruct
  74 | #L1 #L2 #I #V #e #_ #H destruct
  75 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  76 ]
  77 qed.
  78
  79 (* Basic_1: was: drop_gen_sort *)
  80 lemma ldrop_inv_atom1: ∀d,e,L2. ⇩[d, e] ⋆ ≡ L2 → L2 = ⋆.
  81 /2 width=5/ qed-.
  82
  83 fact ldrop_inv_O1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → d = 0 →
  84                        ∀K,I,V. L1 = K. ⓑ{I} V →
  85                        (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  86                        (0 < e ∧ ⇩[d, e - 1] K ≡ L2).
  87 #d #e #L1 #L2 * -d -e -L1 -L2
  88 [ #d #e #_ #K #I #V #H destruct
  89 | #L #I #V #_ #K #J #W #HX destruct /3 width=1/
  90 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct /3 width=1/
  91 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  92 ]
  93 qed.
  94
  95 lemma ldrop_inv_O1: ∀e,K,I,V,L2. ⇩[0, e] K. ⓑ{I} V ≡ L2 →
  96                     (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  97                     (0 < e ∧ ⇩[0, e - 1] K ≡ L2).
  98 /2 width=3/ qed-.
  99
 100 lemma ldrop_inv_pair1: ∀K,I,V,L2. ⇩[0, 0] K. ⓑ{I} V ≡ L2 → L2 = K. ⓑ{I} V.
 101 #K #I #V #L2 #H
 102 elim (ldrop_inv_O1 … H) -H * // #H destruct
 103 elim (lt_refl_false … H)
 104 qed-.
 105
 106 (* Basic_1: was: drop_gen_drop *)
 107 lemma ldrop_inv_ldrop1: ∀e,K,I,V,L2.
 108                         ⇩[0, e] K. ⓑ{I} V ≡ L2 → 0 < e → ⇩[0, e - 1] K ≡ L2.
 109 #e #K #I #V #L2 #H #He
 110 elim (ldrop_inv_O1 … H) -H * // #H destruct
 111 elim (lt_refl_false … He)
 112 qed-.
 113
 114 fact ldrop_inv_skip1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 115                           ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
 116                           ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 117                                    ⇧[d - 1, e] V2 ≡ V1 &
 118                                    L2 = K2. ⓑ{I} V2.
 119 #d #e #L1 #L2 * -d -e -L1 -L2
 120 [ #d #e #_ #I #K #V #H destruct
 121 | #L #I #V #H elim (lt_refl_false … H)
 122 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 123 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct /2 width=5/
 124 ]
 125 qed.
 126
 127 (* Basic_1: was: drop_gen_skip_l *)
 128 lemma ldrop_inv_skip1: ∀d,e,I,K1,V1,L2. ⇩[d, e] K1. ⓑ{I} V1 ≡ L2 → 0 < d →
 129                        ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 130                                 ⇧[d - 1, e] V2 ≡ V1 &
 131                                 L2 = K2. ⓑ{I} V2.
 132 /2 width=3/ qed-.
 133
 134 lemma ldrop_inv_O1_pair2: ∀I,K,V,e,L1. ⇩[0, e] L1 ≡ K. ⓑ{I} V →
 135                           (e = 0 ∧ L1 = K. ⓑ{I} V) ∨
 136                           ∃∃I1,K1,V1. ⇩[0, e - 1] K1 ≡ K. ⓑ{I} V & L1 = K1.ⓑ{I1}V1 & 0 < e.
 137 #I #K #V #e *
 138 [ #H lapply (ldrop_inv_atom1 … H) -H #H destruct
 139 | #L1 #I1 #V1 #H
 140   elim (ldrop_inv_O1 … H) -H *
 141   [ #H1 #H2 destruct /3 width=1/
 142   | /3 width=5/
 143   ]
 144 ]
 145 qed-.
 146
 147 fact ldrop_inv_skip2_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 148                           ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 149                           ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 &
 150                                    ⇧[d - 1, e] V2 ≡ V1 &
 151                                    L1 = K1. ⓑ{I} V1.
 152 #d #e #L1 #L2 * -d -e -L1 -L2
 153 [ #d #e #_ #I #K #V #H destruct
 154 | #L #I #V #H elim (lt_refl_false … H)
 155 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 156 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct /2 width=5/
 157 ]
 158 qed.
 159
 160 (* Basic_1: was: drop_gen_skip_r *)
 161 lemma ldrop_inv_skip2: ∀d,e,I,L1,K2,V2. ⇩[d, e] L1 ≡ K2. ⓑ{I} V2 → 0 < d →
 162                        ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 & ⇧[d - 1, e] V2 ≡ V1 &
 163                                 L1 = K1. ⓑ{I} V1.
 164 /2 width=3/ qed-.
 165
 166 (* Basic properties *********************************************************)
 167
 168 (* Basic_1: was by definition: drop_refl *)
 169 lemma ldrop_refl: ∀L. ⇩[0, 0] L ≡ L.
 170 #L elim L -L //
 171 qed.
 172
 173 lemma ldrop_ldrop_lt: ∀L1,L2,I,V,e.
 174                       ⇩[0, e - 1] L1 ≡ L2 → 0 < e → ⇩[0, e] L1. ⓑ{I} V ≡ L2.
 175 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) // /2 width=1/
 176 qed.
 177
 178 lemma ldrop_skip_lt: ∀L1,L2,I,V1,V2,d,e.
 179                      ⇩[d - 1, e] L1 ≡ L2 → ⇧[d - 1, e] V2 ≡ V1 → 0 < d →
 180                      ⇩[d, e] L1. ⓑ{I} V1 ≡ L2. ⓑ{I} V2.
 181 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV21 #Hd >(plus_minus_m_m d 1) // /2 width=1/
 182 qed.
 183
 184 lemma ldrop_O1_le: ∀i,L. i ≤ |L| → ∃K. ⇩[0, i] L ≡ K.
 185 #i @(nat_ind_plus … i) -i /2 width=2/
 186 #i #IHi *
 187 [ #H lapply (le_n_O_to_eq … H) -H >commutative_plus normalize #H destruct
 188 | #L #I #V normalize #H
 189   elim (IHi L ?) -IHi /2 width=1/ -H /3 width=2/
 190 ]
 191 qed.
 192
 193 lemma ldrop_O1_lt: ∀L,i. i < |L| → ∃∃I,K,V. ⇩[0, i] L ≡ K.ⓑ{I}V.
 194 #L elim L -L
 195 [ #i #H elim (lt_zero_false … H)
 196 | #L #I #V #IHL #i @(nat_ind_plus … i) -i /2 width=4/
 197   #i #_ normalize #H
 198   elim (IHL i ? ) -IHL /2 width=1/ -H /3 width=4/
 199 ]
 200 qed.
 201
 202 lemma ldrop_lsubr_ldrop2_abbr: ∀L1,L2,d,e. L1 ⊑ [d, e] L2 →
 203                                ∀K2,V,i. ⇩[0, i] L2 ≡ K2. ⓓV →
 204                                d ≤ i → i < d + e →
 205                                ∃∃K1. K1 ⊑ [0, d + e - i - 1] K2 &
 206                                      ⇩[0, i] L1 ≡ K1. ⓓV.
 207 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 208 [ #d #e #K1 #V #i #H
 209   lapply (ldrop_inv_atom1 … H) -H #H destruct
 210 | #L1 #L2 #K1 #V #i #_ #_ #H
 211   elim (lt_zero_false … H)
 212 | #L1 #L2 #V #e #HL12 #IHL12 #K1 #W #i #H #_ #Hie
 213   elim (ldrop_inv_O1 … H) -H * #Hi #HLK1
 214   [ -IHL12 -Hie destruct
 215     <minus_n_O <minus_plus_m_m // /2 width=3/
 216   | -HL12
 217     elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 // /2 width=1/ -Hie >minus_minus_comm >arith_b1 // /4 width=3/
 218   ]
 219 | #L1 #L2 #I #V1 #V2 #e #_ #IHL12 #K1 #W #i #H #_ #Hie
 220   elim (ldrop_inv_O1 … H) -H * #Hi #HLK1
 221   [ -IHL12 -Hie -Hi destruct
 222   | elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 // /2 width=1/ -Hie >minus_minus_comm >arith_b1 // /3 width=3/
 223   ]
 224 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 225   elim (le_inv_plus_l … Hdi) #Hdim #Hi
 226   lapply (ldrop_inv_ldrop1 … H ?) -H // #HLK1
 227   elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 // /2 width=1/ -Hdi -Hide >minus_minus_comm >arith_b1 // /3 width=3/
 228 ]
 229 qed.
 230
 231 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 232 #R #HR #L1 #K1 #d #e #HLK1 #L2 #H elim H -L2
 233 [ #L2 #HL12
 234   elim (HR … HLK1 … HL12) -HR -L1 /3 width=3/
 235 | #L #L2 #_ #HL2 * #K #HK1 #HLK
 236   elim (HR … HLK … HL2) -HR -L /3 width=3/
 237 ]
 238 qed.
 239
 240 lemma dedropable_sn_TC: ∀R. dedropable_sn R → dedropable_sn (TC … R).
 241 #R #HR #L1 #K1 #d #e #HLK1 #K2 #H elim H -K2
 242 [ #K2 #HK12
 243   elim (HR … HLK1 … HK12) -HR -K1 /3 width=3/
 244 | #K #K2 #_ #HK2 * #L #HL1 #HLK
 245   elim (HR … HLK … HK2) -HR -K /3 width=3/
 246 ]
 247 qed.
 248
 249 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 250 #R #HR #L1 #L2 #H elim H -L2
 251 [ #L2 #HL12 #K2 #e #HLK2
 252   elim (HR … HL12 … HLK2) -HR -L2 /3 width=3/
 253 | #L #L2 #_ #HL2 #IHL1 #K2 #e #HLK2
 254   elim (HR … HL2 … HLK2) -HR -L2 #K #HLK #HK2
 255   elim (IHL1 … HLK) -L /3 width=5/
 256 ]
 257 qed.
 258
 259 (* Basic forvard lemmas *****************************************************)
 260
 261 (* Basic_1: was: drop_S *)
 262 lemma ldrop_fwd_ldrop2: ∀L1,I2,K2,V2,e. ⇩[O, e] L1 ≡ K2. ⓑ{I2} V2 →
 263                         ⇩[O, e + 1] L1 ≡ K2.
 264 #L1 elim L1 -L1
 265 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H #H destruct
 266 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 267   elim (ldrop_inv_O1 … H) -H * #He #H
 268   [ -IHL1 destruct /2 width=1/
 269   | @ldrop_ldrop >(plus_minus_m_m e 1) // /2 width=3/
 270   ]
 271 ]
 272 qed-.
 273
 274 lemma ldrop_fwd_length: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L2| ≤ |L1|.
 275 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize /2 width=1/
 276 qed-.
 277
 278 lemma ldrop_fwd_lw: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 279 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize
 280 [ /2 width=3/
 281 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12
 282   >(lift_fwd_tw … HV21) -HV21 /2 width=1/
 283 ]
 284 qed-.
 285
 286 lemma ldrop_pair2_fwd_fw: ∀I,L,K,V,d,e. ⇩[d, e] L ≡ K. ⓑ{I} V →
 287                           ∀T. ♯{K, V} < ♯{L, T}.
 288 #I #L #K #V #d #e #H #T
 289 lapply (ldrop_fwd_lw … H) -H #H
 290 @(le_to_lt_to_lt … H) -H /3 width=1/
 291 qed-.
 292
 293 lemma ldrop_fwd_ldrop2_length: ∀L1,I2,K2,V2,e.
 294                                ⇩[0, e] L1 ≡ K2. ⓑ{I2} V2 → e < |L1|.
 295 #L1 elim L1 -L1
 296 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H #H destruct
 297 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 298   elim (ldrop_inv_O1 … H) -H * #He #H
 299   [ -IHL1 destruct //
 300   | lapply (IHL1 … H) -IHL1 -H #HeK1 whd in ⊢ (? ? %); /2 width=1/
 301   ]
 302 ]
 303 qed-.
 304
 305 lemma ldrop_fwd_O1_length: ∀L1,L2,e. ⇩[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 306 #L1 elim L1 -L1
 307 [ #L2 #e #H >(ldrop_inv_atom1 … H) -H //
 308 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 309   elim (ldrop_inv_O1 … H) -H * #He #H
 310   [ -IHL1 destruct //
 311   | lapply (IHL1 … H) -IHL1 -H #H >H -H normalize
 312     >minus_le_minus_minus_comm //
 313   ]
 314 ]
 315 qed-.
 316
 317 (* Basic_1: removed theorems 50:
 318             drop_ctail drop_skip_flat
 319             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 320             drop_clear drop_clear_O drop_clear_S
 321             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 322             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 323             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 324             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 325             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 326             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 327             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 328             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 329             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 330 *)