matita/matita/contribs/lambdadelta/basic_2/unfold/cpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/cpss.ma".
  16
  17 (* CONTEXT-SENSITIVE RESTRICTED PARALLEL COMPUTATION FOR TERMS **************)
  18
  19 inductive cpqs: lenv → relation term ≝
  20 | cpqs_atom : ∀I,L. cpqs L (⓪{I}) (⓪{I})
  21 | cpqs_delta: ∀L,K,V,V2,W2,i.
  22               ⇩[0, i] L ≡ K. ⓓV → cpqs K V V2 →
  23               ⇧[0, i + 1] V2 ≡ W2 → cpqs L (#i) W2
  24 | cpqs_bind : ∀a,I,L,V1,V2,T1,T2.
  25               cpqs L V1 V2 → cpqs (L. ⓑ{I} V1) T1 T2 →
  26               cpqs L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | cpqs_flat : ∀I,L,V1,V2,T1,T2.
  28               cpqs L V1 V2 → cpqs L T1 T2 →
  29               cpqs L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 | cpqs_zeta : ∀L,V,T1,T,T2. cpqs (L.ⓓV) T1 T →
  31               ⇧[0, 1] T2 ≡ T → cpqs L (+ⓓV. T1) T2
  32 | cpqs_tau  : ∀L,V,T1,T2. cpqs L T1 T2 → cpqs L (ⓝV. T1) T2
  33 .
  34
  35 interpretation "context-sensitive restricted parallel computation (term)"
  36    'PRestStar L T1 T2 = (cpqs L T1 T2).
  37
  38 (* Basic properties *********************************************************)
  39
  40 lemma cpqs_lsubr_trans: lsub_trans … cpqs lsubr.
  41 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  42 [ //
  43 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  44   elim (lsubr_fwd_ldrop2_abbr … HL12 … HLK1) -HL12 -HLK1 /3 width=6/
  45 | /4 width=1/
  46 |4,6: /3 width=1/
  47 | /4 width=3/
  48 ]
  49 qed-.
  50
  51 lemma cpss_cpqs: ∀L,T1,T2. L ⊢ T1 ▶* T2 → L ⊢ T1 ➤* T2.
  52 #L #T1 #T2 #H elim H -L -T1 -T2 // /2 width=1/ /2 width=6/
  53 qed.
  54
  55 lemma cpqs_refl: ∀T,L. L ⊢ T ➤* T.
  56 /2 width=1/ qed.
  57
  58 lemma cpqs_delift: ∀L,K,V,T1,d. ⇩[0, d] L ≡ (K. ⓓV) →
  59                    ∃∃T2,T. L ⊢ T1 ➤* T2 & ⇧[d, 1] T ≡ T2.
  60 #L #K #V #T1 #d #HLK
  61 elim (cpss_delift … T1 … HLK) -HLK /3 width=4/
  62 qed-.
  63
  64 lemma cpqs_append: l_appendable_sn … cpqs.
  65 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/ /2 width=3/
  66 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  67 lapply (ldrop_fwd_length_lt2 … HK0) #H
  68 @(cpqs_delta … (L@@K0) V1 … HVW2) //
  69 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  70 qed.
  71
  72 (* Basic inversion lemmas ***************************************************)
  73
  74 fact cpqs_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ➤* T2 → ∀I. T1 = ⓪{I} →
  75                          T2 = ⓪{I} ∨
  76                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  77                                      K ⊢ V ➤* V2 &
  78                                      ⇧[O, i + 1] V2 ≡ T2 &
  79                                      I = LRef i.
  80 #L #T1 #T2 * -L -T1 -T2
  81 [ #I #L #J #H destruct /2 width=1/
  82 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8/
  83 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  84 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  85 | #L #V #T1 #T #T2 #_ #_ #J #H destruct
  86 | #L #V #T1 #T2 #_ #J #H destruct
  87 ]
  88 qed-.
  89
  90 lemma cpqs_inv_atom1: ∀I,L,T2. L ⊢ ⓪{I} ➤* T2 →
  91                       T2 = ⓪{I} ∨
  92                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  93                                   K ⊢ V ➤* V2 &
  94                                   ⇧[O, i + 1] V2 ≡ T2 &
  95                                   I = LRef i.
  96 /2 width=3 by cpqs_inv_atom1_aux/ qed-.
  97
  98 lemma cpqs_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ➤* T2 → T2 = ⋆k.
  99 #L #T2 #k #H
 100 elim (cpqs_inv_atom1 … H) -H //
 101 * #K #V #V2 #i #_ #_ #_ #H destruct
 102 qed-.
 103
 104 lemma cpqs_inv_lref1: ∀L,T2,i. L ⊢ #i ➤* T2 →
 105                       T2 = #i ∨
 106                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 107                                 K ⊢ V ➤* V2 &
 108                                 ⇧[O, i + 1] V2 ≡ T2.
 109 #L #T2 #i #H
 110 elim (cpqs_inv_atom1 … H) -H /2 width=1/
 111 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 112 qed-.
 113
 114 lemma cpqs_inv_gref1: ∀L,T2,p. L ⊢ §p ➤* T2 → T2 = §p.
 115 #L #T2 #p #H
 116 elim (cpqs_inv_atom1 … H) -H //
 117 * #K #V #V2 #i #_ #_ #_ #H destruct
 118 qed-.
 119
 120 fact cpqs_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 121                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 → (
 122                          ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 123                                   L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 124                                   U2 = ⓑ{a,I} V2. T2
 125                          ) ∨
 126                          ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 127 #L #U1 #U2 * -L -U1 -U2
 128 [ #I #L #b #J #W1 #U1 #H destruct
 129 | #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W1 #U1 #H destruct
 130 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W1 #U1 #H destruct /3 width=5/
 131 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W1 #U1 #H destruct
 132 | #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W1 #U1 #H destruct /3 width=3/
 133 | #L #V #T1 #T2 #_ #b #J #W1 #U1 #H destruct
 134 ]
 135 qed-.
 136
 137 lemma cpqs_inv_bind1: ∀a,I,L,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ➤* U2 → (
 138                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 139                                L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 140                                U2 = ⓑ{a,I} V2. T2
 141                       ) ∨
 142                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 143 /2 width=3 by cpqs_inv_bind1_aux/ qed-.
 144
 145 lemma cpqs_inv_abbr1: ∀a,L,V1,T1,U2. L ⊢ ⓓ{a} V1. T1 ➤* U2 → (
 146                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 147                                L. ⓓ V1 ⊢ T1 ➤* T2 &
 148                                U2 = ⓓ{a} V2. T2
 149                       ) ∨
 150                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true.
 151 #a #L #V1 #T1 #U2 #H
 152 elim (cpqs_inv_bind1 … H) -H * /3 width=3/ /3 width=5/
 153 qed-.
 154
 155 lemma cpqs_inv_abst1: ∀a,L,V1,T1,U2. L ⊢ ⓛ{a} V1. T1 ➤* U2 →
 156                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 157                                L. ⓛ V1 ⊢ T1 ➤* T2 &
 158                                U2 = ⓛ{a} V2. T2.
 159 #a #L #V1 #T1 #U2 #H
 160 elim (cpqs_inv_bind1 … H) -H *
 161 [ /3 width=5/
 162 | #T #_ #_ #_ #H destruct
 163 ]
 164 qed-.
 165
 166 fact cpqs_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 167                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 → (
 168                          ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 169                                   U2 = ⓕ{I} V2. T2
 170                          ) ∨
 171                          (L ⊢ T1 ➤* U2 ∧ I = Cast).
 172 #L #U1 #U2 * -L -U1 -U2
 173 [ #I #L #J #W1 #U1 #H destruct
 174 | #L #K #V #V2 #W2 #i #_ #_ #_ #J #W1 #U1 #H destruct
 175 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 176 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /3 width=5/
 177 | #L #V #T1 #T #T2 #_ #_ #J #W1 #U1 #H destruct
 178 | #L #V #T1 #T2 #HT12 #J #W1 #U1 #H destruct /3 width=1/
 179 ]
 180 qed-.
 181
 182 lemma cpqs_inv_flat1: ∀I,L,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ➤* U2 → (
 183                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 184                                U2 = ⓕ{I} V2. T2
 185                       ) ∨
 186                       (L ⊢ T1 ➤* U2 ∧ I = Cast).
 187 /2 width=3 by cpqs_inv_flat1_aux/ qed-.
 188
 189 lemma cpqs_inv_appl1: ∀L,V1,T1,U2. L ⊢ ⓐ V1. T1 ➤* U2 →
 190                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 191                                U2 = ⓐ V2. T2.
 192 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H *
 193 [ /3 width=5/
 194 | #_ #H destruct
 195 ]
 196 qed-.
 197
 198 lemma cpqs_inv_cast1: ∀L,V1,T1,U2. L ⊢ ⓝ V1. T1 ➤* U2 → (
 199                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 200                                U2 = ⓝ V2. T2
 201                       ) ∨
 202                       L ⊢ T1 ➤* U2.
 203 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H * /2 width=1/ /3 width=5/
 204 qed-.
 205
 206 (* Basic forward lemmas *****************************************************)
 207
 208 lemma cpqs_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ➤* T →
 209                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 210 #L1 @(lenv_ind_dx … L1) -L1 normalize
 211 [ #L #T1 #T #HT1
 212   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 213 | #I #L1 #V1 #IH #L #T1 #X
 214   >shift_append_assoc normalize #H
 215   elim (cpqs_inv_bind1 … H) -H *
 216   [ #V0 #T0 #_ #HT10 #H destruct
 217     elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 218     >append_length >HL12 -HL12
 219     @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 220   | #T #_ #_ #H destruct
 221   ]
 222 ]
 223 qed-.