matita/matita/contribs/lambdadelta/basic_2A/computation/cprs_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/reduction/cpr_lift.ma".
  16 include "basic_2A/computation/cprs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma cprs_delta: ∀G,L,K,V,V2,i.
  23                   ⬇[i] L ≡ K.ⓓV → ⦃G, K⦄ ⊢ V ➡* V2 →
  24                   ∀W2. ⬆[0, i + 1] V2 ≡ W2 → ⦃G, L⦄ ⊢ #i ➡* W2.
  25 #G #L #K #V #V2 #i #HLK #H elim H -V2 [ /3 width=6 by cpr_cprs, cpr_delta/ ]
  26 #V1 #V2 #_ #HV12 #IHV1 #W2 #HVW2
  27 lapply (drop_fwd_drop2 … HLK) -HLK #HLK
  28 elim (lift_total V1 0 (i+1)) /4 width=12 by cpr_lift, cprs_strap1/
  29 qed.
  30
  31 (* Advanced inversion lemmas ************************************************)
  32
  33 (* Basic_1: was: pr3_gen_lref *)
  34 lemma cprs_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡* T2 →
  35                       T2 = #i ∨
  36                       ∃∃K,V1,T1. ⬇[i] L ≡ K.ⓓV1 & ⦃G, K⦄ ⊢ V1 ➡* T1 &
  37                                  ⬆[0, i + 1] T1 ≡ T2.
  38 #G #L #T2 #i #H @(cprs_ind … H) -T2 /2 width=1 by or_introl/
  39 #T #T2 #_ #HT2 *
  40 [ #H destruct
  41   elim (cpr_inv_lref1 … HT2) -HT2 /2 width=1 by or_introl/
  42   * /4 width=6 by cpr_cprs, ex3_3_intro, or_intror/
  43 | * #K #V1 #T1 #HLK #HVT1 #HT1
  44   lapply (drop_fwd_drop2 … HLK) #H0LK
  45   elim (cpr_inv_lift1 … HT2 … H0LK … HT1) -H0LK -T
  46   /4 width=6 by cprs_strap1, ex3_3_intro, or_intror/
  47 ]
  48 qed-.
  49
  50 (* Relocation properties ****************************************************)
  51
  52 (* Basic_1: was: pr3_lift *)
  53 lemma cprs_lift: ∀G. d_liftable (cprs G).
  54 /3 width=10 by d_liftable_LTC, cpr_lift/ qed.
  55
  56 (* Basic_1: was: pr3_gen_lift *)
  57 lemma cprs_inv_lift1: ∀G. d_deliftable_sn (cprs G).
  58 /3 width=6 by d_deliftable_sn_LTC, cpr_inv_lift1/
  59 qed-.