matita/matita/contribs/lambdadelta/basic_2/unfold/delift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss.ma".
  16
  17 (* INVERSE BASIC TERM RELOCATION  *******************************************)
  18
  19 definition delift: nat → nat → lenv → relation term ≝
  20                    λd,e,L,T1,T2. ∃∃T. L ⊢ T1 ▶* [d, e] T & ⇧[d, e] T2 ≡ T.
  21
  22 interpretation "inverse basic relocation (term)"
  23    'TSubst L T1 d e T2 = (delift d e L T1 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma lift_delift: ∀T1,T2,d,e. ⇧[d, e] T1 ≡ T2 →
  28                    ∀L. L ⊢ ▼*[d, e] T2 ≡ T1.
  29 /2 width=3/ qed.
  30
  31 lemma delift_refl_O2: ∀L,T,d. L ⊢ ▼*[d, 0] T ≡ T.
  32 /2 width=3/ qed.
  33
  34 lemma delift_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ ▼*[d, e] T1 ≡ T2 →
  35                           ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ ▼*[d, e] T1 ≡ T2.
  36 #L1 #T1 #T2 #d #e * /3 width=3/
  37 qed.
  38
  39 lemma delift_sort: ∀L,d,e,k. L ⊢ ▼*[d, e] ⋆k ≡ ⋆k.
  40 /2 width=3/ qed.
  41
  42 lemma delift_lref_lt: ∀L,d,e,i. i < d → L ⊢ ▼*[d, e] #i ≡ #i.
  43 /3 width=3/ qed.
  44
  45 lemma delift_lref_ge: ∀L,d,e,i. d + e ≤ i → L ⊢ ▼*[d, e] #i ≡ #(i - e).
  46 /3 width=3/ qed.
  47
  48 lemma delift_gref: ∀L,d,e,p. L ⊢ ▼*[d, e] §p ≡ §p.
  49 /2 width=3/ qed.
  50
  51 lemma delift_bind: ∀a,I,L,V1,V2,T1,T2,d,e.
  52                    L ⊢ ▼*[d, e] V1 ≡ V2 → L. ⓑ{I} V2 ⊢ ▼*[d+1, e] T1 ≡ T2 →
  53                    L ⊢ ▼*[d, e] ⓑ{a,I} V1. T1 ≡ ⓑ{a,I} V2. T2.
  54 #a #I #L #V1 #V2 #T1 #T2 #d #e * #V #HV1 #HV2 * #T #HT1 #HT2
  55 lapply (tpss_lsubs_trans … HT1 (L. ⓑ{I} V) ?) -HT1 /2 width=1/ /3 width=5/
  56 qed.
  57
  58 lemma delift_flat: ∀I,L,V1,V2,T1,T2,d,e.
  59                    L ⊢ ▼*[d, e] V1 ≡ V2 → L ⊢ ▼*[d, e] T1 ≡ T2 →
  60                    L ⊢ ▼*[d, e] ⓕ{I} V1. T1 ≡ ⓕ{I} V2. T2.
  61 #I #L #V1 #V2 #T1 #T2 #d #e * #V #HV1 #HV2 * /3 width=5/
  62 qed.
  63
  64 (* Basic inversion lemmas ***************************************************)
  65
  66 lemma delift_inv_sort1: ∀L,U2,d,e,k. L ⊢ ▼*[d, e] ⋆k ≡ U2 → U2 = ⋆k.
  67 #L #U2 #d #e #k * #U #HU
  68 >(tpss_inv_sort1 … HU) -HU #HU2
  69 >(lift_inv_sort2 … HU2) -HU2 //
  70 qed-.
  71
  72 lemma delift_inv_gref1: ∀L,U2,d,e,p. L ⊢ ▼*[d, e] §p ≡ U2 → U2 = §p.
  73 #L #U #d #e #p * #U #HU
  74 >(tpss_inv_gref1 … HU) -HU #HU2
  75 >(lift_inv_gref2 … HU2) -HU2 //
  76 qed-.
  77
  78 lemma delift_inv_bind1: ∀a,I,L,V1,T1,U2,d,e. L ⊢ ▼*[d, e] ⓑ{a,I} V1. T1 ≡ U2 →
  79                         ∃∃V2,T2. L ⊢ ▼*[d, e] V1 ≡ V2 &
  80                                  L. ⓑ{I} V2 ⊢ ▼*[d+1, e] T1 ≡ T2 &
  81                                  U2 = ⓑ{a,I} V2. T2.
  82 #a #I #L #V1 #T1 #U2 #d #e * #U #HU #HU2
  83 elim (tpss_inv_bind1 … HU) -HU #V #T #HV1 #HT1 #X destruct
  84 elim (lift_inv_bind2 … HU2) -HU2 #V2 #T2 #HV2 #HT2
  85 lapply (tpss_lsubs_trans … HT1 (L. ⓑ{I} V2) ?) -HT1 /2 width=1/ /3 width=5/
  86 qed-.
  87
  88 lemma delift_inv_flat1: ∀I,L,V1,T1,U2,d,e. L ⊢ ▼*[d, e] ⓕ{I} V1. T1 ≡ U2 →
  89                         ∃∃V2,T2. L ⊢ ▼*[d, e] V1 ≡ V2 &
  90                                  L ⊢ ▼*[d, e] T1 ≡ T2 &
  91                                  U2 = ⓕ{I} V2. T2.
  92 #I #L #V1 #T1 #U2 #d #e * #U #HU #HU2
  93 elim (tpss_inv_flat1 … HU) -HU #V #T #HV1 #HT1 #X destruct
  94 elim (lift_inv_flat2 … HU2) -HU2 /3 width=5/
  95 qed-.
  96
  97 lemma delift_inv_refl_O2: ∀L,T1,T2,d. L ⊢ ▼*[d, 0] T1 ≡ T2 → T1 = T2.
  98 #L #T1 #T2 #d * #T #HT1
  99 >(tpss_inv_refl_O2 … HT1) -HT1 #HT2
 100 >(lift_inv_refl_O2 … HT2) -HT2 //
 101 qed-.
 102
 103 (* Basic forward lemmas *****************************************************)
 104
 105 lemma delift_fwd_tw: ∀L,T1,T2,d,e. L ⊢ ▼*[d, e] T1 ≡ T2 → #{T1} ≤ #{T2}.
 106 #L #T1 #T2 #d #e * #T #HT1 #HT2
 107 >(tw_lift … HT2) -T2 /2 width=4 by tpss_fwd_tw /
 108 qed-.