matita/matita/contribs/lambdadelta/basic_2/unfold/cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop_append.ma".
  16
  17 (* CONTEXT-SENSITIVE PARALLEL UNFOLD FOR TERMS ******************************)
  18
  19 inductive cpss: lenv → relation term ≝
  20 | cpss_atom : ∀I,L. cpss L (⓪{I}) (⓪{I})
  21 | cpss_delta: ∀L,K,V,V2,W2,i.
  22               ⇩[0, i] L ≡ K. ⓓV → cpss K V V2 →
  23               ⇧[0, i + 1] V2 ≡ W2 → cpss L (#i) W2
  24 | cpss_bind : ∀a,I,L,V1,V2,T1,T2.
  25               cpss L V1 V2 → cpss (L. ⓑ{I} V1) T1 T2 →
  26               cpss L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | cpss_flat : ∀I,L,V1,V2,T1,T2.
  28               cpss L V1 V2 → cpss L T1 T2 →
  29               cpss L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 .
  31
  32 interpretation "context-sensitive parallel unfold (term)"
  33    'PSubstStar L T1 T2 = (cpss L T1 T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 (* Note: it does not hold replacing |L1| with |L2| *)
  38 lemma cpss_lsubr_trans: ∀L1,T1,T2. L1 ⊢ T1 ▶* T2 →
  39                         ∀L2. L2 ⊑ [0, |L1|] L1 → L2 ⊢ T1 ▶* T2.
  40 #L1 #T1 #T2 #H elim H -L1 -T1 -T2
  41 [ //
  42 | #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  43   lapply (ldrop_fwd_ldrop2_length … HLK1) #Hi
  44   lapply (ldrop_fwd_O1_length … HLK1) #H2i
  45   elim (ldrop_lsubr_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // -Hi
  46   <H2i -H2i <minus_plus_m_m /3 width=6/
  47 | /4 width=1/
  48 | /3 width=1/
  49 ]
  50 qed-.
  51
  52 (* Basic_1: was by definition: subst1_refl *)
  53 lemma cpss_refl: ∀T,L. L ⊢ T ▶* T.
  54 #T elim T -T //
  55 #I elim I -I /2 width=1/
  56 qed.
  57
  58 (* Basic_1: was only: subst1_ex *)
  59 lemma cpss_delift: ∀K,V,T1,L,d. ⇩[0, d] L ≡ (K. ⓓV) →
  60                    ∃∃T2,T. L ⊢ T1 ▶* T2 & ⇧[d, 1] T ≡ T2.
  61 #K #V #T1 elim T1 -T1
  62 [ * #i #L #d #HLK /2 width=4/
  63   elim (lt_or_eq_or_gt i d) #Hid /3 width=4/
  64   destruct
  65   elim (lift_total V 0 (i+1)) #W #HVW
  66   elim (lift_split … HVW i i ? ? ?) // /3 width=6/
  67 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  68   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  69   [ elim (IHU1 (L. ⓑ{I} W1) (d+1) ?) -IHU1 /2 width=1/ -HLK /3 width=9/
  70   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  71   ]
  72 ]
  73 qed-.
  74
  75 lemma cpss_append: l_appendable_sn … cpss.
  76 #K #T1 #T2 #H elim H -K -T1 -T2 // /2 width=1/
  77 #K #K0 #V1 #V2 #W2 #i #HK0 #_ #HVW2 #IHV12 #L
  78 lapply (ldrop_fwd_ldrop2_length … HK0) #H
  79 @(cpss_delta … (L@@K0) V1 … HVW2) //
  80 @(ldrop_O1_append_sn_le … HK0) /2 width=2/ (**) (* /3/ does not work *)
  81 qed.
  82
  83 (* Basic inversion lemmas ***************************************************)
  84
  85 fact cpss_inv_atom1_aux: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ∀I. T1 = ⓪{I} →
  86                          T2 = ⓪{I} ∨
  87                          ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
  88                                      K ⊢ V ▶* V2 &
  89                                      ⇧[O, i + 1] V2 ≡ T2 &
  90                                      I = LRef i.
  91 #L #T1 #T2 * -L -T1 -T2
  92 [ #I #L #J #H destruct /2 width=1/
  93 | #L #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #I #H destruct /3 width=8/
  94 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  95 | #I #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  96 ]
  97 qed-.
  98
  99 lemma cpss_inv_atom1: ∀I,L,T2. L ⊢ ⓪{I} ▶* T2 →
 100                       T2 = ⓪{I} ∨
 101                       ∃∃K,V,V2,i. ⇩[O, i] L ≡ K. ⓓV &
 102                                   K ⊢ V ▶* V2 &
 103                                   ⇧[O, i + 1] V2 ≡ T2 &
 104                                   I = LRef i.
 105 /2 width=3 by cpss_inv_atom1_aux/ qed-.
 106
 107 (* Basic_1: was only: subst1_gen_sort *)
 108 lemma cpss_inv_sort1: ∀L,T2,k. L ⊢ ⋆k ▶* T2 → T2 = ⋆k.
 109 #L #T2 #k #H
 110 elim (cpss_inv_atom1 … H) -H //
 111 * #K #V #V2 #i #_ #_ #_ #H destruct
 112 qed-.
 113
 114 (* Basic_1: was only: subst1_gen_lref *)
 115 lemma cpss_inv_lref1: ∀L,T2,i. L ⊢ #i ▶* T2 →
 116                       T2 = #i ∨
 117                       ∃∃K,V,V2. ⇩[O, i] L ≡ K. ⓓV &
 118                                 K ⊢ V ▶* V2 &
 119                                 ⇧[O, i + 1] V2 ≡ T2.
 120 #L #T2 #i #H
 121 elim (cpss_inv_atom1 … H) -H /2 width=1/
 122 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6/
 123 qed-.
 124
 125 lemma cpss_inv_gref1: ∀L,T2,p. L ⊢ §p ▶* T2 → T2 = §p.
 126 #L #T2 #p #H
 127 elim (cpss_inv_atom1 … H) -H //
 128 * #K #V #V2 #i #_ #_ #_ #H destruct
 129 qed-.
 130
 131 fact cpss_inv_bind1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 132                          ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 →
 133                          ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 134                                   L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 135                                   U2 = ⓑ{a,I} V2. T2.
 136 #L #U1 #U2 * -L -U1 -U2
 137 [ #I #L #b #J #W1 #U1 #H destruct
 138 | #L #K #V #V2 #W2 #i #_ #_ #_ #b #J #W1 #U1 #H destruct
 139 | #a #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W1 #U1 #H destruct /2 width=5/
 140 | #I #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W1 #U1 #H destruct
 141 ]
 142 qed-.
 143
 144 lemma cpss_inv_bind1: ∀a,I,L,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶* U2 →
 145                       ∃∃V2,T2. L ⊢ V1 ▶* V2 &
 146                                L. ⓑ{I} V1 ⊢ T1 ▶* T2 &
 147                                U2 = ⓑ{a,I} V2. T2.
 148 /2 width=3 by cpss_inv_bind1_aux/ qed-.
 149
 150 fact cpss_inv_flat1_aux: ∀L,U1,U2. L ⊢ U1 ▶* U2 →
 151                          ∀I,V1,T1. U1 = ⓕ{I} V1. T1 →
 152                          ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 153                                   U2 =  ⓕ{I} V2. T2.
 154 #L #U1 #U2 * -L -U1 -U2
 155 [ #I #L #J #W1 #U1 #H destruct
 156 | #L #K #V #V2 #W2 #i #_ #_ #_ #J #W1 #U1 #H destruct
 157 | #a #I #L #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 158 | #I #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5/
 159 ]
 160 qed-.
 161
 162 lemma cpss_inv_flat1: ∀I,L,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶* U2 →
 163                       ∃∃V2,T2. L ⊢ V1 ▶* V2 & L ⊢ T1 ▶* T2 &
 164                                U2 =  ⓕ{I} V2. T2.
 165 /2 width=3 by cpss_inv_flat1_aux/ qed-.
 166
 167 (* Basic forward lemmas *****************************************************)
 168
 169 lemma cpss_fwd_tw: ∀L,T1,T2. L ⊢ T1 ▶* T2 → ♯{T1} ≤ ♯{T2}.
 170 #L #T1 #T2 #H elim H -L -T1 -T2 normalize
 171 /3 width=1 by monotonic_le_plus_l, le_plus/ (**) (* auto is too slow without trace *)
 172 qed-.
 173
 174 lemma cpss_fwd_shift1: ∀L1,L,T1,T. L ⊢ L1 @@ T1 ▶* T →
 175                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 176 #L1 @(lenv_ind_dx … L1) -L1 normalize
 177 [ #L #T1 #T #HT1
 178   @(ex2_2_intro … (⋆)) // (**) (* explicit constructor *)
 179 | #I #L1 #V1 #IH #L #T1 #X
 180   >shift_append_assoc normalize #H
 181   elim (cpss_inv_bind1 … H) -H
 182   #V0 #T0 #_ #HT10 #H destruct
 183   elim (IH … HT10) -IH -HT10 #L2 #T2 #HL12 #H destruct
 184   >append_length >HL12 -HL12
 185   @(ex2_2_intro … (⋆.ⓑ{I}V0@@L2) T2) [ >append_length ] // /2 width=3/ (**) (* explicit constructor *)
 186 ]
 187 qed-.
 188
 189 (* Basic_1: removed theorems 27:
 190             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 191             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 192             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 193             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 194             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 195             subst0_confluence_lift subst0_tlt
 196             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 197             subst1_gen_lift_eq subst1_confluence_neq
 198 *)