matita/matita/contribs/lambdadelta/basic_2/unfold/delift_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/ldrop_sfr.ma".
  16 include "basic_2/unfold/tpss_lift.ma".
  17 include "basic_2/unfold/delift.ma".
  18
  19 (* INVERSE BASIC TERM RELOCATION  *******************************************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 lemma delift_lref_be: ∀L,K,V1,V2,U2,i,d,e. d ≤ i → i < d + e →
  24                       ⇩[0, i] L ≡ K. ⓓV1 → K ⊢ ▼*[0, d + e - i - 1] V1 ≡ V2 →
  25                       ⇧[0, d] V2 ≡ U2 → L ⊢ ▼*[d, e] #i ≡ U2.
  26 #L #K #V1 #V2 #U2 #i #d #e #Hdi #Hide #HLK * #V #HV1 #HV2 #HVU2
  27 elim (lift_total V 0 (i+1)) #U #HVU
  28 lapply (lift_trans_be … HV2 … HVU ? ?) -HV2 // >minus_plus <plus_minus_m_m /2 width=1/ #HV2U
  29 lapply (lift_conf_be … HVU2 … HV2U ?) //
  30 >commutative_plus in ⊢ (??%??→?); <minus_plus_m_m /3 width=6/
  31 qed.
  32
  33 fact sfr_delift_aux: ∀L,T,T1,d,e. d + e ≤ |L| → ≽ [d, e] L → T = T1 →
  34                      ∃T2. L ⊢ ▼*[d, e] T1 ≡ T2.
  35 #L #T @(fw_ind … L T) -L -T #L #T #IH * * /2 width=2/
  36 [ #i #d #e #Hde #HL #H destruct
  37   elim (lt_or_ge i d) #Hdi [ /3 width=2/ ]
  38   elim (lt_or_ge i (d+e)) #Hide [2: /3 width=2/ ]
  39   lapply (lt_to_le_to_lt … Hide Hde) #Hi
  40   elim (ldrop_O1_lt … Hi) -Hi #I #K #V1 #HLK
  41   lapply (sfr_inv_ldrop … HLK … HL ? ?) // #H destruct
  42   lapply (ldrop_pair2_fwd_fw … HLK (#i)) #HKL
  43   lapply (ldrop_fwd_ldrop2 … HLK) #HLK0
  44   lapply (ldrop_fwd_O1_length … HLK0) #H
  45   lapply (sfr_ldrop_trans_be_up … HLK0 … HL ? ?) -HLK0 -HL
  46   [1,2: /2 width=1/ | <minus_n_O <minus_plus ] #HK
  47   elim (IH … HKL … HK ?) -IH -HKL -HK
  48   [3: // |2: skip |4: >H -H /2 width=1/ ] -Hde -H #V2 #V12 (**) (* H erased two times *)
  49   elim (lift_total V2 0 d) /3 width=7/
  50 | #a #I #V1 #T1 #d #e #Hde #HL #H destruct
  51   elim (IH … V1 … Hde HL ?) [2,4: // |3: skip ] #V2 #HV12
  52   elim (IH (L.ⓑ{I}V1) T1 ? ? (d+1) e ? ? ?) -IH [3,6: // |2: skip |4,5: /2 width=1/ ] -Hde -HL #T2 #HT12
  53   lapply (delift_lsubs_trans … HT12 (L.ⓑ{I}V2) ?) -HT12 /2 width=1/ /3 width=4/
  54 | #I #V1 #T1 #d #e #Hde #HL #H destruct
  55   elim (IH … V1 … Hde HL ?) [2,4: // |3: skip ] #V2 #HV12
  56   elim (IH … T1 … Hde HL ?) -IH -Hde -HL [3,4: // |2: skip ] /3 width=2/
  57 ]
  58 qed.
  59
  60 lemma sfr_delift: ∀L,T1,d,e. d + e ≤ |L| → ≽ [d, e] L →
  61                   ∃T2. L ⊢ ▼*[d, e] T1 ≡ T2.
  62 /2 width=2/ qed-.
  63
  64 (* Advanced inversion lemmas ************************************************)
  65
  66 lemma delift_inv_lref1_lt: ∀L,U2,i,d,e. L ⊢ ▼*[d, e] #i ≡ U2 → i < d → U2 = #i.
  67 #L #U2 #i #d #e * #U #HU #HU2 #Hid
  68 elim (tpss_inv_lref1 … HU) -HU
  69 [ #H destruct >(lift_inv_lref2_lt … HU2) //
  70 | * #K #V1 #V2 #Hdi
  71   lapply (lt_to_le_to_lt … Hid Hdi) -Hid -Hdi #Hi
  72   elim (lt_refl_false … Hi)
  73 ]
  74 qed-.
  75
  76 lemma delift_inv_lref1_be: ∀L,U2,d,e,i. L ⊢ ▼*[d, e] #i ≡ U2 →
  77                            d ≤ i → i < d + e →
  78                            ∃∃K,V1,V2. ⇩[0, i] L ≡ K. ⓓV1 &
  79                                       K ⊢ ▼*[0, d + e - i - 1] V1 ≡ V2 &
  80                                       ⇧[0, d] V2 ≡ U2.
  81 #L #U2 #d #e #i * #U #HU #HU2 #Hdi #Hide
  82 elim (tpss_inv_lref1 … HU) -HU
  83 [ #H destruct elim (lift_inv_lref2_be … HU2 ? ?) //
  84 | * #K #V1 #V #_ #_ #HLK #HV1 #HVU
  85   elim (lift_div_be … HVU … HU2 ? ?) -U // /2 width=1/ /3 width=6/
  86 ]
  87 qed-.
  88
  89 lemma delift_inv_lref1_ge: ∀L,U2,i,d,e. L ⊢ ▼*[d, e] #i ≡ U2 →
  90                            d + e ≤ i → U2 = #(i - e).
  91 #L #U2 #i #d #e * #U #HU #HU2 #Hdei
  92 elim (tpss_inv_lref1 … HU) -HU
  93 [ #H destruct >(lift_inv_lref2_ge … HU2) //
  94 | * #K #V1 #V2 #_ #Hide
  95   lapply (lt_to_le_to_lt … Hide Hdei) -Hide -Hdei #Hi
  96   elim (lt_refl_false … Hi)
  97 ]
  98 qed-.
  99
 100 lemma delift_inv_lref1: ∀L,U2,i,d,e. L ⊢ ▼*[d, e] #i ≡ U2 →
 101                         ∨∨ (i < d ∧ U2 = #i)
 102                         |  (∃∃K,V1,V2. d ≤ i & i < d + e &
 103                                        ⇩[0, i] L ≡ K. ⓓV1 &
 104                                        K ⊢ ▼*[0, d + e - i - 1] V1 ≡ V2 &
 105                                        ⇧[0, d] V2 ≡ U2
 106                            )
 107                         |  (d + e ≤ i ∧ U2 = #(i - e)).
 108 #L #U2 #i #d #e #H
 109 elim (lt_or_ge i d) #Hdi
 110 [ elim (delift_inv_lref1_lt … H Hdi) -H /3 width=1/
 111 | elim (lt_or_ge i (d+e)) #Hide
 112   [ elim (delift_inv_lref1_be … H Hdi Hide) -H /3 width=6/
 113   | elim (delift_inv_lref1_ge … H Hide) -H /3 width=1/
 114   ]
 115 ]
 116 qed-.
 117
 118 (* Properties on basic term relocation **************************************)
 119
 120 lemma delift_lift_le: ∀K,T1,T2,dt,et. K ⊢ ▼*[dt, et] T1 ≡ T2 →
 121                       ∀L,U1,d,e. dt + et ≤ d → ⇩[d, e] L ≡ K →
 122                       ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d - et, e] T2 ≡ U2 →
 123                       L ⊢ ▼*[dt, et] U1 ≡ U2.
 124 #K #T1 #T2 #dt #et * #T #HT1 #HT2 #L #U1 #d #e #Hdetd #HLK #HTU1 #U2 #HTU2
 125 elim (lift_total T d e) #U #HTU
 126 lapply (tpss_lift_le … HT1 … HLK HTU1 … HTU) -T1 -HLK // #HU1
 127 elim (lift_trans_ge … HT2 … HTU ?) -T // -Hdetd #T #HT2 #HTU
 128 >(lift_mono … HTU2 … HT2) -T2 /2 width=3/
 129 qed.
 130
 131 lemma delift_lift_be: ∀K,T1,T2,dt,et. K ⊢ ▼*[dt, et] T1 ≡ T2 →
 132                       ∀L,U1,d,e. dt ≤ d → d ≤ dt + et →
 133                       ⇩[d, e] L ≡ K → ⇧[d, e] T1 ≡ U1 →
 134                       L ⊢ ▼*[dt, et + e] U1 ≡ T2.
 135 #K #T1 #T2 #dt #et * #T #HT1 #HT2 #L #U1 #d #e #Hdtd #Hddet #HLK #HTU1
 136 elim (lift_total T d e) #U #HTU
 137 lapply (tpss_lift_be … HT1 … HLK HTU1 … HTU) -T1 -HLK // #HU1
 138 lapply (lift_trans_be … HT2 … HTU ? ?) -T // -Hdtd -Hddet /2 width=3/
 139 qed.
 140
 141 lemma delift_lift_ge: ∀K,T1,T2,dt,et. K ⊢ ▼*[dt, et] T1 ≡ T2 →
 142                       ∀L,U1,d,e. d ≤ dt → ⇩[d, e] L ≡ K →
 143                       ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 →
 144                       L ⊢ ▼*[dt + e, et] U1 ≡ U2.
 145 #K #T1 #T2 #dt #et * #T #HT1 #HT2 #L #U1 #d #e #Hddt #HLK #HTU1 #U2 #HTU2
 146 elim (lift_total T d e) #U #HTU
 147 lapply (tpss_lift_ge … HT1 … HLK HTU1 … HTU) -T1 -HLK // #HU1
 148 elim (lift_trans_le … HT2 … HTU ?) -T // -Hddt #T #HT2 #HTU
 149 >(lift_mono … HTU2 … HT2) -T2 /2 width=3/
 150 qed.
 151
 152 lemma delift_inv_lift1_eq: ∀L,U1,T2,d,e. L ⊢ ▼*[d, e] U1 ≡ T2 →
 153                            ∀K. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 → T1 = T2.
 154 #L #U1 #T2 #d #e * #U2 #HU12 #HTU2 #K #HLK #T1 #HTU1
 155 lapply (tpss_inv_lift1_eq … HU12 … HTU1) -L -K #H destruct
 156 lapply (lift_inj … HTU1 … HTU2) -U2 //
 157 qed-.
 158
 159 lemma delift_lift_div_be: ∀L,T1,T,d,e,i. L ⊢ ▼*[i, d + e - i] T1 ≡ T →
 160                           ∀T2. ⇧[d, i - d] T2 ≡ T → d ≤ i → i ≤ d + e →
 161                           L ⊢ ▼*[d, e] T1 ≡ T2.
 162 #L #T1 #T #d #e #i * #T0 #HT10 #HT0 #T2 #HT2 #Hdi #Hide
 163 lapply (tpss_weak … HT10 d e ? ?) -HT10 // [ >commutative_plus /2 width=1/ ] #HT10
 164 lapply (lift_trans_be … HT2 … HT0 ? ?) -T //
 165 >commutative_plus >commutative_plus in ⊢ (? ? (? % ?) ? ? → ?);
 166 <minus_le_minus_minus_comm // <plus_minus_m_m [ /2 width=3/ | /2 width=1/ ]
 167 qed.