matita/matita/contribs/lambdadelta/basic_2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_plus.ma".
  16 include "basic_2/notation/relations/rlift_4.ma".
  17 include "basic_2/grammar/term_weight.ma".
  18 include "basic_2/grammar/term_simple.ma".
  19
  20 (* BASIC TERM RELOCATION ****************************************************)
  21
  22 (* Basic_1: includes:
  23             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  24 *)
  25 inductive lift: relation4 ynat nat term term ≝
  26 | lift_sort   : ∀k,l,m. lift l m (⋆k) (⋆k)
  27 | lift_lref_lt: ∀i,l,m. yinj i < l → lift l m (#i) (#i)
  28 | lift_lref_ge: ∀i,l,m. l ≤ yinj i → lift l m (#i) (#(i + m))
  29 | lift_gref   : ∀p,l,m. lift l m (§p) (§p)
  30 | lift_bind   : ∀a,I,V1,V2,T1,T2,l,m.
  31                 lift l m V1 V2 → lift (⫯l) m T1 T2 →
  32                 lift l m (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  33 | lift_flat   : ∀I,V1,V2,T1,T2,l,m.
  34                 lift l m V1 V2 → lift l m T1 T2 →
  35                 lift l m (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  36 .
  37
  38 interpretation "relocation" 'RLift l m T1 T2 = (lift l m T1 T2).
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 fact lift_inv_O2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → m = 0 → T1 = T2.
  43 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 /3 width=1 by eq_f2/
  44 qed-.
  45
  46 lemma lift_inv_O2: ∀l,T1,T2. ⬆[l, 0] T1 ≡ T2 → T1 = T2.
  47 /2 width=4 by lift_inv_O2_aux/ qed-.
  48
  49 fact lift_inv_sort1_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  50 #l #m #T1 #T2 * -l -m -T1 -T2 //
  51 [ #i #l #m #_ #k #H destruct
  52 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  53 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  54 ]
  55 qed-.
  56
  57 lemma lift_inv_sort1: ∀l,m,T2,k. ⬆[l, m] ⋆k ≡ T2 → T2 = ⋆k.
  58 /2 width=5 by lift_inv_sort1_aux/ qed-.
  59
  60 fact lift_inv_lref1_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀i. T1 = #i →
  61                          (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  62 #l #m #T1 #T2 * -l -m -T1 -T2
  63 [ #k #l #m #i #H destruct
  64 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl,conj/
  65 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_intror,conj/
  66 | #p #l #m #i #H destruct
  67 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  68 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
  69 ]
  70 qed-.
  71
  72 lemma lift_inv_lref1: ∀l,m,T2,i. ⬆[l, m] #i ≡ T2 →
  73                       (i < l ∧ T2 = #i) ∨ (l ≤ i ∧ T2 = #(i + m)).
  74 /2 width=3 by lift_inv_lref1_aux/ qed-.
  75
  76 lemma lift_inv_lref1_lt: ∀l,m,T2,i. ⬆[l, m] #i ≡ T2 → i < l → T2 = #i.
  77 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  78 #Hli #_ #Hil elim (ylt_yle_false … Hli) -Hli //
  79 qed-.
  80
  81 lemma lift_inv_lref1_ge: ∀l,m,T2,i. ⬆[l, m] #i ≡ T2 → l ≤ i → T2 = #(i + m).
  82 #l #m #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  83 #Hil #_ #Hli elim (ylt_yle_false … Hli) -Hli //
  84 qed-.
  85
  86 fact lift_inv_gref1_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  87 #l #m #T1 #T2 * -l -m -T1 -T2 //
  88 [ #i #l #m #_ #k #H destruct
  89 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  90 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
  91 ]
  92 qed-.
  93
  94 lemma lift_inv_gref1: ∀l,m,T2,p. ⬆[l, m] §p ≡ T2 → T2 = §p.
  95 /2 width=5 by lift_inv_gref1_aux/ qed-.
  96
  97 fact lift_inv_bind1_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 →
  98                          ∀a,I,V1,U1. T1 = ⓑ{a,I}V1.U1 →
  99                          ∃∃V2,U2. ⬆[l, m] V1 ≡ V2 & ⬆[⫯l, m] U1 ≡ U2 &
 100                                   T2 = ⓑ{a,I}V2.U2.
 101 #l #m #T1 #T2 * -l -m -T1 -T2
 102 [ #k #l #m #a #I #V1 #U1 #H destruct
 103 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 104 | #i #l #m #_ #a #I #V1 #U1 #H destruct
 105 | #p #l #m #a #I #V1 #U1 #H destruct
 106 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 107 | #J #W1 #W2 #T1 #T2 #l #m #_ #HT #a #I #V1 #U1 #H destruct
 108 ]
 109 qed-.
 110
 111 lemma lift_inv_bind1: ∀l,m,T2,a,I,V1,U1. ⬆[l, m] ⓑ{a,I}V1.U1 ≡ T2 →
 112                       ∃∃V2,U2. ⬆[l, m] V1 ≡ V2 & ⬆[⫯l, m] U1 ≡ U2 &
 113                                T2 = ⓑ{a,I}V2.U2.
 114 /2 width=3 by lift_inv_bind1_aux/ qed-.
 115
 116 fact lift_inv_flat1_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 →
 117                          ∀I,V1,U1. T1 = ⓕ{I}V1.U1 →
 118                          ∃∃V2,U2. ⬆[l, m] V1 ≡ V2 & ⬆[l, m] U1 ≡ U2 &
 119                                   T2 = ⓕ{I}V2.U2.
 120 #l #m #T1 #T2 * -l -m -T1 -T2
 121 [ #k #l #m #I #V1 #U1 #H destruct
 122 | #i #l #m #_ #I #V1 #U1 #H destruct
 123 | #i #l #m #_ #I #V1 #U1 #H destruct
 124 | #p #l #m #I #V1 #U1 #H destruct
 125 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V1 #U1 #H destruct
 126 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 127 ]
 128 qed-.
 129
 130 lemma lift_inv_flat1: ∀l,m,T2,I,V1,U1. ⬆[l, m] ⓕ{I}V1.U1 ≡ T2 →
 131                       ∃∃V2,U2. ⬆[l, m] V1 ≡ V2 & ⬆[l, m] U1 ≡ U2 &
 132                                T2 = ⓕ{I}V2.U2.
 133 /2 width=3 by lift_inv_flat1_aux/ qed-.
 134
 135 fact lift_inv_sort2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 136 #l #m #T1 #T2 * -l -m -T1 -T2 //
 137 [ #i #l #m #_ #k #H destruct
 138 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 139 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 140 ]
 141 qed-.
 142
 143 (* Basic_1: was: lift_gen_sort *)
 144 lemma lift_inv_sort2: ∀l,m,T1,k. ⬆[l, m] T1 ≡ ⋆k → T1 = ⋆k.
 145 /2 width=5 by lift_inv_sort2_aux/ qed-.
 146
 147 fact lift_inv_lref2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀i. T2 = #i →
 148                          (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 149 #l #m #T1 #T2 * -l -m -T1 -T2
 150 [ #k #l #m #i #H destruct
 151 | #j #l #m #Hj #i #Hi destruct /3 width=1 by or_introl, conj/
 152 | #j #l #m #Hj #i #Hi destruct <minus_plus_m_m /4 width=1 by monotonic_yle_plus_dx, or_intror, conj/
 153 | #p #l #m #i #H destruct
 154 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 155 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #i #H destruct
 156 ]
 157 qed-.
 158
 159 (* Basic_1: was: lift_gen_lref *)
 160 lemma lift_inv_lref2: ∀l,m,T1,i. ⬆[l, m] T1 ≡ #i →
 161                       (i < l ∧ T1 = #i) ∨ (l + m ≤ i ∧ T1 = #(i - m)).
 162 /2 width=3 by lift_inv_lref2_aux/ qed-.
 163
 164 (* Basic_1: was: lift_gen_lref_lt *)
 165 lemma lift_inv_lref2_lt: ∀l,m,T1,i. ⬆[l, m] T1 ≡ #i → i < l → T1 = #i.
 166 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 167 #H #_ #Hil lapply (yle_fwd_plus_sn1 … H) -H
 168 #Hli elim (ylt_yle_false … Hli) -Hli //
 169 qed-.
 170
 171 (* Basic_1: was: lift_gen_lref_false *)
 172 lemma lift_inv_lref2_be: ∀l,m,T1,i. ⬆[l, m] T1 ≡ #i →
 173                          l ≤ i → i < l + m → ⊥.
 174 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H *
 175 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 176 elim (ylt_yle_false … H2) -H2 //
 177 qed-.
 178
 179 (* Basic_1: was: lift_gen_lref_ge *)
 180 lemma lift_inv_lref2_ge: ∀l,m,T1,i. ⬆[l, m] T1 ≡ #i → l + m ≤ i → T1 = #(i - m).
 181 #l #m #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 182 #Hil #_ #H lapply (yle_fwd_plus_sn1 … H) -H
 183 #Hli elim (ylt_yle_false … Hli) -Hli //
 184 qed-.
 185
 186 fact lift_inv_gref2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 187 #l #m #T1 #T2 * -l -m -T1 -T2 //
 188 [ #i #l #m #_ #k #H destruct
 189 | #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 190 | #I #V1 #V2 #T1 #T2 #l #m #_ #_ #k #H destruct
 191 ]
 192 qed-.
 193
 194 lemma lift_inv_gref2: ∀l,m,T1,p. ⬆[l, m] T1 ≡ §p → T1 = §p.
 195 /2 width=5 by lift_inv_gref2_aux/ qed-.
 196
 197 fact lift_inv_bind2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 →
 198                          ∀a,I,V2,U2. T2 = ⓑ{a,I}V2.U2 →
 199                          ∃∃V1,U1. ⬆[l, m] V1 ≡ V2 & ⬆[⫯l, m] U1 ≡ U2 &
 200                                   T1 = ⓑ{a,I}V1.U1.
 201 #l #m #T1 #T2 * -l -m -T1 -T2
 202 [ #k #l #m #a #I #V2 #U2 #H destruct
 203 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 204 | #i #l #m #_ #a #I #V2 #U2 #H destruct
 205 | #p #l #m #a #I #V2 #U2 #H destruct
 206 | #b #J #W1 #W2 #T1 #T2 #l #m #HW #HT #a #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 207 | #J #W1 #W2 #T1 #T2 #l #m #_ #_ #a #I #V2 #U2 #H destruct
 208 ]
 209 qed-.
 210
 211 (* Basic_1: was: lift_gen_bind *)
 212 lemma lift_inv_bind2: ∀l,m,T1,a,I,V2,U2. ⬆[l, m] T1 ≡ ⓑ{a,I}V2.U2 →
 213                       ∃∃V1,U1. ⬆[l, m] V1 ≡ V2 & ⬆[⫯l, m] U1 ≡ U2 &
 214                                T1 = ⓑ{a,I}V1.U1.
 215 /2 width=3 by lift_inv_bind2_aux/ qed-.
 216
 217 fact lift_inv_flat2_aux: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 →
 218                          ∀I,V2,U2. T2 = ⓕ{I}V2.U2 →
 219                          ∃∃V1,U1. ⬆[l, m] V1 ≡ V2 & ⬆[l, m] U1 ≡ U2 &
 220                                   T1 = ⓕ{I}V1.U1.
 221 #l #m #T1 #T2 * -l -m -T1 -T2
 222 [ #k #l #m #I #V2 #U2 #H destruct
 223 | #i #l #m #_ #I #V2 #U2 #H destruct
 224 | #i #l #m #_ #I #V2 #U2 #H destruct
 225 | #p #l #m #I #V2 #U2 #H destruct
 226 | #a #J #W1 #W2 #T1 #T2 #l #m #_ #_ #I #V2 #U2 #H destruct
 227 | #J #W1 #W2 #T1 #T2 #l #m #HW #HT #I #V2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 228 ]
 229 qed-.
 230
 231 (* Basic_1: was: lift_gen_flat *)
 232 lemma lift_inv_flat2: ∀l,m,T1,I,V2,U2. ⬆[l, m] T1 ≡  ⓕ{I}V2.U2 →
 233                       ∃∃V1,U1. ⬆[l, m] V1 ≡ V2 & ⬆[l, m] U1 ≡ U2 &
 234                                T1 = ⓕ{I}V1.U1.
 235 /2 width=3 by lift_inv_flat2_aux/ qed-.
 236
 237 lemma lift_inv_Y1: ∀T1,T2,m. ⬆[∞, m] T1 ≡ T2 → T1 = T2.
 238 #T1 elim T1 -T1 *
 239 [ #k #X #m #H lapply (lift_inv_sort1 … H) -H //
 240 | #i #X #m #H lapply (lift_inv_lref1_lt … H ?) -H //
 241 | #p #X #m #H lapply (lift_inv_gref1 … H) -H //
 242 | #a #I #V1 #T1 #IHV1 #IHT1 #X #m #H elim (lift_inv_bind1 … H) -H
 243   #V2 #T2 #HV12 #HT12 #H destruct /3 width=2 by eq_f2/
 244 | #I #V1 #T1 #IHV1 #IHT1 #X #m #H elim (lift_inv_flat1 … H) -H
 245   #V2 #T2 #HV12 #HT12 #H destruct /3 width=2 by eq_f2/
 246 ]
 247 qed-.
 248
 249 lemma lift_inv_pair_xy_x: ∀l,m,I,V,T. ⬆[l,  m] ②{I}V.T ≡ V → ⊥.
 250 #l #m #J #V elim V -V
 251 [ * #i #T #H
 252   [ lapply (lift_inv_sort2 … H) -H #H destruct
 253   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 254   | lapply (lift_inv_gref2 … H) -H #H destruct
 255   ]
 256 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 257   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 258   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2 by/
 259   ]
 260 ]
 261 qed-.
 262
 263 (* Basic_1: was: thead_x_lift_y_y *)
 264 lemma lift_inv_pair_xy_y: ∀I,T,V,l,m. ⬆[l, m] ②{I}V.T ≡ T → ⊥.
 265 #J #T elim T -T
 266 [ * #i #V #l #m #H
 267   [ lapply (lift_inv_sort2 … H) -H #H destruct
 268   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 269   | lapply (lift_inv_gref2 … H) -H #H destruct
 270   ]
 271 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #l #m #H
 272   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 273   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4 by/
 274   ]
 275 ]
 276 qed-.
 277
 278 (* Basic forward lemmas *****************************************************)
 279
 280 lemma lift_fwd_pair1: ∀I,T2,V1,U1,l,m. ⬆[l, m] ②{I}V1.U1 ≡ T2 →
 281                       ∃∃V2,U2. ⬆[l, m] V1 ≡ V2 & T2 = ②{I}V2.U2.
 282 * [ #a ] #I #T2 #V1 #U1 #l #m #H
 283 [ elim (lift_inv_bind1 … H) -H /2 width=4 by ex2_2_intro/
 284 |  elim (lift_inv_flat1 … H) -H /2 width=4 by ex2_2_intro/
 285 ]
 286 qed-.
 287
 288 lemma lift_fwd_pair2: ∀I,T1,V2,U2,l,m. ⬆[l, m] T1 ≡ ②{I}V2.U2 →
 289                       ∃∃V1,U1. ⬆[l, m] V1 ≡ V2 & T1 = ②{I}V1.U1.
 290 * [ #a ] #I #T1 #V2 #U2 #l #m #H
 291 [ elim (lift_inv_bind2 … H) -H /2 width=4 by ex2_2_intro/
 292 |  elim (lift_inv_flat2 … H) -H /2 width=4 by ex2_2_intro/
 293 ]
 294 qed-.
 295
 296 lemma lift_fwd_tw: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → ♯{T1} = ♯{T2}.
 297 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 normalize //
 298 qed-.
 299
 300 lemma lift_simple_dx: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 301 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 302 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 303 elim (simple_inv_bind … H)
 304 qed-.
 305
 306 lemma lift_simple_sn: ∀l,m,T1,T2. ⬆[l, m] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 307 #l #m #T1 #T2 #H elim H -l -m -T1 -T2 //
 308 #a #I #V1 #V2 #T1 #T2 #l #m #_ #_ #_ #_ #H
 309 elim (simple_inv_bind … H)
 310 qed-.
 311
 312 (* Basic properties *********************************************************)
 313
 314 (* Basic_1: was: lift_lref_gt *)
 315 lemma lift_lref_ge_minus: ∀l,m,i. l + yinj m ≤ yinj i → ⬆[l, m] #(i - m) ≡ #i.
 316 #l #m #i #H >(plus_minus_m_m i m) in ⊢ (? ? ? ? %);
 317 elim (yle_inv_plus_inj2 … H) -H #Hlim #H
 318 lapply (yle_inv_inj … H) -H /2 width=1 by lift_lref_ge/
 319 qed.
 320
 321 lemma lift_lref_ge_minus_eq: ∀l,m,i,j. l + yinj m ≤ yinj i → j = i - m → ⬆[l, m] #j ≡ #i.
 322 /2 width=1 by lift_lref_ge_minus/ qed-.
 323
 324 (* Basic_1: was: lift_r *)
 325 lemma lift_refl: ∀T,l. ⬆[l, 0] T ≡ T.
 326 #T elim T -T
 327 [ * #i // #l elim (ylt_split i l) /2 width=1 by lift_lref_lt, lift_lref_ge/
 328 | * /2 width=1 by lift_bind, lift_flat/
 329 ]
 330 qed.
 331
 332 (* Basic_2b: first lemma *)
 333 lemma lift_Y1: ∀T,m. ⬆[∞, m] T ≡ T.
 334 #T elim T -T * /2 width=1 by lift_lref_lt, lift_bind, lift_flat/
 335 qed.
 336
 337 lemma lift_total: ∀T1,l,m. ∃T2. ⬆[l, m] T1 ≡ T2.
 338 #T1 elim T1 -T1
 339 [ * #i /2 width=2 by lift_sort, lift_gref, ex_intro/
 340   #l #m elim (ylt_split i l) /3 width=2 by lift_lref_lt, lift_lref_ge, ex_intro/
 341 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #l #m
 342   elim (IHV1 l m) -IHV1 #V2 #HV12
 343   [ elim (IHT1 (⫯l) m) -IHT1 /3 width=2 by lift_bind, ex_intro/
 344   | elim (IHT1 l m) -IHT1 /3 width=2 by lift_flat, ex_intro/
 345   ]
 346 ]
 347 qed.
 348
 349 (* Basic_1: was: lift_free (right to left) *)
 350 lemma lift_split: ∀l1,m2,T1,T2. ⬆[l1, m2] T1 ≡ T2 →
 351                   ∀l2,m1. l1 ≤ l2 → l2 ≤ l1 + yinj m1 → m1 ≤ m2 →
 352                   ∃∃T. ⬆[l1, m1] T1 ≡ T & ⬆[l2, m2 - m1] T ≡ T2.
 353 #l1 #m2 #T1 #T2 #H elim H -l1 -m2 -T1 -T2
 354 [ /3 width=3 by lift_sort, ex2_intro/
 355 | #i #l1 #m2 #Hil1 #l2 #m1 #Hl12 #_ #_
 356   lapply (ylt_yle_trans … Hl12 Hil1) -Hl12 #Hil2 /4 width=3 by lift_lref_lt, ex2_intro/
 357 | #i #l1 #m2 #Hil1 #l2 #m1 #_ #Hl21 #Hm12
 358   lapply (yle_trans … Hl21 (i+m1) ?) /2 width=1 by monotonic_yle_plus_dx/ -Hl21 #Hl21
 359   >(plus_minus_m_m m2 m1 ?) /3 width=3 by lift_lref_ge, ex2_intro/
 360 | /3 width=3 by lift_gref, ex2_intro/
 361 | #a #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 362   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 363   elim (IHT (⫯l2) … ? ? Hm12) /3 width=5 by lift_bind, yle_succ, ex2_intro/
 364 | #I #V1 #V2 #T1 #T2 #l1 #m2 #_ #_ #IHV #IHT #l2 #m1 #Hl12 #Hl21 #Hm12
 365   elim (IHV … Hl12 Hl21 Hm12) -IHV #V0 #HV0a #HV0b
 366   elim (IHT l2 … ? ? Hm12) /3 width=5 by lift_flat, ex2_intro/
 367 ]
 368 qed.
 369
 370 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 371 lemma is_lift_dec: ∀T2,l,m. Decidable (∃T1. ⬆[l, m] T1 ≡ T2).
 372 #T1 elim T1 -T1
 373 [ * [1,3: /3 width=2 by lift_sort, lift_gref, ex_intro, or_introl/ ] #i #l #m
 374   elim (ylt_split i l) #Hli
 375   [ /4 width=3 by lift_lref_lt, ex_intro, or_introl/
 376   | elim (ylt_split i (l + m)) #Hilm
 377     [ @or_intror * #T1 #H elim (lift_inv_lref2_be … H Hli Hilm)
 378     | -Hli /4 width=2 by lift_lref_ge_minus, ex_intro, or_introl/
 379     ]
 380   ]
 381 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #l #m
 382   [ elim (IHV2 l m) -IHV2
 383     [ * #V1 #HV12 elim (IHT2 (⫯l) m) -IHT2
 384       [ * #T1 #HT12 @or_introl /3 width=2 by lift_bind, ex_intro/
 385       | -V1 #HT2 @or_intror * #X #H
 386         elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 387       ]
 388     | -IHT2 #HV2 @or_intror * #X #H
 389       elim (lift_inv_bind2 … H) -H /3 width=2 by ex_intro/
 390     ]
 391   | elim (IHV2 l m) -IHV2
 392     [ * #V1 #HV12 elim (IHT2 l m) -IHT2
 393       [ * #T1 #HT12 /4 width=2 by lift_flat, ex_intro, or_introl/
 394       | -V1 #HT2 @or_intror * #X #H
 395         elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 396       ]
 397     | -IHT2 #HV2 @or_intror * #X #H
 398       elim (lift_inv_flat2 … H) -H /3 width=2 by ex_intro/
 399     ]
 400   ]
 401 ]
 402 qed.
 403
 404 (* Basic_1: removed theorems 7:
 405             lift_head lift_gen_head
 406             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 407             lift_tlt_dx
 408 *)