matita/matita/contribs/lambdadelta/basic_2/unfold/lpqs_cpqs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/fsup.ma".
  16 include "basic_2/unfold/lpqs_ldrop.ma".
  17
  18 (* SN RESTRICTED PARALLEL COMPUTATION FOR LOCAL ENVIRONMENTS ****************)
  19
  20 (* Main properties on context-sensitive rest parallel computation for terms *)
  21
  22 fact cpqs_conf_lpqs_atom_atom:
  23    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ➤* T & L2 ⊢ ⓪{I} ➤* T.
  24 /2 width=3/ qed-.
  25
  26 fact cpqs_conf_lpqs_atom_delta:
  27    ∀L0,i. (
  28       ∀L,T.♯{L, T} < ♯{L0, #i} →
  29       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  30       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  31       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  32    ) →
  33    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  34    ∀V2. K0 ⊢ V0 ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  35    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  36    ∃∃T. L1 ⊢ #i ➤* T & L2 ⊢ T2 ➤* T.
  37 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  38 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  39 elim (lpqs_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  40 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  41 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  42 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  43 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  44 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  45 elim (lift_total V 0 (i+1)) #T #HVT
  46 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  47 qed-.
  48
  49 fact cpqs_conf_lpqs_delta_delta:
  50    ∀L0,i. (
  51       ∀L,T.♯{L, T} < ♯{L0, #i} →
  52       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  53       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  54       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  55    ) →
  56    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  57    ∀V1. K0 ⊢ V0 ➤* V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  58    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  59    ∀V2. KX ⊢ VX ➤* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  60    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  61    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
  62 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  63 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  64 lapply (ldrop_mono … H … HLK0) -H #H destruct
  65 elim (lpqs_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  66 elim (lpqs_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  67 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  68 elim (lpqs_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  69 elim (lpqs_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  70 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  71 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  72 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  73 elim (lift_total V 0 (i+1)) #T #HVT
  74 lapply (cpqs_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  75 lapply (cpqs_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  76 qed-.
  77
  78 fact cpqs_conf_lpqs_bind_bind:
  79    ∀a,I,L0,V0,T0. (
  80       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
  81       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  82       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
  83       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
  84    ) →
  85    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ➤* T1 →
  86    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ➤* T2 →
  87    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
  88    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ➤* T & L2 ⊢ ⓑ{a,I}V2.T2 ➤* T.
  89 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  90 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  91 elim (IH … HV01 … HV02 … HL01 … HL02) //
  92 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  93 qed-.
  94
  95 fact cpqs_conf_lpqs_bind_zeta:
  96    ∀L0,V0,T0. (
  97       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
  98       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
  99       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 100       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 101    ) →
 102    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 →
 103    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 104    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 105    ∃∃T. L1 ⊢ +ⓓV1.T1 ➤* T & L2 ⊢ X2 ➤* T.
 106 #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 107 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 108 elim (IH … HT01 … HT02 (L1.ⓓV1) … (L2.ⓓV1)) -IH -HT01 -HT02 // /2 width=1/ -L0 -V0 -T0 #T #HT1 #HT2
 109 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ /3 width=3/
 110 qed-.
 111
 112 fact cpqs_conf_lpqs_zeta_zeta:
 113    ∀L0,V0,T0. (
 114       ∀L,T.♯{L,T} < ♯{L0,+ⓓV0.T0} →
 115       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 116       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 117       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 118    ) →
 119    ∀T1. L0.ⓓV0 ⊢ T0 ➤* T1 → ∀X1. ⇧[O, 1] X1 ≡ T1 →
 120    ∀T2. L0.ⓓV0 ⊢ T0 ➤* T2 → ∀X2. ⇧[O, 1] X2 ≡ T2 →
 121    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 122    ∃∃T. L1 ⊢ X1 ➤* T & L2 ⊢ X2 ➤* T.
 123 #L0 #V0 #T0 #IH #T1 #HT01 #X1 #HXT1
 124 #T2 #HT02 #X2 #HXT2 #L1 #HL01 #L2 #HL02
 125 elim (IH … HT01 … HT02 (L1.ⓓV0) … (L2.ⓓV0)) -IH -HT01 -HT02 // /2 width=1/ -L0 -T0 #T #HT1 #HT2
 126 elim (cpqs_inv_lift1 … HT1 L1 … HXT1) -T1 /2 width=1/ #T1 #HT1 #HXT1
 127 elim (cpqs_inv_lift1 … HT2 L2 … HXT2) -T2 /2 width=1/ #T2 #HT2 #HXT2
 128 lapply (lift_inj … HT2 … HT1) -T #H destruct /2 width=3/
 129 qed-.
 130
 131 fact cpqs_conf_lpqs_flat_flat:
 132    ∀I,L0,V0,T0. (
 133       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
 134       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 135       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 136       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 137    ) →
 138    ∀V1. L0 ⊢ V0 ➤* V1 → ∀T1. L0 ⊢ T0 ➤* T1 →
 139    ∀V2. L0 ⊢ V0 ➤* V2 → ∀T2. L0 ⊢ T0 ➤* T2 →
 140    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 141    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ➤* T & L2 ⊢ ⓕ{I}V2.T2 ➤* T.
 142 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 143 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 144 elim (IH … HV01 … HV02 … HL01 … HL02) //
 145 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 146 qed-.
 147
 148 fact cpqs_conf_lpqs_flat_tau:
 149    ∀L0,V0,T0. (
 150       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 151       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 152       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 153       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 154    ) →
 155    ∀V1,T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 156    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 157    ∃∃T. L1 ⊢ ⓝV1.T1 ➤* T & L2 ⊢ T2 ➤* T.
 158 #L0 #V0 #T0 #IH #V1 #T1 #HT01
 159 #T2 #HT02 #L1 #HL01 #L2 #HL02
 160 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /3 width=3/
 161 qed-.
 162
 163 fact cpqs_conf_lpqs_tau_tau:
 164    ∀L0,V0,T0. (
 165       ∀L,T.♯{L,T} < ♯{L0,ⓝV0.T0} →
 166       ∀T1. L ⊢ T ➤* T1 → ∀T2. L ⊢ T ➤* T2 →
 167       ∀L1. L ⊢ ➤* L1 → ∀L2. L ⊢ ➤* L2 →
 168       ∃∃T0. L1 ⊢ T1 ➤* T0 & L2 ⊢ T2 ➤* T0
 169    ) →
 170    ∀T1. L0 ⊢ T0 ➤* T1 → ∀T2. L0 ⊢ T0 ➤* T2 →
 171    ∀L1. L0 ⊢ ➤* L1 → ∀L2. L0 ⊢ ➤* L2 →
 172    ∃∃T. L1 ⊢ T1 ➤* T & L2 ⊢ T2 ➤* T.
 173 #L0 #V0 #T0 #IH #T1 #HT01
 174 #T2 #HT02 #L1 #HL01 #L2 #HL02
 175 elim (IH … HT01 … HT02 … HL01 … HL02) // -L0 -V0 -T0 /2 width=3/
 176 qed-.
 177
 178 theorem cpqs_conf_lpqs: lpx_sn_confluent cpqs cpqs.
 179 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 180 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 181   elim (cpqs_inv_atom1 … H1) -H1
 182   elim (cpqs_inv_atom1 … H2) -H2
 183   [ #H2 #H1 destruct
 184     /2 width=1 by cpqs_conf_lpqs_atom_atom/
 185   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 186     /3 width=10 by cpqs_conf_lpqs_atom_delta/
 187   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 188     /4 width=10 by ex2_commute, cpqs_conf_lpqs_atom_delta/
 189   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 190     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 191     /3 width=17 by cpqs_conf_lpqs_delta_delta/
 192   ]
 193 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 194   elim (cpqs_inv_bind1 … H1) -H1 *
 195   [ #V1 #T1 #HV01 #HT01 #H1
 196   | #T1 #HT01 #HXT1 #H11 #H12
 197   ]
 198   elim (cpqs_inv_bind1 … H2) -H2 *
 199   [1,3: #V2 #T2 #HV02 #HT02 #H2
 200   |2,4: #T2 #HT02 #HXT2 #H21 #H22
 201   ] destruct
 202   [ /3 width=10 by cpqs_conf_lpqs_bind_bind/
 203   | /4 width=11 by ex2_commute, cpqs_conf_lpqs_bind_zeta/
 204   | /3 width=11 by cpqs_conf_lpqs_bind_zeta/
 205   | /3 width=12 by cpqs_conf_lpqs_zeta_zeta/
 206   ]
 207 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 208   elim (cpqs_inv_flat1 … H1) -H1 *
 209   [ #V1 #T1 #HV01 #HT01 #H1
 210   | #HX1 #H1
 211   ]
 212   elim (cpqs_inv_flat1 … H2) -H2 *
 213   [1,3: #V2 #T2 #HV02 #HT02 #H2
 214   |2,4: #HX2 #H2
 215   ] destruct
 216   [ /3 width=10 by cpqs_conf_lpqs_flat_flat/
 217   | /4 width=8 by ex2_commute, cpqs_conf_lpqs_flat_tau/
 218   | /3 width=8 by cpqs_conf_lpqs_flat_tau/
 219   | /3 width=7 by cpqs_conf_lpqs_tau_tau/
 220   ]
 221 ]
 222 qed-.
 223
 224 theorem cpqs_conf: ∀L. confluent … (cpqs L).
 225 /2 width=6 by cpqs_conf_lpqs/ qed-.
 226
 227 theorem cpqs_trans_lpqs: lpx_sn_transitive cpqs cpqs.
 228 #L1 #T1 @(f2_ind … fw … L1 T1) -L1 -T1 #n #IH #L1 * [|*]
 229 [ #I #Hn #T #H1 #L2 #HL12 #T2 #HT2 destruct
 230   elim (cpqs_inv_atom1 … H1) -H1
 231   [ #H destruct
 232     elim (cpqs_inv_atom1 … HT2) -HT2
 233     [ #H destruct //
 234     | * #K2 #V #V2 #i #HLK2 #HV2 #HVT2 #H destruct
 235       elim (lpqs_ldrop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
 236       elim (lpqs_inv_pair2 … H) -H #K1 #V1 #HK12 #HV1 #H destruct
 237       lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 238     ]
 239   | * #K1 #V1 #V #i #HLK1 #HV1 #HVT #H destruct
 240     elim (lpqs_ldrop_conf … HLK1 … HL12) -HL12 #X #H #HLK2
 241     elim (lpqs_inv_pair1 … H) -H #K2 #W2 #HK12 #_ #H destruct
 242     lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
 243     elim (cpqs_inv_lift1 … HT2 … HLK2 … HVT) -L2 -T
 244     lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 245   ]
 246 | #a #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 247   elim (cpqs_inv_bind1 … H1) -H1 *
 248   [ #V #T #HV1 #HT1 #H destruct
 249     elim (cpqs_inv_bind1 … H2) -H2 *
 250     [ #V2 #T2 #HV2 #HT2 #H destruct /4 width=5/
 251     | #T2 #HT2 #HXT2 #H1 #H2 destruct /4 width=5/
 252     ]
 253   | #Y1 #HTY1 #HXY1 #H11 #H12 destruct
 254     elim (lift_total X2 0 1) #Y2 #HXY2
 255     lapply (cpqs_lift … H2 (L2.ⓓV1) … HXY1 … HXY2) /2 width=1/ -X1 /4 width=5/
 256   ]
 257 | #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 258   elim (cpqs_inv_flat1 … H1) -H1 *
 259   [ #V #T #HV1 #HT1 #H destruct
 260     elim (cpqs_inv_flat1 … H2) -H2 *
 261     [ #V2 #T2 #HV2 #HT2 #H destruct /3 width=5/
 262     | #HX2 #H destruct /3 width=5/
 263     ]
 264   | #HX1 #H destruct /3 width=5/
 265 ]
 266 qed-.
 267
 268 theorem cpqs_trans: ∀L. Transitive … (cpqs L).
 269 /2 width=5 by cpqs_trans_lpqs/ qed-.
 270
 271 (* Properties on context-sensitive rest. parallel computation for terms *****)
 272
 273 lemma lpqs_cpqs_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 274                          ∃∃T. L1 ⊢ T0 ➤* T & L1 ⊢ T1 ➤* T.
 275 #L0 #T0 #T1 #HT01 #L1 #HL01
 276 elim (cpqs_conf_lpqs … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 277 qed-.
 278
 279 lemma lpqs_cpqs_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ➤* T1 → ∀L1. L0 ⊢ ➤* L1 →
 280                          ∃∃T. L1 ⊢ T0 ➤* T & L0 ⊢ T1 ➤* T.
 281 #L0 #T0 #T1 #HT01 #L1 #HL01
 282 elim (cpqs_conf_lpqs … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 283 qed-.
 284
 285 lemma lpqs_cpqs_trans: ∀L1,L2. L1 ⊢ ➤* L2 →
 286                        ∀T1,T2. L2 ⊢ T1 ➤* T2 → L1 ⊢ T1 ➤* T2.
 287 /2 width=5 by cpqs_trans_lpqs/ qed-.
 288
 289 lemma fsup_cpqs_trans: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀U2. L2 ⊢ T2 ➤* U2 →
 290                        ∃∃L,U1. L1 ⊢ ➤* L & L ⊢ T1 ➤* U1 & ⦃L, U1⦄ ⊃ ⦃L2, U2⦄.
 291 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
 292 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
 293 elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
 294 elim (lift_total T d e) #U #HTU
 295 elim (ldrop_lpqs_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
 296 lapply (cpqs_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
 297 qed-.