matita/matita/contribs/lambdadelta/basic_2/unfold/lpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/lpss.ma".
  16 include "basic_2/unfold/cpqs.ma".
  17
  18 (* SN RESTRICTED PARALLEL COMPUTATION FOR LOCAL ENVIRONMENTS ****************)
  19
  20 definition lpqs: relation lenv ≝ lpx_sn cpqs.
  21
  22 interpretation "restricted parallel computation (local environment, sn variant)"
  23    'PRestStarSn L1 L2 = (lpqs L1 L2).
  24
  25 (* Basic inversion lemmas ***************************************************)
  26
  27 lemma lpqs_inv_atom1: ∀L2. ⋆ ⊢ ➤* L2 → L2 = ⋆.
  28 /2 width=4 by lpx_sn_inv_atom1_aux/ qed-.
  29
  30 lemma lpqs_inv_pair1: ∀I,K1,V1,L2. K1. ⓑ{I} V1 ⊢ ➤* L2 →
  31                       ∃∃K2,V2. K1 ⊢ ➤* K2 & K1 ⊢ V1 ➤* V2 & L2 = K2. ⓑ{I} V2.
  32 /2 width=3 by lpx_sn_inv_pair1_aux/ qed-.
  33
  34 lemma lpqs_inv_atom2: ∀L1. L1 ⊢ ➤* ⋆ → L1 = ⋆.
  35 /2 width=4 by lpx_sn_inv_atom2_aux/ qed-.
  36
  37 lemma lpqs_inv_pair2: ∀I,L1,K2,V2. L1 ⊢ ➤* K2. ⓑ{I} V2 →
  38                       ∃∃K1,V1. K1 ⊢ ➤* K2 & K1 ⊢ V1 ➤* V2 & L1 = K1. ⓑ{I} V1.
  39 /2 width=3 by lpx_sn_inv_pair2_aux/ qed-.
  40
  41 (* Basic properties *********************************************************)
  42
  43 lemma lpqs_refl: ∀L. L ⊢ ➤* L.
  44 /2 width=1 by lpx_sn_refl/ qed.
  45
  46 lemma lpqs_pair: ∀I,K1,K2,V1,V2. K1 ⊢ ➤* K2 → K1 ⊢ V1 ➤* V2 →
  47                  K1.ⓑ{I}V1 ⊢ ➤* K2.ⓑ{I}V2.
  48 /2 width=1/ qed.
  49
  50 lemma lpqs_append: ∀K1,K2. K1 ⊢ ➤* K2 → ∀L1,L2. L1 ⊢ ➤* L2 →
  51                    L1 @@ K1 ⊢ ➤* L2 @@ K2.
  52 /3 width=1 by lpx_sn_append, cpqs_append/ qed.
  53
  54 lemma lpss_lpqs: ∀L1,L2. L1 ⊢ ▶* L2 → L1 ⊢ ➤* L2.
  55 #L1 #L2 #H elim H -L1 -L2 // /3 width=1/
  56 qed.
  57
  58 (* Basic forward lemmas *****************************************************)
  59
  60 lemma lpqs_fwd_length: ∀L1,L2. L1 ⊢ ➤* L2 → |L1| = |L2|.
  61 /2 width=2 by lpx_sn_fwd_length/ qed-.
  62
  63 (* Advanced forward lemmas **************************************************)
  64
  65 lemma lpqs_fwd_append1: ∀K1,L1,L. K1 @@ L1 ⊢ ➤* L →
  66                         ∃∃K2,L2. K1 ⊢ ➤* K2 & L = K2 @@ L2.
  67 /2 width=2 by lpx_sn_fwd_append1/ qed-.
  68
  69 lemma lpqs_fwd_append2: ∀L,K2,L2. L ⊢ ➤* K2 @@ L2 →
  70                         ∃∃K1,L1. K1 ⊢ ➤* K2 & L = K1 @@ L1.
  71 /2 width=2 by lpx_sn_fwd_append2/ qed-.