matita/matita/contribs/lambdadelta/basic_2/unfold/tpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/tps.ma".
  16
  17 (* PARTIAL UNFOLD ON TERMS **************************************************)
  18
  19 definition tpss: nat → nat → lenv → relation term ≝
  20                  λd,e,L. TC … (tps d e L).
  21
  22 interpretation "partial unfold (term)"
  23    'PSubstStar L T1 d e T2 = (tpss d e L T1 T2).
  24
  25 (* Basic eliminators ********************************************************)
  26
  27 lemma tpss_ind: ∀d,e,L,T1. ∀R:predicate term. R T1 →
  28                 (∀T,T2. L ⊢ T1 ▶* [d, e] T → L ⊢ T ▶ [d, e] T2 → R T → R T2) →
  29                 ∀T2. L ⊢ T1 ▶* [d, e] T2 → R T2.
  30 #d #e #L #T1 #R #HT1 #IHT1 #T2 #HT12
  31 @(TC_star_ind … HT1 IHT1 … HT12) //
  32 qed-.
  33
  34 lemma tpss_ind_dx: ∀d,e,L,T2. ∀R:predicate term. R T2 →
  35                    (∀T1,T. L ⊢ T1 ▶ [d, e] T → L ⊢ T ▶* [d, e] T2 → R T → R T1) →
  36                    ∀T1. L ⊢ T1 ▶* [d, e] T2 → R T1.
  37 #d #e #L #T2 #R #HT2 #IHT2 #T1 #HT12
  38 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  39 qed-.
  40
  41 (* Basic properties *********************************************************)
  42
  43 lemma tps_tpss: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  44 /2 width=1/ qed.
  45
  46 lemma tpss_strap1: ∀L,T1,T,T2,d,e.
  47                    L ⊢ T1 ▶* [d, e] T → L ⊢ T ▶ [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  48 /2 width=3/ qed.
  49
  50 lemma tpss_strap2: ∀L,T1,T,T2,d,e.
  51                    L ⊢ T1 ▶ [d, e] T → L ⊢ T ▶* [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  52 /2 width=3/ qed.
  53
  54 lemma tpss_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ T1 ▶* [d, e] T2 →
  55                         ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ T1 ▶* [d, e] T2.
  56 /3 width=3/ qed.
  57
  58 lemma tpss_refl: ∀d,e,L,T. L ⊢ T ▶* [d, e] T.
  59 /2 width=1/ qed.
  60
  61 lemma tpss_bind: ∀L,V1,V2,d,e. L ⊢ V1 ▶* [d, e] V2 →
  62                  ∀a,I,T1,T2. L. ⓑ{I} V2 ⊢ T1 ▶* [d + 1, e] T2 →
  63                  L ⊢ ⓑ{a,I} V1. T1 ▶* [d, e] ⓑ{a,I} V2. T2.
  64 #L #V1 #V2 #d #e #HV12 elim HV12 -V2
  65 [ #V2 #HV12 #a #I #T1 #T2 #HT12 elim HT12 -T2
  66   [ /3 width=5/
  67   | #T #T2 #_ #HT2 #IHT @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  68   ]
  69 | #V #V2 #_ #HV12 #IHV #a #I #T1 #T2 #HT12
  70   lapply (tpss_lsubs_trans … HT12 (L. ⓑ{I} V) ?) -HT12 /2 width=1/ #HT12
  71   lapply (IHV a … HT12) -IHV -HT12 #HT12 @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  72 ]
  73 qed.
  74
  75 lemma tpss_flat: ∀L,I,V1,V2,T1,T2,d,e.
  76                  L ⊢ V1 ▶* [d, e] V2 → L ⊢ T1 ▶* [d, e] T2 →
  77                  L ⊢ ⓕ{I} V1. T1 ▶* [d, e] ⓕ{I} V2. T2.
  78 #L #I #V1 #V2 #T1 #T2 #d #e #HV12 elim HV12 -V2
  79 [ #V2 #HV12 #HT12 elim HT12 -T2
  80   [ /3 width=1/
  81   | #T #T2 #_ #HT2 #IHT @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  82   ]
  83 | #V #V2 #_ #HV12 #IHV #HT12
  84   lapply (IHV … HT12) -IHV -HT12 #HT12 @step /2 width=5/ (**) (* /3 width=5/ is too slow *)
  85 ]
  86 qed.
  87
  88 lemma tpss_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 ▶* [d1, e1] T2 →
  89                  ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  90                  L ⊢ T1 ▶* [d2, e2] T2.
  91 #L #T1 #T2 #d1 #e1 #H #d1 #d2 #Hd21 #Hde12 @(tpss_ind … H) -T2
  92 [ //
  93 | #T #T2 #_ #HT12 #IHT
  94   lapply (tps_weak … HT12 … Hd21 Hde12) -HT12 -Hd21 -Hde12 /2 width=3/
  95 ]
  96 qed.
  97
  98 lemma tpss_weak_top: ∀L,T1,T2,d,e.
  99                      L ⊢ T1 ▶* [d, e] T2 → L ⊢ T1 ▶* [d, |L| - d] T2.
 100 #L #T1 #T2 #d #e #H @(tpss_ind … H) -T2
 101 [ //
 102 | #T #T2 #_ #HT12 #IHT
 103   lapply (tps_weak_top … HT12) -HT12 /2 width=3/
 104 ]
 105 qed.
 106
 107 lemma tpss_weak_all: ∀L,T1,T2,d,e.
 108                      L ⊢ T1 ▶* [d, e] T2 → L ⊢ T1 ▶* [0, |L|] T2.
 109 #L #T1 #T2 #d #e #HT12
 110 lapply (tpss_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
 111 lapply (tpss_weak_top … HT12) //
 112 qed.
 113
 114 lemma tpss_append: ∀K,T1,T2,d,e. K ⊢ T1 ▶* [d, e] T2 →
 115                    ∀L. L @@ K ⊢ T1 ▶* [d, e] T2.
 116 #K #T1 #T2 #d #e #H @(tpss_ind … H) -T2 // /3 width=3/
 117 qed.
 118
 119 (* Basic inversion lemmas ***************************************************)
 120
 121 (* Note: this can be derived from tpss_inv_atom1 *)
 122 lemma tpss_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k ▶* [d, e] T2 → T2 = ⋆k.
 123 #L #T2 #k #d #e #H @(tpss_ind … H) -T2
 124 [ //
 125 | #T #T2 #_ #HT2 #IHT destruct
 126   >(tps_inv_sort1 … HT2) -HT2 //
 127 ]
 128 qed-.
 129
 130 (* Note: this can be derived from tpss_inv_atom1 *)
 131 lemma tpss_inv_gref1: ∀L,T2,p,d,e. L ⊢ §p ▶* [d, e] T2 → T2 = §p.
 132 #L #T2 #p #d #e #H @(tpss_ind … H) -T2
 133 [ //
 134 | #T #T2 #_ #HT2 #IHT destruct
 135   >(tps_inv_gref1 … HT2) -HT2 //
 136 ]
 137 qed-.
 138
 139 lemma tpss_inv_bind1: ∀d,e,L,a,I,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶* [d, e] U2 →
 140                       ∃∃V2,T2. L ⊢ V1 ▶* [d, e] V2 &
 141                                L. ⓑ{I} V2 ⊢ T1 ▶* [d + 1, e] T2 &
 142                                U2 = ⓑ{a,I} V2. T2.
 143 #d #e #L #a #I #V1 #T1 #U2 #H @(tpss_ind … H) -U2
 144 [ /2 width=5/
 145 | #U #U2 #_ #HU2 * #V #T #HV1 #HT1 #H destruct
 146   elim (tps_inv_bind1 … HU2) -HU2 #V2 #T2 #HV2 #HT2 #H
 147   lapply (tpss_lsubs_trans … HT1 (L. ⓑ{I} V2) ?) -HT1 /2 width=1/ /3 width=5/
 148 ]
 149 qed-.
 150
 151 lemma tpss_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶* [d, e] U2 →
 152                       ∃∃V2,T2. L ⊢ V1 ▶* [d, e] V2 & L ⊢ T1 ▶* [d, e] T2 &
 153                                U2 =  ⓕ{I} V2. T2.
 154 #d #e #L #I #V1 #T1 #U2 #H @(tpss_ind … H) -U2
 155 [ /2 width=5/
 156 | #U #U2 #_ #HU2 * #V #T #HV1 #HT1 #H destruct
 157   elim (tps_inv_flat1 … HU2) -HU2 /3 width=5/
 158 ]
 159 qed-.
 160
 161 lemma tpss_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 ▶* [d, 0] T2 → T1 = T2.
 162 #L #T1 #T2 #d #H @(tpss_ind … H) -T2
 163 [ //
 164 | #T #T2 #_ #HT2 #IHT <(tps_inv_refl_O2 … HT2) -HT2 //
 165 ]
 166 qed-.
 167
 168 (* Basic forward lemmas *****************************************************)
 169
 170 lemma tpss_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 ▶* [d, e] T2 → ♯{T1} ≤ ♯{T2}.
 171 #L #T1 #T2 #d #e #H @(tpss_ind … H) -T2 //
 172 #T #T2 #_ #HT2 #IHT1
 173 lapply (tps_fwd_tw … HT2) -HT2 #HT2
 174 @(transitive_le … IHT1) //
 175 qed-.
 176
 177 lemma tpss_fwd_shift1: ∀L,L1,T1,T,d,e. L ⊢ L1 @@ T1 ▶*[d, e] T →
 178                        ∃∃L2,T2. |L1| = |L2| & T = L2 @@ T2.
 179 #L #L1 #T1 #T #d #e #H @(tpss_ind … H) -T
 180 [ /2 width=4/
 181 | #T #X #_ #H0 * #L0 #T0 #HL10 #H destruct
 182   elim (tps_fwd_shift1 … H0) -H0 #L2 #T2 #HL02 #H destruct /2 width=4/
 183 ]
 184 qed-.
 185