matita/matita/contribs/lambdadelta/basic_2/unfold/lpss_cpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/fsup.ma".
  16 include "basic_2/unfold/lpss_ldrop.ma".
  17
  18 (* SN PARALLEL UNFOLD FOR LOCAL ENVIRONMENTS ********************************)
  19
  20 (* Main properties on context-sensitive parallel unfold for terms ***********)
  21
  22 fact cpss_conf_lpss_atom_atom:
  23    ∀I,L1,L2. ∃∃T. L1 ⊢ ⓪{I} ▶* T & L2 ⊢ ⓪{I} ▶* T.
  24 /2 width=3/ qed-.
  25
  26 fact cpss_conf_lpss_atom_delta:
  27    ∀L0,i. (
  28       ∀L,T.♯{L, T} < ♯{L0, #i} →
  29       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  30       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  31       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  32    ) →
  33    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  34    ∀V2. K0 ⊢ V0 ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  35    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  36    ∃∃T. L1 ⊢ #i ▶* T & L2 ⊢ T2 ▶* T.
  37 #L0 #i #IH #K0 #V0 #HLK0 #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  38 elim (lpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  39 elim (lpss_inv_pair1 … H1) -H1 #K1 #V1 #HK01 #HV01 #H destruct
  40 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  41 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  42 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  43 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  44 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  45 elim (lift_total V 0 (i+1)) #T #HVT
  46 lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 /3 width=6/
  47 qed-.
  48
  49 fact cpss_conf_lpss_delta_delta:
  50    ∀L0,i. (
  51       ∀L,T.♯{L, T} < ♯{L0, #i} →
  52       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  53       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  54       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  55    ) →
  56    ∀K0,V0. ⇩[O, i] L0 ≡ K0.ⓓV0 →
  57    ∀V1. K0 ⊢ V0 ▶* V1 → ∀T1. ⇧[O, i + 1] V1 ≡ T1 →
  58    ∀KX,VX. ⇩[O, i] L0 ≡ KX.ⓓVX →
  59    ∀V2. KX ⊢ VX ▶* V2 → ∀T2. ⇧[O, i + 1] V2 ≡ T2 →
  60    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  61    ∃∃T. L1 ⊢ T1 ▶* T & L2 ⊢ T2 ▶* T.
  62 #L0 #i #IH #K0 #V0 #HLK0 #V1 #HV01 #T1 #HVT1
  63 #KX #VX #H #V2 #HV02 #T2 #HVT2 #L1 #HL01 #L2 #HL02
  64 lapply (ldrop_mono … H … HLK0) -H #H destruct
  65 elim (lpss_ldrop_conf … HLK0 … HL01) -HL01 #X1 #H1 #HLK1
  66 elim (lpss_inv_pair1 … H1) -H1 #K1 #W1 #HK01 #_ #H destruct
  67 lapply (ldrop_fwd_ldrop2 … HLK1) -W1 #HLK1
  68 elim (lpss_ldrop_conf … HLK0 … HL02) -HL02 #X2 #H2 #HLK2
  69 elim (lpss_inv_pair1 … H2) -H2 #K2 #W2 #HK02 #_ #H destruct
  70 lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
  71 lapply (ldrop_pair2_fwd_fw … HLK0 (#i)) -HLK0 #HLK0
  72 elim (IH … HLK0 … HV01 … HV02 … HK01 … HK02) -L0 -K0 -V0 #V #HV1 #HV2
  73 elim (lift_total V 0 (i+1)) #T #HVT
  74 lapply (cpss_lift … HV1 … HLK1 … HVT1 … HVT) -K1 -V1
  75 lapply (cpss_lift … HV2 … HLK2 … HVT2 … HVT) -K2 -V2 -V /2 width=3/
  76 qed-.
  77
  78 fact cpss_conf_lpss_bind_bind:
  79    ∀a,I,L0,V0,T0. (
  80       ∀L,T.♯{L,T} < ♯{L0,ⓑ{a,I}V0.T0} →
  81       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  82       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
  83       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
  84    ) →
  85    ∀V1. L0 ⊢ V0 ▶* V1 → ∀T1. L0.ⓑ{I}V0 ⊢ T0 ▶* T1 →
  86    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0.ⓑ{I}V0 ⊢ T0 ▶* T2 →
  87    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
  88    ∃∃T. L1 ⊢ ⓑ{a,I}V1.T1 ▶* T & L2 ⊢ ⓑ{a,I}V2.T2 ▶* T.
  89 #a #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
  90 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
  91 elim (IH … HV01 … HV02 … HL01 … HL02) //
  92 elim (IH … HT01 … HT02 (L1.ⓑ{I}V1) … (L2.ⓑ{I}V2)) -IH // /2 width=1/ /3 width=5/
  93 qed-.
  94
  95 fact cpss_conf_lpss_flat_flat:
  96    ∀I,L0,V0,T0. (
  97       ∀L,T.♯{L,T} < ♯{L0,ⓕ{I}V0.T0} →
  98       ∀T1. L ⊢ T ▶* T1 → ∀T2. L ⊢ T ▶* T2 →
  99       ∀L1. L ⊢ ▶* L1 → ∀L2. L ⊢ ▶* L2 →
 100       ∃∃T0. L1 ⊢ T1 ▶* T0 & L2 ⊢ T2 ▶* T0
 101    ) →
 102    ∀V1. L0 ⊢ V0 ▶* V1 → ∀T1. L0 ⊢ T0 ▶* T1 →
 103    ∀V2. L0 ⊢ V0 ▶* V2 → ∀T2. L0 ⊢ T0 ▶* T2 →
 104    ∀L1. L0 ⊢ ▶* L1 → ∀L2. L0 ⊢ ▶* L2 →
 105    ∃∃T. L1 ⊢ ⓕ{I}V1.T1 ▶* T & L2 ⊢ ⓕ{I}V2.T2 ▶* T.
 106 #I #L0 #V0 #T0 #IH #V1 #HV01 #T1 #HT01
 107 #V2 #HV02 #T2 #HT02 #L1 #HL01 #L2 #HL02
 108 elim (IH … HV01 … HV02 … HL01 … HL02) //
 109 elim (IH … HT01 … HT02 … HL01 … HL02) // /3 width=5/
 110 qed-.
 111
 112 theorem cpss_conf_lpss: lpx_sn_confluent cpss cpss.
 113 #L0 #T0 @(f2_ind … fw … L0 T0) -L0 -T0 #n #IH #L0 * [|*]
 114 [ #I0 #Hn #T1 #H1 #T2 #H2 #L1 #HL01 #L2 #HL02 destruct
 115   elim (cpss_inv_atom1 … H1) -H1
 116   elim (cpss_inv_atom1 … H2) -H2
 117   [ #H2 #H1 destruct
 118     /2 width=1 by cpss_conf_lpss_atom_atom/
 119   | * #K0 #V0 #V2 #i2 #HLK0 #HV02 #HVT2 #H2 #H1 destruct
 120     /3 width=10 by cpss_conf_lpss_atom_delta/
 121   | #H2 * #K0 #V0 #V1 #i1 #HLK0 #HV01 #HVT1 #H1 destruct
 122     /4 width=10 by ex2_commute, cpss_conf_lpss_atom_delta/
 123   | * #X #Y #V2 #z #H #HV02 #HVT2 #H2
 124     * #K0 #V0 #V1 #i #HLK0 #HV01 #HVT1 #H1 destruct
 125     /3 width=17 by cpss_conf_lpss_delta_delta/
 126   ]
 127 | #a #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 128   elim (cpss_inv_bind1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
 129   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
 130   /3 width=10 by cpss_conf_lpss_bind_bind/
 131 | #I #V0 #T0 #Hn #X1 #H1 #X2 #H2 #L1 #HL01 #L2 #HL02 destruct
 132   elim (cpss_inv_flat1 … H1) -H1 #V1 #T1 #HV01 #HT01 #H destruct
 133   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV02 #HT02 #H destruct
 134   /3 width=10 by cpss_conf_lpss_flat_flat/
 135 ]
 136 qed-.
 137
 138 (* Basic_1: was only: subst1_confluence_eq *)
 139 theorem cpss_conf: ∀L. confluent … (cpss L).
 140 /2 width=6 by cpss_conf_lpss/ qed-.
 141
 142 theorem cpss_trans_lpss: lpx_sn_transitive cpss cpss.
 143 #L1 #T1 @(f2_ind … fw … L1 T1) -L1 -T1 #n #IH #L1 * [|*]
 144 [ #I #Hn #T #H1 #L2 #HL12 #T2 #HT2 destruct
 145   elim (cpss_inv_atom1 … H1) -H1
 146   [ #H destruct
 147     elim (cpss_inv_atom1 … HT2) -HT2
 148     [ #H destruct //
 149     | * #K2 #V #V2 #i #HLK2 #HV2 #HVT2 #H destruct
 150       elim (lpss_ldrop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
 151       elim (lpss_inv_pair2 … H) -H #K1 #V1 #HK12 #HV1 #H destruct
 152       lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 153     ]
 154   | * #K1 #V1 #V #i #HLK1 #HV1 #HVT #H destruct
 155     elim (lpss_ldrop_conf … HLK1 … HL12) -HL12 #X #H #HLK2
 156     elim (lpss_inv_pair1 … H) -H #K2 #W2 #HK12 #_ #H destruct
 157     lapply (ldrop_fwd_ldrop2 … HLK2) -W2 #HLK2
 158     elim (cpss_inv_lift1 … HT2 … HLK2 … HVT) -L2 -T
 159     lapply (ldrop_pair2_fwd_fw … HLK1 (#i)) /3 width=9/
 160   ]
 161 | #a #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 162   elim (cpss_inv_bind1 … H1) -H1 #V #T #HV1 #HT1 #H destruct
 163   elim (cpss_inv_bind1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct /4 width=5/
 164 | #I #V1 #T1 #Hn #X1 #H1 #L2 #HL12 #X2 #H2
 165   elim (cpss_inv_flat1 … H1) -H1 #V #T #HV1 #HT1 #H destruct
 166   elim (cpss_inv_flat1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct /3 width=5/
 167 ]
 168 qed-.
 169
 170 (* Basic_1: was only: subst1_trans *)
 171 theorem cpss_trans: ∀L. Transitive … (cpss L).
 172 /2 width=5 by cpss_trans_lpss/ qed-.
 173
 174 (* Properties on context-sensitive parallel unfold for terms ****************)
 175
 176 (* Basic_1: was only: subst1_subst1_back *)
 177 lemma lpss_cpss_conf_dx: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 178                          ∃∃T. L1 ⊢ T0 ▶* T & L1 ⊢ T1 ▶* T.
 179 #L0 #T0 #T1 #HT01 #L1 #HL01
 180 elim (cpss_conf_lpss … HT01 T0 … HL01 … HL01) // -L0 /2 width=3/
 181 qed-.
 182
 183 lemma lpss_cpss_conf_sn: ∀L0,T0,T1. L0 ⊢ T0 ▶* T1 → ∀L1. L0 ⊢ ▶* L1 →
 184                          ∃∃T. L1 ⊢ T0 ▶* T & L0 ⊢ T1 ▶* T.
 185 #L0 #T0 #T1 #HT01 #L1 #HL01
 186 elim (cpss_conf_lpss … HT01 T0 … L0 … HL01) // -HT01 -HL01 /2 width=3/
 187 qed-.
 188
 189 (* Basic_1: was only: subst1_subst1 *)
 190 lemma lpss_cpss_trans: ∀L1,L2. L1 ⊢ ▶* L2 →
 191                        ∀T1,T2. L2 ⊢ T1 ▶* T2 → L1 ⊢ T1 ▶* T2.
 192 /2 width=5 by cpss_trans_lpss/ qed-.
 193
 194 lemma fsup_cpss_trans: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ∀U2. L2 ⊢ T2 ▶* U2 →
 195                        ∃∃L,U1. L1 ⊢ ▶* L & L ⊢ T1 ▶* U1 & ⦃L, U1⦄ ⊃ ⦃L2, U2⦄.
 196 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 [1,2,3,4,5: /3 width=5/ ]
 197 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #U2 #HTU2
 198 elim (IHT12 … HTU2) -IHT12 -HTU2 #K #T #HK1 #HT1 #HT2
 199 elim (lift_total T d e) #U #HTU
 200 elim (ldrop_lpss_trans … HLK1 … HK1) -HLK1 -HK1 #L2 #HL12 #HL2K
 201 lapply (cpss_lift … HT1 … HL2K … HTU1 … HTU) -HT1 -HTU1 /3 width=11/
 202 qed-.