matita/matita/contribs/lambdadelta/basic_2/unfold/tpss_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss_lift.ma".
  16
  17 (* PARALLEL UNFOLD ON TERMS *************************************************)
  18
  19 (* alternative definition of tpss *)
  20 inductive tpssa: nat → nat → lenv → relation term ≝
  21 | tpssa_atom : ∀L,I,d,e. tpssa d e L (⓪{I}) (⓪{I})
  22 | tpssa_subst: ∀L,K,V1,V2,W2,i,d,e. d ≤ i → i < d + e →
  23                ⇩[0, i] L ≡ K. ⓓV1 → tpssa 0 (d + e - i - 1) K V1 V2 →
  24                ⇧[0, i + 1] V2 ≡ W2 → tpssa d e L (#i) W2
  25 | tpssa_bind : ∀L,a,I,V1,V2,T1,T2,d,e.
  26                tpssa d e L V1 V2 → tpssa (d + 1) e (L. ⓑ{I} V2) T1 T2 →
  27                tpssa d e L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  28 | tpssa_flat : ∀L,I,V1,V2,T1,T2,d,e.
  29                tpssa d e L V1 V2 → tpssa d e L T1 T2 →
  30                tpssa d e L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  31 .
  32
  33 interpretation "parallel unfold (term) alternative"
  34    'PSubstStarAlt L T1 d e T2 = (tpssa d e L T1 T2).
  35
  36 (* Basic properties *********************************************************)
  37
  38 lemma tpssa_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ T1 ▶▶* [d, e] T2 →
  39                          ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ T1 ▶▶* [d, e] T2.
  40 #L1 #T1 #T2 #d #e #H elim H -L1 -T1 -T2 -d -e
  41 [ //
  42 | #L1 #K1 #V1 #V2 #W2 #i #d #e #Hdi #Hide #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  43   elim (ldrop_lsubs_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // /3 width=6/
  44 | /4 width=1/
  45 | /3 width=1/
  46 ]
  47 qed.
  48
  49 lemma tpssa_refl: ∀T,L,d,e. L ⊢ T ▶▶* [d, e] T.
  50 #T elim T -T //
  51 #I elim I -I /2 width=1/
  52 qed.
  53
  54 lemma tpssa_tps_trans: ∀L,T1,T,d,e. L ⊢ T1 ▶▶* [d, e] T →
  55                        ∀T2. L ⊢ T ▶ [d, e] T2 → L ⊢ T1 ▶▶* [d, e] T2.
  56 #L #T1 #T #d #e #H elim H -L -T1 -T -d -e
  57 [ #L #I #d #e #X #H
  58   elim (tps_inv_atom1 … H) -H // * /2 width=6/
  59 | #L #K #V1 #V2 #W2 #i #d #e #Hdi #Hide #HLK #_ #HVW2 #IHV12 #T2 #H
  60   lapply (ldrop_fwd_ldrop2 … HLK) #H0LK
  61   lapply (tps_weak … H 0 (d+e) ? ?) -H // #H
  62   elim (tps_inv_lift1_be … H … H0LK … HVW2 ? ?) -H -H0LK -HVW2 // /3 width=6/
  63 | #L #a #I #V1 #V #T1 #T #d #e #_ #_ #IHV1 #IHT1 #X #H
  64   elim (tps_inv_bind1 … H) -H #V2 #T2 #HV2 #HT2 #H destruct
  65   lapply (tps_lsubs_trans … HT2 (L.ⓑ{I}V) ?) -HT2 /2 width=1/ #HT2
  66   lapply (IHV1 … HV2) -IHV1 -HV2 #HV12
  67   lapply (IHT1 … HT2) -IHT1 -HT2 #HT12
  68   lapply (tpssa_lsubs_trans … HT12 (L.ⓑ{I}V2) ?) -HT12 /2 width=1/
  69 | #L #I #V1 #V #T1 #T #d #e #_ #_ #IHV1 #IHT1 #X #H
  70   elim (tps_inv_flat1 … H) -H #V2 #T2 #HV2 #HT2 #H destruct /3 width=1/
  71 ]
  72 qed.
  73
  74 lemma tpss_tpssa: ∀L,T1,T2,d,e. L ⊢ T1 ▶* [d, e] T2 → L ⊢ T1 ▶▶* [d, e] T2.
  75 #L #T1 #T2 #d #e #H @(tpss_ind … H) -T2 // /2 width=3/
  76 qed.
  77
  78 (* Basic inversion lemmas ***************************************************)
  79
  80 lemma tpssa_tpss: ∀L,T1,T2,d,e. L ⊢ T1 ▶▶* [d, e] T2 → L ⊢ T1 ▶* [d, e] T2.
  81 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e // /2 width=6/
  82 qed-.
  83
  84 lemma tpss_ind_alt: ∀R:ℕ→ℕ→lenv→relation term.
  85                     (∀L,I,d,e. R d e L (⓪{I}) (⓪{I})) →
  86                     (∀L,K,V1,V2,W2,i,d,e. d ≤ i → i < d + e →
  87                      ⇩[O, i] L ≡ K.ⓓV1 → K ⊢ V1 ▶* [O, d + e - i - 1] V2 →
  88                      ⇧[O, i + 1] V2 ≡ W2 → R O (d+e-i-1) K V1 V2 → R d e L #i W2
  89                     ) →
  90                     (∀L,a,I,V1,V2,T1,T2,d,e. L ⊢ V1 ▶* [d, e] V2 →
  91                      L.ⓑ{I}V2 ⊢ T1 ▶* [d + 1, e] T2 → R d e L V1 V2 →
  92                      R (d+1) e (L.ⓑ{I}V2) T1 T2 → R d e L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  93                     ) →
  94                     (∀L,I,V1,V2,T1,T2,d,e. L ⊢ V1 ▶* [d, e] V2 →
  95                      L ⊢ T1 ▶* [d, e] T2 → R d e L V1 V2 →
  96                      R d e L T1 T2 → R d e L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  97                     ) →
  98                     ∀d,e,L,T1,T2. L ⊢ T1 ▶* [d, e] T2 → R d e L T1 T2.
  99 #R #H1 #H2 #H3 #H4 #d #e #L #T1 #T2 #H elim (tpss_tpssa … H) -L -T1 -T2 -d -e
 100 // /3 width=1 by tpssa_tpss/ /3 width=7 by tpssa_tpss/
 101 qed-.