matita/matita/contribs/lambdadelta/basic_2/unfold/delift_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/delift_lift.ma".
  16
  17 (* INVERSE BASIC TERM RELOCATION  *******************************************)
  18
  19 (* alternative definition of inverse basic term relocation *)
  20 inductive delifta: nat → nat → lenv → relation term ≝
  21 | delifta_sort   : ∀L,d,e,k. delifta d e L (⋆k) (⋆k)
  22 | delifta_lref_lt: ∀L,d,e,i. i < d → delifta d e L (#i) (#i)
  23 | delifta_lref_be: ∀L,K,V1,V2,W2,i,d,e. d ≤ i → i < d + e →
  24                    ⇩[0, i] L ≡ K. ⓓV1 → delifta 0 (d + e - i - 1) K V1 V2 →
  25                    ⇧[0, d] V2 ≡ W2 → delifta d e L (#i) W2
  26 | delifta_lref_ge: ∀L,d,e,i. d + e ≤ i → delifta d e L (#i) (#(i - e))
  27 | delifta_gref   : ∀L,d,e,p. delifta d e L (§p) (§p)
  28 | delifta_bind   : ∀L,a,I,V1,V2,T1,T2,d,e.
  29                    delifta d e L V1 V2 → delifta (d + 1) e (L. ⓑ{I} V2) T1 T2 →
  30                    delifta d e L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  31 | delifta_flat   : ∀L,I,V1,V2,T1,T2,d,e.
  32                    delifta d e L V1 V2 → delifta d e L T1 T2 →
  33                    delifta d e L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  34 .
  35
  36 interpretation "inverse basic relocation (term) alternative"
  37    'TSubstAlt L T1 d e T2 = (delifta d e L T1 T2).
  38
  39 (* Basic properties *********************************************************)
  40
  41 lemma delifta_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ ▼▼*[d, e] T1 ≡ T2 →
  42                            ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ ▼▼*[d, e] T1 ≡ T2.
  43 #L1 #T1 #T2 #d #e #H elim H -L1 -T1 -T2 -d -e // /2 width=1/
  44 [ #L1 #K1 #V1 #V2 #W2 #i #d #e #Hdi #Hide #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  45   elim (ldrop_lsubs_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // /3 width=6/
  46 | /4 width=1/
  47 | /3 width=1/
  48 ]
  49 qed.
  50
  51 lemma delift_delifta: ∀L,T1,T2,d,e. L ⊢ ▼*[d, e] T1 ≡ T2 → L ⊢ ▼▼*[d, e] T1 ≡ T2.
  52 #L #T1 @(fw_ind … L T1) -L -T1 #L #T1 elim T1 -T1
  53 [ * #i #IH #T2 #d #e #H
  54   [ >(delift_inv_sort1 … H) -H //
  55   | elim (delift_inv_lref1 … H) -H * /2 width=1/
  56     #K #V1 #V2 #Hdi #Hide #HLK #HV12 #HVT2
  57     lapply (ldrop_pair2_fwd_fw … HLK) #H
  58     lapply (IH … HV12) // -H /2 width=6/
  59   | >(delift_inv_gref1 … H) -H //
  60   ]
  61 | * [ #a ] #I #V1 #T1 #_ #_ #IH #X #d #e #H
  62   [ elim (delift_inv_bind1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  63     lapply (delift_lsubs_trans … HT12 (L.ⓑ{I}V1) ?) -HT12 /2 width=1/ #HT12
  64     lapply (IH … HV12) -HV12 // #HV12
  65     lapply (IH … HT12) -IH -HT12 /2 width=1/ #HT12
  66     lapply (delifta_lsubs_trans … HT12 (L.ⓑ{I}V2) ?) -HT12 /2 width=1/
  67   | elim (delift_inv_flat1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  68     lapply (IH … HV12) -HV12 //
  69     lapply (IH … HT12) -IH -HT12 // /2 width=1/
  70   ]
  71 ]
  72 qed.
  73
  74 (* Basic inversion lemmas ***************************************************)
  75
  76 lemma delifta_delift: ∀L,T1,T2,d,e. L ⊢ ▼▼*[d, e] T1 ≡ T2 → L ⊢ ▼*[d, e] T1 ≡ T2.
  77 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e // /2 width=1/ /2 width=6/
  78 qed-.
  79
  80 lemma delift_ind_alt: ∀R:ℕ→ℕ→lenv→relation term.
  81                       (∀L,d,e,k. R d e L (⋆k) (⋆k)) →
  82                       (∀L,d,e,i. i < d → R d e L (#i) (#i)) →
  83                       (∀L,K,V1,V2,W2,i,d,e. d ≤ i → i < d + e →
  84                        ⇩[O, i] L ≡ K.ⓓV1 → K ⊢ ▼*[O, d + e - i - 1] V1 ≡ V2 →
  85                        ⇧[O, d] V2 ≡ W2 → R O (d+e-i-1) K V1 V2 → R d e L #i W2
  86                       ) →
  87                       (∀L,d,e,i. d + e ≤ i → R d e L (#i) (#(i - e))) →
  88                       (∀L,d,e,p. R d e L (§p) (§p)) →
  89                       (∀L,a,I,V1,V2,T1,T2,d,e. L ⊢ ▼*[d, e] V1 ≡ V2 →
  90                        L.ⓑ{I}V2 ⊢ ▼*[d + 1, e] T1 ≡ T2 → R d e L V1 V2 →
  91                        R (d+1) e (L.ⓑ{I}V2) T1 T2 → R d e L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  92                       ) →
  93                       (∀L,I,V1,V2,T1,T2,d,e. L ⊢ ▼*[d, e] V1 ≡ V2 →
  94                        L⊢ ▼*[d, e] T1 ≡ T2 → R d e L V1 V2 →
  95                        R d e L T1 T2 → R d e L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  96                       ) →
  97                       ∀d,e,L,T1,T2. L ⊢ ▼*[d, e] T1 ≡ T2 → R d e L T1 T2.
  98 #R #H1 #H2 #H3 #H4 #H5 #H6 #H7 #d #e #L #T1 #T2 #H elim (delift_delifta … H) -L -T1 -T2 -d -e
  99 // /2 width=1 by delifta_delift/ /3 width=1 by delifta_delift/ /3 width=7 by delifta_delift/
 100 qed-.