matita/matita/contribs/lambdadelta/basic_2/syntax/append_length.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/lenv_length.ma".
  16 include "basic_2/syntax/append.ma".
  17
  18 (* APPEND FOR LOCAL ENVIRONMENTS ********************************************)
  19
  20 (* Properties with length for local environments ****************************)
  21
  22 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  23 #L1 #L2 elim L2 -L2 //
  24 #L2 #I #V2 >append_pair >length_pair >length_pair //
  25 qed.
  26
  27 lemma ltail_length: ∀I,L,V. |ⓑ{I}V.L| = ⫯|L|.
  28 #I #L #V >append_length //
  29 qed.
  30
  31 (* Basic_1: was just: chead_ctail *)
  32 lemma lpair_ltail: ∀L,I,V. ∃∃J,K,W. L.ⓑ{I}V = ⓑ{J}W.K & |L| = |K|.
  33 #L elim L -L /2 width=5 by ex2_3_intro/
  34 #L #Z #X #IHL #I #V elim (IHL Z X) -IHL
  35 #J #K #W #H #_ >H -H >ltail_length
  36 @(ex2_3_intro … J (K.ⓑ{I}V) W) /2 width=1 by length_pair/
  37 qed-.
  38
  39 (* Advanced inversion lemmas on length for local environments ***************)
  40
  41 (* Basic_2A1: was: length_inv_pos_dx_ltail *)
  42 lemma length_inv_succ_dx_ltail: ∀L,l. |L| = ⫯l →
  43                                 ∃∃I,K,V. |K| = l & L = ⓑ{I}V.K.
  44 #Y #l #H elim (length_inv_succ_dx … H) -H #I #L #V #Hl #HLK destruct
  45 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
  46 qed-.
  47
  48 (* Basic_2A1: was: length_inv_pos_sn_ltail *)
  49 lemma length_inv_succ_sn_ltail: ∀L,l. ⫯l = |L| →
  50                                 ∃∃I,K,V. l = |K| & L = ⓑ{I}V.K.
  51 #Y #l #H elim (length_inv_succ_sn … H) -H #I #L #V #Hl #HLK destruct
  52 elim (lpair_ltail L I V) /2 width=5 by ex2_3_intro/
  53 qed-.
  54
  55 (* Inversion lemmas with length for local environments **********************)
  56
  57 (* Basic_2A1: was: append_inj_sn *)
  58 lemma append_inj_length_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  59                             L1 = L2 ∧ K1 = K2.
  60 #K1 elim K1 -K1
  61 [ * /2 width=1 by conj/
  62   #K2 #I2 #V2 #L1 #L2 #_ >length_atom >length_pair
  63   #H destruct
  64 | #K1 #I1 #V1 #IH *
  65   [ #L1 #L2 #_ >length_atom >length_pair
  66     #H destruct
  67   | #K2 #I2 #V2 #L1 #L2 #H1 >length_pair >length_pair #H2
  68     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  69     elim (IH … H1) -IH -H1 /3 width=4 by conj/
  70   ]
  71 ]
  72 qed-.
  73
  74 (* Note: lemma 750 *)
  75 (* Basic_2A1: was: append_inj_dx *)
  76 lemma append_inj_length_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  77                             L1 = L2 ∧ K1 = K2.
  78 #K1 elim K1 -K1
  79 [ * /2 width=1 by conj/
  80   #K2 #I2 #V2 #L1 #L2 >append_atom >append_pair #H destruct
  81   >length_pair >append_length >plus_n_Sm
  82   #H elim (plus_xSy_x_false … H)
  83 | #K1 #I1 #V1 #IH *
  84   [ #L1 #L2 >append_pair >append_atom #H destruct
  85     >length_pair >append_length >plus_n_Sm #H
  86     lapply (discr_plus_x_xy … H) -H #H destruct
  87   | #K2 #I2 #V2 #L1 #L2 >append_pair >append_pair #H1 #H2
  88     elim (destruct_lpair_lpair_aux … H1) -H1 #H1 #H3 #H4 destruct (**) (* destruct lemma needed *)
  89     elim (IH … H1) -IH -H1 /2 width=1 by conj/
  90   ]
  91 ]
  92 qed-.
  93
  94 (* Advanced inversion lemmas ************************************************)
  95
  96 lemma append_inj_dx: ∀L,K1,K2. L@@K1 = L@@K2 → K1 = K2.
  97 #L #K1 #K2 #H elim (append_inj_length_dx … H) -H //
  98 qed-.
  99
 100 lemma append_inv_refl_dx: ∀L,K. L@@K = L → K = ⋆.
 101 #L #K #H elim (append_inj_dx … (⋆) … H) //
 102 qed-.
 103
 104 lemma append_inv_pair_dx: ∀I,L,K,V. L@@K = L.ⓑ{I}V → K = ⋆.ⓑ{I}V.
 105 #I #L #K #V #H elim (append_inj_dx … (⋆.ⓑ{I}V) … H) //
 106 qed-.
 107
 108 (* Basic eliminators ********************************************************)
 109
 110 (* Basic_1: was: c_tail_ind *)
 111 lemma lenv_ind_alt: ∀R:predicate lenv.
 112                     R (⋆) → (∀I,L,T. R L → R (ⓑ{I}T.L)) →
 113                     ∀L. R L.
 114 #R #IH1 #IH2 #L @(f_ind … length … L) -L #x #IHx * // -IH1
 115 #L #I #V #H destruct elim (lpair_ltail L I V) /4 width=1 by/
 116 qed-.