matita/matita/contribs/lambdadelta/basic_2A/computation/cprs_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/reduction/cpr_lift.ma".
  16 include "basic_2A/computation/cprs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 (* Note: apparently this was missing in basic_1 *)
  23 lemma cprs_delta: ∀G,L,K,V,V2,i.
  24                   ⬇[i] L ≡ K.ⓓV → ⦃G, K⦄ ⊢ V ➡* V2 →
  25                   ∀W2. ⬆[0, i + 1] V2 ≡ W2 → ⦃G, L⦄ ⊢ #i ➡* W2.
  26 #G #L #K #V #V2 #i #HLK #H elim H -V2 [ /3 width=6 by cpr_cprs, cpr_delta/ ]
  27 #V1 #V2 #_ #HV12 #IHV1 #W2 #HVW2
  28 lapply (drop_fwd_drop2 … HLK) -HLK #HLK
  29 elim (lift_total V1 0 (i+1)) /4 width=12 by cpr_lift, cprs_strap1/
  30 qed.
  31
  32 (* Advanced inversion lemmas ************************************************)
  33
  34 (* Basic_1: was: pr3_gen_lref *)
  35 lemma cprs_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡* T2 →
  36                       T2 = #i ∨
  37                       ∃∃K,V1,T1. ⬇[i] L ≡ K.ⓓV1 & ⦃G, K⦄ ⊢ V1 ➡* T1 &
  38                                  ⬆[0, i + 1] T1 ≡ T2.
  39 #G #L #T2 #i #H @(cprs_ind … H) -T2 /2 width=1 by or_introl/
  40 #T #T2 #_ #HT2 *
  41 [ #H destruct
  42   elim (cpr_inv_lref1 … HT2) -HT2 /2 width=1 by or_introl/
  43   * /4 width=6 by cpr_cprs, ex3_3_intro, or_intror/
  44 | * #K #V1 #T1 #HLK #HVT1 #HT1
  45   lapply (drop_fwd_drop2 … HLK) #H0LK
  46   elim (cpr_inv_lift1 … HT2 … H0LK … HT1) -H0LK -T
  47   /4 width=6 by cprs_strap1, ex3_3_intro, or_intror/
  48 ]
  49 qed-.
  50
  51 (* Relocation properties ****************************************************)
  52
  53 (* Basic_1: was: pr3_lift *)
  54 lemma cprs_lift: ∀G. d_liftable (cprs G).
  55 /3 width=10 by d_liftable_LTC, cpr_lift/ qed.
  56
  57 (* Basic_1: was: pr3_gen_lift *)
  58 lemma cprs_inv_lift1: ∀G. d_deliftable_sn (cprs G).
  59 /3 width=6 by d_deliftable_sn_LTC, cpr_inv_lift1/
  60 qed-.