matita/matita/contribs/lambdadelta/basic_2/syntax/tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazyeq_4.ma".
  16 include "basic_2/syntax/item_sd.ma".
  17 include "basic_2/syntax/lenv.ma".
  18
  19 (* DEGREE-BASED EQUIVALENCE ON TERMS ****************************************)
  20
  21 inductive tdeq (h) (o): relation term ≝
  22 | tdeq_sort: ∀s1,s2,d. deg h o s1 d → deg h o s2 d → tdeq h o (⋆s1) (⋆s2)
  23 | tdeq_lref: ∀i. tdeq h o (#i) (#i)
  24 | tdeq_gref: ∀l. tdeq h o (§l) (§l)
  25 | tdeq_pair: ∀I,V1,V2,T1,T2. tdeq h o V1 V2 → tdeq h o T1 T2 → tdeq h o (②{I}V1.T1) (②{I}V2.T2)
  26 .
  27
  28 interpretation
  29    "degree-based equivalence (terms)"
  30    'LazyEq h o T1 T2 = (tdeq h o T1 T2).
  31
  32 definition cdeq: ∀h. sd h → relation3 lenv term term ≝
  33                  λh,o,L. tdeq h o.
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tdeq_refl: ∀h,o. reflexive … (tdeq h o).
  38 #h #o #T elim T -T /2 width=1 by tdeq_pair/
  39 * /2 width=1 by tdeq_lref, tdeq_gref/
  40 #s elim (deg_total h o s) /2 width=3 by tdeq_sort/
  41 qed.
  42
  43 lemma tdeq_sym: ∀h,o. symmetric … (tdeq h o).
  44 #h #o #T1 #T2 #H elim H -T1 -T2
  45 /2 width=3 by tdeq_sort, tdeq_lref, tdeq_gref, tdeq_pair/
  46 qed-.
  47
  48 (* Basic inversion lemmas ***************************************************)
  49
  50 fact tdeq_inv_sort1_aux: ∀h,o,X,Y. X ≡[h, o] Y → ∀s1. X = ⋆s1 →
  51                          ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  52 #h #o #X #Y * -X -Y
  53 [ #s1 #s2 #d #Hs1 #Hs2 #s #H destruct /2 width=5 by ex3_2_intro/
  54 | #i #s #H destruct
  55 | #l #s #H destruct
  56 | #I #V1 #V2 #T1 #T2 #_ #_ #s #H destruct
  57 ]
  58 qed-.
  59
  60 lemma tdeq_inv_sort1: ∀h,o,Y,s1. ⋆s1 ≡[h, o] Y →
  61                       ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  62 /2 width=3 by tdeq_inv_sort1_aux/ qed-.
  63
  64 fact tdeq_inv_lref1_aux: ∀h,o,X,Y. X ≡[h, o] Y → ∀i. X = #i → Y = #i.
  65 #h #o #X #Y * -X -Y //
  66 [ #s1 #s2 #d #_ #_ #j #H destruct
  67 | #I #V1 #V2 #T1 #T2 #_ #_ #j #H destruct
  68 ]
  69 qed-.
  70
  71 lemma tdeq_inv_lref1: ∀h,o,Y,i. #i ≡[h, o] Y → Y = #i.
  72 /2 width=5 by tdeq_inv_lref1_aux/ qed-.
  73
  74 fact tdeq_inv_gref1_aux: ∀h,o,X,Y. X ≡[h, o] Y → ∀l. X = §l → Y = §l.
  75 #h #o #X #Y * -X -Y //
  76 [ #s1 #s2 #d #_ #_ #k #H destruct
  77 | #I #V1 #V2 #T1 #T2 #_ #_ #k #H destruct
  78 ]
  79 qed-.
  80
  81 lemma tdeq_inv_gref1: ∀h,o,Y,l. §l ≡[h, o] Y → Y = §l.
  82 /2 width=5 by tdeq_inv_gref1_aux/ qed-.
  83
  84 fact tdeq_inv_pair1_aux: ∀h,o,X,Y. X ≡[h, o] Y → ∀I,V1,T1. X = ②{I}V1.T1 →
  85                          ∃∃V2,T2. V1 ≡[h, o] V2 & T1 ≡[h, o] T2 & Y = ②{I}V2.T2.
  86 #h #o #X #Y * -X -Y
  87 [ #s1 #s2 #d #_ #_ #J #W1 #U1 #H destruct
  88 | #i #J #W1 #U1 #H destruct
  89 | #l #J #W1 #U1 #H destruct
  90 | #I #V1 #V2 #T1 #T2 #HV #HT #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
  91 ]
  92 qed-.
  93
  94 lemma tdeq_inv_pair1: ∀h,o,I,V1,T1,Y. ②{I}V1.T1 ≡[h, o] Y →
  95                       ∃∃V2,T2. V1 ≡[h, o] V2 & T1 ≡[h, o] T2 & Y = ②{I}V2.T2.
  96 /2 width=3 by tdeq_inv_pair1_aux/ qed-.
  97
  98 (* Advanced inversion lemmas ************************************************)
  99
 100 lemma tdeq_inv_sort1_deg: ∀h,o,Y,s1. ⋆s1 ≡[h, o] Y → ∀d. deg h o s1 d →
 101                           ∃∃s2. deg h o s2 d & Y = ⋆s2.
 102 #h #o #Y #s1 #H #d #Hs1 elim (tdeq_inv_sort1 … H) -H
 103 #s2 #x #Hx <(deg_mono h o … Hx … Hs1) -s1 -d /2 width=3 by ex2_intro/
 104 qed-.
 105
 106 (* Basic forward lemmas *****************************************************)
 107
 108 lemma tdeq_fwd_atom1: ∀h,o,I,Y. ⓪{I} ≡[h, o] Y → ∃J. Y = ⓪{J}.
 109 #h #o * #x #Y #H [ elim (tdeq_inv_sort1 … H) -H ]
 110 /3 width=4 by tdeq_inv_gref1, tdeq_inv_lref1, ex_intro/
 111 qed-.