matita/matita/contribs/lambdadelta/basic_2/unfold/frsupp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/frsup.ma".
  16
  17 (* PLUS-ITERATED RESTRICTED SUPCLOSURE **************************************)
  18
  19 definition frsupp: bi_relation lenv term ≝ bi_TC … frsup.
  20
  21 interpretation "plus-iterated restricted structural predecessor (closure)"
  22    'RestSupTermPlus L1 T1 L2 T2 = (frsupp L1 T1 L2 T2).
  23
  24 (* Basic eliminators ********************************************************)
  25
  26 lemma frsupp_ind: ∀L1,T1. ∀R:relation2 lenv term.
  27                   (∀L2,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → R L2 T2) →
  28                   (∀L,T,L2,T2. ⦃L1, T1⦄ ⧁+ ⦃L, T⦄ → ⦃L, T⦄ ⧁ ⦃L2, T2⦄ → R L T → R L2 T2) →
  29                   ∀L2,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → R L2 T2.
  30 #L1 #T1 #R #IH1 #IH2 #L2 #T2 #H
  31 @(bi_TC_ind … IH1 IH2 ? ? H)
  32 qed-.
  33
  34 lemma frsupp_ind_dx: ∀L2,T2. ∀R:relation2 lenv term.
  35                      (∀L1,T1. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → R L1 T1) →
  36                      (∀L1,L,T1,T. ⦃L1, T1⦄ ⧁ ⦃L, T⦄ → ⦃L, T⦄ ⧁+ ⦃L2, T2⦄ → R L T → R L1 T1) →
  37                      ∀L1,T1. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → R L1 T1.
  38 #L2 #T2 #R #IH1 #IH2 #L1 #T1 #H
  39 @(bi_TC_ind_dx … IH1 IH2 ? ? H)
  40 qed-.
  41
  42 (* Baic inversion lemmas ****************************************************)
  43
  44 lemma frsupp_inv_dx: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ ∨
  45                      ∃∃L,T. ⦃L1, T1⦄ ⧁+ ⦃L, T⦄ & ⦃L, T⦄ ⧁ ⦃L2, T2⦄.
  46 /2 width=1 by bi_TC_decomp_r/ qed-.
  47
  48 lemma frsupp_inv_sn: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ ∨
  49                      ∃∃L,T. ⦃L1, T1⦄ ⧁ ⦃L, T⦄ & ⦃L, T⦄ ⧁+ ⦃L2, T2⦄.
  50 /2 width=1 by bi_TC_decomp_l/ qed-.
  51
  52 (* Basic properties *********************************************************)
  53
  54 lemma frsup_frsupp: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁ ⦃L2, T2⦄ → ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄.
  55 /2 width=1/ qed.
  56
  57 lemma frsupp_strap1: ∀L1,L,L2,T1,T,T2. ⦃L1, T1⦄ ⧁+ ⦃L, T⦄ → ⦃L, T⦄ ⧁ ⦃L2, T2⦄ →
  58                      ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄.
  59 /2 width=4/ qed.
  60
  61 lemma frsupp_strap2: ∀L1,L,L2,T1,T,T2. ⦃L1, T1⦄ ⧁ ⦃L, T⦄ → ⦃L, T⦄ ⧁+ ⦃L2, T2⦄ →
  62                      ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄.
  63 /2 width=4/ qed.
  64
  65 (* Basic forward lemmas *****************************************************)
  66
  67 lemma frsupp_fwd_fw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → #{L2, T2} < #{L1, T1}.
  68 #L1 #L2 #T1 #T2 #H @(frsupp_ind … H) -L2 -T2
  69 /3 width=3 by frsup_fwd_fw, transitive_lt/
  70 qed-.
  71
  72 lemma frsupp_fwd_lw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → #{L1} ≤ #{L2}.
  73 #L1 #L2 #T1 #T2 #H @(frsupp_ind … H) -L2 -T2
  74 /2 width=3 by frsup_fwd_lw/ (**) (* /3 width=5 by frsup_fwd_lw, transitive_le/ is too slow *)
  75 #L #T #L2 #T2 #_ #HL2 #HL1
  76 lapply (frsup_fwd_lw … HL2) -HL2 /2 width=3 by transitive_le/
  77 qed-.
  78
  79 lemma frsupp_fwd_tw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → #{T2} < #{T1}.
  80 #L1 #L2 #T1 #T2 #H @(frsupp_ind … H) -L2 -T2
  81 /3 width=3 by frsup_fwd_tw, transitive_lt/
  82 qed-.
  83
  84 lemma frsupp_fwd_append: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⧁+ ⦃L2, T2⦄ → ∃L. L2 = L1 @@ L.
  85 #L1 #L2 #T1 #T2 #H @(frsupp_ind … H) -L2 -T2 /2 width=3 by frsup_fwd_append/
  86 #L #T #L2 #T2 #_ #HL2 * #K1 #H destruct
  87 elim (frsup_fwd_append … HL2) -HL2 #K2 #H destruct /2 width=2/
  88 qed-.
  89
  90 (* Advanced forward lemmas **************************************************)
  91
  92 lemma lift_frsupp_trans: ∀L,U1,K,U2. ⦃L, U1⦄ ⧁+ ⦃L @@ K, U2⦄ →
  93                          ∀T1,d,e. ⇧[d, e] T1 ≡ U1 →
  94                          ∃T2. ⇧[d + |K|, e] T2 ≡ U2.
  95 #L #U1 @(f2_ind … fw … L U1) -L -U1 #n #IH
  96 #L #U1 #Hn #K #U2 #H #T1 #d #e #HTU1 destruct
  97 elim (frsupp_inv_sn … H) -H /2 width=5 by lift_frsup_trans/ *
  98 #L0 #U0 #HL0 #HL
  99 elim (frsup_fwd_append … HL0) #K0 #H destruct
 100 elim (frsupp_fwd_append … HL) #L0 >append_assoc #H
 101 elim (append_inj_dx … H ?) -H // #_ #H destruct
 102 <append_assoc in HL; #HL
 103 elim (lift_frsup_trans … HTU1 … HL0) -T1 #T #HTU
 104 lapply (frsup_fwd_fw … HL0) -HL0 #HL0
 105 elim (IH … HL … HTU) -IH -HL -T // -L -U1 -U0 /2 width=2/
 106 qed-.