matita/matita/contribs/lambdadelta/basic_2A/computation/cpxs_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/reduction/lpx_drop.ma".
  16 include "basic_2A/computation/cpxs_lift.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED PARALLEL COMPUTATION ON TERMS *****************)
  19
  20 (* Main properties **********************************************************)
  21
  22 theorem cpxs_trans: ∀h,g,G,L. Transitive … (cpxs h g G L).
  23 normalize /2 width=3 by trans_TC/ qed-.
  24
  25 theorem cpxs_bind: ∀h,g,a,I,G,L,V1,V2,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡*[h, g] T2 →
  26                    ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  27                    ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  28 #h #g #a #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cpxs_ind … H) -V2
  29 /3 width=5 by cpxs_trans, cpxs_bind_dx/
  30 qed.
  31
  32 theorem cpxs_flat: ∀h,g,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  33                    ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  34                    ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  35 #h #g #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cpxs_ind … H) -V2
  36 /3 width=5 by cpxs_trans, cpxs_flat_dx/
  37 qed.
  38
  39 theorem cpxs_beta_rc: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
  40                       ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  41                       ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
  42 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HT12 #H @(cpxs_ind … H) -W2
  43 /4 width=5 by cpxs_trans, cpxs_beta_dx, cpxs_bind_dx, cpx_pair_sn/
  44 qed.
  45
  46 theorem cpxs_beta: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
  47                    ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 → ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  48                    ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
  49 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HT12 #HW12 #H @(cpxs_ind … H) -V2
  50 /4 width=5 by cpxs_trans, cpxs_beta_rc, cpxs_bind_dx, cpx_flat/
  51 qed.
  52
  53 theorem cpxs_theta_rc: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
  54                        ⦃G, L⦄ ⊢ V1 ➡[h, g] V → ⬆[0, 1] V ≡ V2 →
  55                        ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  56                        ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
  57 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HT12 #H @(cpxs_ind … H) -W2
  58 /3 width=5 by cpxs_trans, cpxs_theta_dx, cpxs_bind_dx/
  59 qed.
  60
  61 theorem cpxs_theta: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
  62                     ⬆[0, 1] V ≡ V2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  63                     ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ V1 ➡*[h, g] V →
  64                     ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
  65 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV2 #HW12 #HT12 #H @(TC_ind_dx … V1 H) -V1
  66 /3 width=5 by cpxs_trans, cpxs_theta_rc, cpxs_flat_dx/
  67 qed.
  68
  69 (* Advanced inversion lemmas ************************************************)
  70
  71 lemma cpxs_inv_appl1: ∀h,g,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓐV1.T1 ➡*[h, g] U2 →
  72                       ∨∨ ∃∃V2,T2.       ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 &
  73                                         U2 = ⓐV2. T2
  74                        | ∃∃a,W,T.       ⦃G, L⦄ ⊢ T1 ➡*[h, g] ⓛ{a}W.T & ⦃G, L⦄ ⊢ ⓓ{a}ⓝW.V1.T ➡*[h, g] U2
  75                        | ∃∃a,V0,V2,V,T. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V0 & ⬆[0,1] V0 ≡ V2 &
  76                                         ⦃G, L⦄ ⊢ T1 ➡*[h, g] ⓓ{a}V.T & ⦃G, L⦄ ⊢ ⓓ{a}V.ⓐV2.T ➡*[h, g] U2.
  77 #h #g #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 [ /3 width=5 by or3_intro0, ex3_2_intro/ ]
  78 #U #U2 #_ #HU2 * *
  79 [ #V0 #T0 #HV10 #HT10 #H destruct
  80   elim (cpx_inv_appl1 … HU2) -HU2 *
  81   [ #V2 #T2 #HV02 #HT02 #H destruct /4 width=5 by cpxs_strap1, or3_intro0, ex3_2_intro/
  82   | #a #V2 #W #W2 #T #T2 #HV02 #HW2 #HT2 #H1 #H2 destruct
  83     lapply (cpxs_strap1 … HV10 … HV02) -V0 #HV12
  84     lapply (lsubr_cpx_trans … HT2 (L.ⓓⓝW.V1) ?) -HT2
  85     /5 width=5 by cpxs_bind, cpxs_flat_dx, cpx_cpxs, lsubr_beta, ex2_3_intro, or3_intro1/
  86   | #a #V #V2 #W0 #W2 #T #T2 #HV0 #HV2 #HW02 #HT2 #H1 #H2 destruct
  87     /5 width=10 by cpxs_flat_sn, cpxs_bind_dx, cpxs_strap1, ex4_5_intro, or3_intro2/
  88   ]
  89 | /4 width=9 by cpxs_strap1, or3_intro1, ex2_3_intro/
  90 | /4 width=11 by cpxs_strap1, or3_intro2, ex4_5_intro/
  91 ]
  92 qed-.
  93
  94 (* Properties on sn extended parallel reduction for local environments ******)
  95
  96 lemma lpx_cpx_trans: ∀h,g,G. s_r_transitive … (cpx h g G) (λ_.lpx h g G).
  97 #h #g #G #L2 #T1 #T2 #HT12 elim HT12 -G -L2 -T1 -T2
  98 [ /2 width=3 by/
  99 | /3 width=2 by cpx_cpxs, cpx_st/
 100 | #I #G #L2 #K2 #V0 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV02 #L1 #HL12
 101   elim (lpx_drop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
 102   elim (lpx_inv_pair2 … H) -H #K1 #V1 #HK12 #HV10 #H destruct
 103   /4 width=7 by cpxs_delta, cpxs_strap2/
 104 |4,9: /4 width=1 by cpxs_beta, cpxs_bind, lpx_pair/
 105 |5,7,8: /3 width=1 by cpxs_flat, cpxs_ct, cpxs_eps/
 106 | /4 width=3 by cpxs_zeta, lpx_pair/
 107 | /4 width=3 by cpxs_theta, cpxs_strap1, lpx_pair/
 108 ]
 109 qed-.
 110
 111 lemma cpx_bind2: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
 112                  ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡[h, g] T2 →
 113                  ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
 114 /4 width=5 by lpx_cpx_trans, cpxs_bind_dx, lpx_pair/ qed.
 115
 116 (* Advanced properties ******************************************************)
 117
 118 lemma lpx_cpxs_trans: ∀h,g,G. s_rs_transitive … (cpx h g G) (λ_.lpx h g G).
 119 #h #g #G @s_r_trans_LTC1 /2 width=3 by lpx_cpx_trans/ (**) (* full auto fails *)
 120 qed-.
 121
 122 lemma cpxs_bind2_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
 123                      ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡*[h, g] T2 →
 124                      ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
 125 /4 width=5 by lpx_cpxs_trans, cpxs_bind_dx, lpx_pair/ qed.
 126
 127 (* Properties on supclosure *************************************************)
 128
 129 lemma fqu_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 130                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 131                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
 132 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 133 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
 134   #U2 #HVU2 @(ex3_intro … U2)
 135   [1,3: /3 width=7 by fqu_drop, cpxs_delta, drop_pair, drop_drop/
 136   | #H destruct /2 width=7 by lift_inv_lref2_be/
 137   ]
 138 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
 139   [1,3: /2 width=4 by fqu_pair_sn, cpxs_pair_sn/
 140   | #H0 destruct /2 width=1 by/
 141   ]
 142 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
 143   [1,3: /2 width=4 by fqu_bind_dx, cpxs_bind/
 144   | #H0 destruct /2 width=1 by/
 145   ]
 146 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
 147   [1,3: /2 width=4 by fqu_flat_dx, cpxs_flat/
 148   | #H0 destruct /2 width=1 by/
 149   ]
 150 | #G #L #K #T1 #U1 #m #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (m+1))
 151   #U2 #HTU2 @(ex3_intro … U2)
 152   [1,3: /2 width=10 by cpxs_lift, fqu_drop/
 153   | #H0 destruct /3 width=5 by lift_inj/
 154 ]
 155 qed-.
 156
 157 lemma fquq_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 158                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 159                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
 160 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
 161 [ #H12 elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
 162   /3 width=4 by fqu_fquq, ex3_intro/
 163 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 164 ]
 165 qed-.
 166
 167 lemma fqup_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 168                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 169                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 170 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 171 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
 172   /3 width=4 by fqu_fqup, ex3_intro/
 173 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 174   #U1 #HTU1 #H #H12 elim (fqu_cpxs_trans_neq … H1 … HTU1 H) -T1
 175   /3 width=8 by fqup_strap2, ex3_intro/
 176 ]
 177 qed-.
 178
 179 lemma fqus_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 180                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 181                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 182 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 183 [ #H12 elim (fqup_cpxs_trans_neq … H12 … HTU2 H) -T2
 184   /3 width=4 by fqup_fqus, ex3_intro/
 185 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 186 ]
 187 qed-.