matita/matita/contribs/lambdadelta/basic_2/unfold/lsstas.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/statictypestar_7.ma".
  16 include "basic_2/static/ssta.ma".
  17
  18 (* NAT-ITERATED STRATIFIED STATIC TYPE ASSIGNMENT FOR TERMS *****************)
  19
  20 definition lsstas: ∀h. sd h → genv → lenv → nat → relation term ≝
  21                    λh,g,G,L. lstar … (ssta h g G L).
  22
  23 interpretation "nat-iterated stratified static type assignment (term)"
  24    'StaticTypeStar h g G L l T U = (lsstas h g G L l T U).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma lsstas_ind_sn: ∀h,g,G,L,U2. ∀R:relation2 nat term.
  29                      R 0 U2 → (
  30                         ∀l,T,U1. ⦃G, L⦄ ⊢ T •[h, g] U1 → ⦃G, L⦄ ⊢ U1 •* [h, g, l] U2 →
  31                         R l U1 → R (l+1) T
  32                      ) →
  33                      ∀l,T. ⦃G, L⦄ ⊢ T •*[h, g, l] U2 → R l T.
  34 /3 width=5 by lstar_ind_l/ qed-.
  35
  36 lemma lsstas_ind_dx: ∀h,g,G,L,T. ∀R:relation2 nat term.
  37                      R 0 T → (
  38                         ∀l,U1,U2. ⦃G, L⦄ ⊢ T •* [h, g, l] U1 →  ⦃G, L⦄ ⊢ U1 •[h, g] U2 →
  39                         R l U1 → R (l+1) U2
  40                      ) →
  41                      ∀l,U. ⦃G, L⦄ ⊢ T •*[h, g, l] U → R l U.
  42 /3 width=5 by lstar_ind_r/ qed-.
  43
  44 (* Basic inversion lemmas ***************************************************)
  45
  46 lemma lsstas_inv_O: ∀h,g,G,L,T,U. ⦃G, L⦄ ⊢ T •*[h, g, 0] U → T = U.
  47 /2 width=4 by lstar_inv_O/ qed-.
  48
  49 lemma lsstas_inv_SO: ∀h,g,G,L,T,U. ⦃G, L⦄ ⊢ T •*[h, g, 1] U → ⦃G, L⦄ ⊢ T •[h, g] U.
  50 /2 width=1 by lstar_inv_step/ qed-.
  51
  52 lemma lsstas_inv_step_sn: ∀h,g,G,L,T1,T2,l. ⦃G, L⦄ ⊢ T1 •*[h, g, l+1] T2 →
  53                          ∃∃T. ⦃G, L⦄ ⊢ T1 •[h, g] T & ⦃G, L⦄ ⊢ T •*[h, g, l] T2.
  54 /2 width=3 by lstar_inv_S/ qed-.
  55
  56 lemma lsstas_inv_step_dx: ∀h,g,G,L,T1,T2,l. ⦃G, L⦄ ⊢ T1 •*[h, g, l+1] T2 →
  57                           ∃∃T. ⦃G, L⦄ ⊢ T1 •*[h, g, l] T & ⦃G, L⦄ ⊢ T •[h, g] T2.
  58 /2 width=3 by lstar_inv_S_dx/ qed-.
  59
  60 lemma lsstas_inv_sort1: ∀h,g,G,L,X,k,l. ⦃G, L⦄ ⊢ ⋆k •*[h, g, l] X → X = ⋆((next h)^l k).
  61 #h #g #G #L #X #k #l #H @(lsstas_ind_dx … H) -X -l //
  62 #l #X #X0 #_ #H #IHX destruct
  63 lapply (ssta_inv_sort1 … H) -H #H destruct
  64 >iter_SO //
  65 qed-.
  66
  67 lemma lsstas_inv_gref1: ∀h,g,G,L,X,p,l. ⦃G, L⦄ ⊢ §p •*[h, g, l+1] X → ⊥.
  68 #h #g #G #L #X #p #l #H elim (lsstas_inv_step_sn … H) -H
  69 #U #H #HUX elim (ssta_inv_gref1 … H)
  70 qed-.
  71
  72 lemma lsstas_inv_bind1: ∀h,g,a,I,G,L,V,T,X,l. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T •*[h, g, l] X →
  73                         ∃∃U. ⦃G, L.ⓑ{I}V⦄ ⊢ T •*[h, g, l] U & X = ⓑ{a,I}V.U.
  74 #h #g #a #I #G #L #V #T #X #l #H @(lsstas_ind_dx … H) -X -l [ /2 width=3/ ]
  75 #l #X #X0 #_ #HX0 * #U #HTU #H destruct
  76 elim (ssta_inv_bind1 … HX0) -HX0 #U0 #HU0 #H destruct /3 width=3/
  77 qed-.
  78
  79 lemma lsstas_inv_appl1: ∀h,g,G,L,V,T,X,l. ⦃G, L⦄ ⊢ ⓐV.T •*[h, g, l] X →
  80                         ∃∃U. ⦃G, L⦄ ⊢ T •*[h, g, l] U & X = ⓐV.U.
  81 #h #g #G #L #V #T #X #l #H @(lsstas_ind_dx … H) -X -l [ /2 width=3/ ]
  82 #l #X #X0 #_ #HX0 * #U #HTU #H destruct
  83 elim (ssta_inv_appl1 … HX0) -HX0 #U0 #HU0 #H destruct /3 width=3/
  84 qed-.
  85
  86 lemma lsstas_inv_cast1: ∀h,g,G,L,W,T,U,l. ⦃G, L⦄ ⊢ ⓝW.T •*[h, g, l+1] U → ⦃G, L⦄ ⊢ T •*[h, g, l+1] U.
  87 #h #g #G #L #W #T #X #l #H elim (lsstas_inv_step_sn … H) -H
  88 #U #H #HUX lapply (ssta_inv_cast1 … H) -H /2 width=3/
  89 qed-.
  90
  91 (* Basic properties *********************************************************)
  92
  93 lemma lsstas_refl: ∀h,g,G,L. reflexive … (lsstas h g G L 0).
  94 // qed.
  95
  96 lemma ssta_lsstas: ∀h,g,G,L,T,U. ⦃G, L⦄ ⊢ T •[h, g] U → ⦃G, L⦄ ⊢ T •*[h, g, 1] U.
  97 /2 width=1/ qed.
  98
  99 lemma lsstas_step_sn: ∀h,g,G,L,T1,U1,U2,l. ⦃G, L⦄ ⊢ T1 •[h, g] U1 → ⦃G, L⦄ ⊢ U1 •*[h, g, l] U2 →
 100                       ⦃G, L⦄ ⊢ T1 •*[h, g, l+1] U2.
 101 /2 width=3/ qed.
 102
 103 lemma lsstas_step_dx: ∀h,g,G,L,T1,T2,U2,l. ⦃G, L⦄ ⊢ T1 •*[h, g, l] T2 → ⦃G, L⦄ ⊢ T2 •[h, g] U2 →
 104                       ⦃G, L⦄ ⊢ T1 •*[h, g, l+1] U2.
 105 /2 width=3/ qed.
 106
 107 lemma lsstas_split: ∀h,g,G,L. inv_ltransitive … (lsstas h g G L).
 108 /2 width=1 by lstar_inv_ltransitive/ qed-.
 109
 110 lemma lsstas_sort: ∀h,g,G,L,l,k. ⦃G, L⦄ ⊢ ⋆k •*[h, g, l] ⋆((next h)^l k).
 111 #h #g #G #L #l @(nat_ind_plus … l) -l //
 112 #l #IHl #k >iter_SO /2 width=3/
 113 qed.
 114
 115 lemma lsstas_bind: ∀h,g,I,G,L,V,T,U,l. ⦃G, L.ⓑ{I}V⦄ ⊢ T •*[h, g, l] U →
 116                    ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T •*[h, g, l] ⓑ{a,I}V.U.
 117 #h #g #I #G #L #V #T #U #l #H @(lsstas_ind_dx … H) -U -l // /3 width=3/
 118 qed.
 119
 120 lemma lsstas_appl: ∀h,g,G,L,T,U,l. ⦃G, L⦄ ⊢ T •*[h, g, l] U →
 121                    ∀V.⦃G, L⦄ ⊢ ⓐV.T •*[h, g, l] ⓐV.U.
 122 #h #g #G #L #T #U #l #H @(lsstas_ind_dx … H) -U -l // /3 width=3/
 123 qed.
 124
 125 lemma lsstas_cast: ∀h,g,G,L,T,U,l. ⦃G, L⦄ ⊢ T •*[h, g, l+1] U →
 126                    ∀W. ⦃G, L⦄ ⊢ ⓝW.T •*[h, g, l+1] U.
 127 #h #g #G #L #T #U #l #H elim (lsstas_inv_step_sn … H) -H /3 width=3/
 128 qed.
 129
 130 (* Basic_1: removed theorems 7:
 131             sty1_abbr sty1_appl sty1_bind sty1_cast2
 132             sty1_correct sty1_lift sty1_trans
 133 *)