matita/matita/contribs/lambdadelta/basic_2/unfold/cpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/cpss.ma".
  16
  17 (* CONTEXT-SENSITIVE RESTRICTED PARALLEL COMPUTATION FOR TERMS **************)
  18
  19 inductive cpqs: lenv → relation term ≝
  20 | cpqs_atom : ∀I,L. cpqs L (⓪{I}) (⓪{I})
  21 | cpqs_delta: ∀L,K,V,V2,W2,i.
  22               ⇩[0, i] L ≡ K. ⓓV → cpqs K V V2 →
  23               ⇧[0, i + 1] V2 ≡ W2 → cpqs L (#i) W2
  24 | cpqs_bind : ∀a,I,L,V1,V2,T1,T2.
  25               cpqs L V1 V2 → cpqs (L. ⓑ{I} V1) T1 T2 →
  26               cpqs L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | cpqs_flat : ∀I,L,V1,V2,T1,T2.
  28               cpqs L V1 V2 → cpqs L T1 T2 →
  29               cpqs L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 | cpqs_zeta : ∀L,V,T1,T,T2. cpqs (L.ⓓV) T1 T →
  31               ⇧[0, 1] T2 ≡ T → cpqs L (+ⓓV. T1) T2
  32 | cpqs_tau  : ∀L,V,T1,T2. cpqs L T1 T2 → cpqs L (ⓝV. T1) T2
  33 .
  34
  35 interpretation "context-sensitive restricted parallel computation (term)"
  36    'PRestStar L T1 T2 = (cpqs L T1 T2).
  37
  38 (* Basic properties *********************************************************)
  39
  40 (* Note: it does not hold replacing |L1| with |L2| *)
  41 lemma cpqs_lsubr_trans: ∀L1,T1,T2. L1 ⊢ T1 ➤* T2 →
  42                         ∀L2. L2 ⊑ [0, |L1|] L1 → L2 ⊢ T1 ➤* T2.
  43 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  44 [ //
  45 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  46   lapply (ldrop_fwd_ldrop2_length … HLK1) #Hi
  47   lapply (ldrop_fwd_O1_length … HLK1) #H2i
  48   elim (ldrop_lsubr_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // -Hi
  49   <H2i -H2i <minus_plus_m_m /3 width=6/
  50 | /4 width=1/
  51 |4,6: /3 width=1/
  52 | /4 width=3/
  53 ]
  54 qed-.
  55
  56 lemma cpss_cpqs: ∀L,T1,T2. L ⊢ T1 ▶* T2 → L ⊢ T1 ➤* T2.
  57 #L #T1 #T2 #H elim H -L -T1 -T2 // /2 width=1/ /2 width=6/
  58 qed.
  59
  60 lemma cpqs_refl: ∀T,L. L ⊢ T ➤* T.
  61 /2 width=1/ qed.
  62
  63 lemma cpqs_delift: ∀L,K,V,T1,d. ⇩[0, d] L ≡ (K. ⓓV) →
  64                    ∃∃T2,T. L ⊢ T1 ➤* T2 & ⇧[d, 1] T ≡ T2.
  65 #L #K #V #T1 #d #HLK
  66 elim (cpss_delift … T1 … HLK) -HLK /3 width=4/
  67 qed-.
  68
  69 lemma cpqs_append: l_appendable_sn … cpqs.
  70 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/ /2 width=3/
  71 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  72 lapply (ldrop_fwd_ldrop2_length … HK0) #H
  73 @(cpqs_delta … (L@@K0) V1 … HVW2) //
  74 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  75 qed.
  76
  77 (* Basic inversion lemmas ***************************************************)
  78
  79 fact cpqs_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ➤* T2 → ∀I. T1 = ⓪{I} →
  80                          T2 = ⓪{I} ∨
  81                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  82                                      K ⊢ V ➤* V2 &
  83                                      ⇧[O, i + 1] V2 ≡ T2 &
  84                                      I = LRef i.
  85 #L #T1 #T2 * -L -T1 -T2
  86 [ #I #L #J #H destruct /2 width=1/
  87 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8/
  88 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  89 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  90 | #L #V #T1 #T #T2 #_ #_ #J #H destruct
  91 | #L #V #T1 #T2 #_ #J #H destruct
  92 ]
  93 qed-.
  94
  95 lemma cpqs_inv_atom1: ∀I,L,T2. L ⊢ ⓪{I} ➤* T2 →
  96                       T2 = ⓪{I} ∨
  97                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  98                                   K ⊢ V ➤* V2 &
  99                                   ⇧[O, i + 1] V2 ≡ T2 &
 100                                   I = LRef i.
 101 /2 width=3 by cpqs_inv_atom1_aux/ qed-.
 102
 103 lemma cpqs_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ➤* T2 → T2 = ⋆k.
 104 #L #T2 #k #H
 105 elim (cpqs_inv_atom1 … H) -H //
 106 * #K #V #V2 #i #_ #_ #_ #H destruct
 107 qed-.
 108
 109 lemma cpqs_inv_lref1: ∀L,T2,i. L ⊢ #i ➤* T2 →
 110                       T2 = #i ∨
 111                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 112                                 K ⊢ V ➤* V2 &
 113                                 ⇧[O, i + 1] V2 ≡ T2.
 114 #L #T2 #i #H
 115 elim (cpqs_inv_atom1 … H) -H /2 width=1/
 116 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 117 qed-.
 118
 119 lemma cpqs_inv_gref1: ∀L,T2,p. L ⊢ §p ➤* T2 → T2 = §p.
 120 #L #T2 #p #H
 121 elim (cpqs_inv_atom1 … H) -H //
 122 * #K #V #V2 #i #_ #_ #_ #H destruct
 123 qed-.
 124
 125 fact cpqs_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 126                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 → (
 127                          ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 128                                   L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 129                                   U2 = ⓑ{a,I} V2. T2
 130                          ) ∨
 131                          ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 132 #L #U1 #U2 * -L -U1 -U2
 133 [ #I #L #b #J #W1 #U1 #H destruct
 134 | #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W1 #U1 #H destruct
 135 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W1 #U1 #H destruct /3 width=5/
 136 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W1 #U1 #H destruct
 137 | #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W1 #U1 #H destruct /3 width=3/
 138 | #L #V #T1 #T2 #_ #b #J #W1 #U1 #H destruct
 139 ]
 140 qed-.
 141
 142 lemma cpqs_inv_bind1: ∀a,I,L,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ➤* U2 → (
 143                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 144                                L. ⓑ{I} V1 ⊢ T1 ➤* T2 &
 145                                U2 = ⓑ{a,I} V2. T2
 146                       ) ∨
 147                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true & I = Abbr.
 148 /2 width=3 by cpqs_inv_bind1_aux/ qed-.
 149
 150 lemma cpqs_inv_abbr1: ∀a,L,V1,T1,U2. L ⊢ ⓓ{a} V1. T1 ➤* U2 → (
 151                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 152                                L. ⓓ V1 ⊢ T1 ➤* T2 &
 153                                U2 = ⓓ{a} V2. T2
 154                       ) ∨
 155                       ∃∃T. L.ⓓV1 ⊢ T1 ➤* T & ⇧[0, 1] U2 ≡ T & a = true.
 156 #a #L #V1 #T1 #U2 #H
 157 elim (cpqs_inv_bind1 … H) -H * /3 width=3/ /3 width=5/
 158 qed-.
 159
 160 lemma cpqs_inv_abst1: ∀a,L,V1,T1,U2. L ⊢ ⓛ{a} V1. T1 ➤* U2 →
 161                       ∃∃V2,T2. L ⊢ V1 ➤* V2 &
 162                                L. ⓛ V1 ⊢ T1 ➤* T2 &
 163                                U2 = ⓛ{a} V2. T2.
 164 #a #L #V1 #T1 #U2 #H
 165 elim (cpqs_inv_bind1 … H) -H *
 166 [ /3 width=5/
 167 | #T #_ #_ #_ #H destruct
 168 ]
 169 qed-.
 170
 171 fact cpqs_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ➤* U2 →
 172                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 → (
 173                          ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 174                                   U2 = ⓕ{I} V2. T2
 175                          ) ∨
 176                          (L ⊢ T1 ➤* U2 ∧ I = Cast).
 177 #L #U1 #U2 * -L -U1 -U2
 178 [ #I #L #J #W1 #U1 #H destruct
 179 | #L #K #V #V2 #W2 #i #_ #_ #_ #J #W1 #U1 #H destruct
 180 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 181 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /3 width=5/
 182 | #L #V #T1 #T #T2 #_ #_ #J #W1 #U1 #H destruct
 183 | #L #V #T1 #T2 #HT12 #J #W1 #U1 #H destruct /3 width=1/
 184 ]
 185 qed-.
 186
 187 lemma cpqs_inv_flat1: ∀I,L,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ➤* U2 → (
 188                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 189                                U2 = ⓕ{I} V2. T2
 190                       ) ∨
 191                       (L ⊢ T1 ➤* U2 ∧ I = Cast).
 192 /2 width=3 by cpqs_inv_flat1_aux/ qed-.
 193
 194 lemma cpqs_inv_appl1: ∀L,V1,T1,U2. L ⊢ ⓐ V1. T1 ➤* U2 →
 195                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 196                                U2 = ⓐ V2. T2.
 197 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H *
 198 [ /3 width=5/
 199 | #_ #H destruct
 200 ]
 201 qed-.
 202
 203 lemma cpqs_inv_cast1: ∀L,V1,T1,U2. L ⊢ ⓝ V1. T1 ➤* U2 → (
 204                       ∃∃V2,T2. L ⊢ V1 ➤* V2 & L ⊢ T1 ➤* T2 &
 205                                U2 = ⓝ V2. T2
 206                       ) ∨
 207                       L ⊢ T1 ➤* U2.
 208 #L #V1 #T1 #U2 #H elim (cpqs_inv_flat1 … H) -H * /2 width=1/ /3 width=5/
 209 qed-.
 210
 211 (* Basic forward lemmas *****************************************************)
 212
 213 lemma cpqs_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ➤* T →
 214                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 215 #L1 @(lenv_ind_dx … L1) -L1 normalize
 216 [ #L #T1 #T #HT1
 217   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 218 | #I #L1 #V1 #IH #L #T1 #X
 219   >shift_append_assoc normalize #H
 220   elim (cpqs_inv_bind1 … H) -H *
 221   [ #V0 #T0 #_ #HT10 #H destruct
 222     elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 223     >append_length >HL12 -HL12
 224     @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 225   | #T #_ #_ #H destruct
 226   ]
 227 ]
 228 qed-.