matita/matita/contribs/lambdadelta/basic_2A/computation/csx_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/grammar/tsts_tsts.ma".
  16 include "basic_2A/computation/cpxs_cpxs.ma".
  17 include "basic_2A/computation/csx_alt.ma".
  18 include "basic_2A/computation/csx_lift.ma".
  19
  20 (* CONTEXT-SENSITIVE EXTENDED STRONGLY NORMALIZING TERMS ********************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma csx_lpx_conf: ∀h,g,G,L1,L2. ⦃G, L1⦄ ⊢ ➡[h, g] L2 →
  25                     ∀T. ⦃G, L1⦄ ⊢ ⬊*[h, g] T → ⦃G, L2⦄ ⊢ ⬊*[h, g] T.
  26 #h #g #G #L1 #L2 #HL12 #T #H @(csx_ind_alt … H) -T
  27 /4 width=3 by csx_intro, lpx_cpx_trans/
  28 qed-.
  29
  30 lemma csx_abst: ∀h,g,a,G,L,W. ⦃G, L⦄ ⊢ ⬊*[h, g] W →
  31                 ∀T. ⦃G, L.ⓛW⦄ ⊢ ⬊*[h, g] T → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓛ{a}W.T.
  32 #h #g #a #G #L #W #HW @(csx_ind … HW) -W #W #_ #IHW #T #HT @(csx_ind … HT) -T #T #HT #IHT
  33 @csx_intro #X #H1 #H2
  34 elim (cpx_inv_abst1 … H1) -H1
  35 #W0 #T0 #HLW0 #HLT0 #H destruct
  36 elim (eq_false_inv_tpair_sn … H2) -H2
  37 [ -IHT #H lapply (csx_cpx_trans … HLT0) // -HT
  38   #HT0 lapply (csx_lpx_conf … (L.ⓛW0) … HT0) -HT0 /3 width=1 by lpx_pair/
  39 | -IHW -HLW0 -HT * #H destruct /3 width=1 by/
  40 ]
  41 qed.
  42
  43 lemma csx_abbr: ∀h,g,a,G,L,V. ⦃G, L⦄ ⊢ ⬊*[h, g] V →
  44                 ∀T. ⦃G, L.ⓓV⦄ ⊢ ⬊*[h, g] T → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓓ{a}V. T.
  45 #h #g #a #G #L #V #HV elim HV -V #V #_ #IHV #T #HT @(csx_ind_alt … HT) -T #T #HT #IHT
  46 @csx_intro #X #H1 #H2
  47 elim (cpx_inv_abbr1 … H1) -H1 *
  48 [ #V1 #T1 #HLV1 #HLT1 #H destruct
  49   elim (eq_false_inv_tpair_sn … H2) -H2
  50   [ /4 width=5 by csx_cpx_trans, csx_lpx_conf, lpx_pair/
  51   | -IHV -HLV1 * #H destruct /3 width=1 by cpx_cpxs/
  52   ]
  53 | -IHV -IHT -H2
  54   /3 width=8 by csx_cpx_trans, csx_inv_lift, drop_drop/
  55 ]
  56 qed.
  57
  58 fact csx_appl_beta_aux: ∀h,g,a,G,L,U1. ⦃G, L⦄ ⊢ ⬊*[h, g] U1 →
  59                         ∀V,W,T1. U1 = ⓓ{a}ⓝW.V.T1 → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV.ⓛ{a}W.T1.
  60 #h #g #a #G #L #X #H @(csx_ind … H) -X
  61 #X #HT1 #IHT1 #V #W #T1 #H1 destruct
  62 @csx_intro #X #H1 #H2
  63 elim (cpx_inv_appl1 … H1) -H1 *
  64 [ -HT1 #V0 #Y #HLV0 #H #H0 destruct
  65   elim (cpx_inv_abst1 … H) -H #W0 #T0 #HLW0 #HLT0 #H destruct
  66   @IHT1 -IHT1 [4: // | skip |3: #H destruct /2 width=1 by/ ] -H2
  67   lapply (lsubr_cpx_trans … HLT0 (L.ⓓⓝW.V) ?) -HLT0 /3 width=1 by cpx_bind, cpx_flat, lsubr_beta/
  68 | -IHT1 -H2 #b #V0 #W0 #W2 #T0 #T2 #HLV0 #HLW02 #HLT02 #H1 #H3 destruct
  69   lapply (lsubr_cpx_trans … HLT02 (L.ⓓⓝW0.V) ?) -HLT02
  70   /4 width=5 by csx_cpx_trans, cpx_bind, cpx_flat, lsubr_beta/
  71 | -HT1 -IHT1 -H2 #b #V0 #V1 #W0 #W1 #T0 #T3 #_ #_ #_ #_ #H destruct
  72 ]
  73 qed-.
  74
  75 (* Basic_1: was just: sn3_beta *)
  76 lemma csx_appl_beta: ∀h,g,a,G,L,V,W,T. ⦃G, L⦄ ⊢ ⬊*[h, g] ⓓ{a}ⓝW.V.T → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV.ⓛ{a}W.T.
  77 /2 width=3 by csx_appl_beta_aux/ qed.
  78
  79 fact csx_appl_theta_aux: ∀h,g,a,G,L,U. ⦃G, L⦄ ⊢ ⬊*[h, g] U → ∀V1,V2. ⬆[0, 1] V1 ≡ V2 →
  80                          ∀V,T. U = ⓓ{a}V.ⓐV2.T → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV1.ⓓ{a}V.T.
  81 #h #g #a #G #L #X #H @(csx_ind_alt … H) -X #X #HVT #IHVT #V1 #V2 #HV12 #V #T #H destruct
  82 lapply (csx_fwd_pair_sn … HVT) #HV
  83 lapply (csx_fwd_bind_dx … HVT) -HVT #HVT
  84 @csx_intro #X #HL #H
  85 elim (cpx_inv_appl1 … HL) -HL *
  86 [ -HV #V0 #Y #HLV10 #HL #H0 destruct
  87   elim (cpx_inv_abbr1 … HL) -HL *
  88   [ #V3 #T3 #HV3 #HLT3 #H0 destruct
  89     elim (lift_total V0 0 1) #V4 #HV04
  90     elim (eq_term_dec (ⓓ{a}V.ⓐV2.T) (ⓓ{a}V3.ⓐV4.T3))
  91     [ -IHVT #H0 destruct
  92       elim (eq_false_inv_tpair_sn … H) -H
  93       [ -HLV10 -HV3 -HLT3 -HVT
  94         >(lift_inj … HV12 … HV04) -V4
  95         #H elim H //
  96       | * #_ #H elim H //
  97       ]
  98     | -H -HVT #H
  99       lapply (cpx_lift … HLV10 (L.ⓓV) (Ⓕ) … HV12 … HV04) -HLV10 -HV12 /2 width=1 by drop_drop/ #HV24
 100       @(IHVT … H … HV04) -IHVT /4 width=1 by cpx_cpxs, cpx_bind, cpx_flat/
 101     ]
 102   | -H -IHVT #T0 #HLT0 #HT0 #H0 destruct
 103     lapply (csx_cpx_trans … HVT (ⓐV2.T0) ?) /2 width=1 by cpx_flat/ -T #HVT0
 104     lapply (csx_inv_lift … L … (Ⓕ) … 1 HVT0 ? ? ?) -HVT0
 105     /3 width=5 by csx_cpx_trans, cpx_pair_sn, drop_drop, lift_flat/
 106   ]
 107 | -HV -HV12 -HVT -IHVT -H #b #V0 #W0 #W1 #T0 #T1 #_ #_ #_ #H destruct
 108 | -IHVT -H #b #V0 #V3 #W0 #W1 #T0 #T1 #HLV10 #HV03 #HLW01 #HLT01 #H1 #H2 destruct
 109   lapply (cpx_lift … HLV10 (L. ⓓW0) … HV12 … HV03) -HLV10 -HV12 -HV03 /2 width=2 by drop_drop/ #HLV23
 110   @csx_abbr /2 width=3 by csx_cpx_trans/ -HV
 111   @(csx_lpx_conf … (L.ⓓW0)) /2 width=1 by lpx_pair/ -W1
 112   /4 width=5 by csx_cpxs_trans, cpx_cpxs, cpx_flat/
 113 ]
 114 qed-.
 115
 116 lemma csx_appl_theta: ∀h,g,a,V1,V2. ⬆[0, 1] V1 ≡ V2 →
 117                       ∀G,L,V,T. ⦃G, L⦄ ⊢ ⬊*[h, g] ⓓ{a}V.ⓐV2.T → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV1.ⓓ{a}V.T.
 118 /2 width=5 by csx_appl_theta_aux/ qed.
 119
 120 (* Basic_1: was just: sn3_appl_appl *)
 121 lemma csx_appl_simple_tsts: ∀h,g,G,L,V. ⦃G, L⦄ ⊢ ⬊*[h, g] V → ∀T1. ⦃G, L⦄ ⊢ ⬊*[h, g] T1 →
 122                             (∀T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → (T1 ≂ T2 → ⊥) → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV.T2) →
 123                             𝐒⦃T1⦄ → ⦃G, L⦄ ⊢ ⬊*[h, g] ⓐV.T1.
 124 #h #g #G #L #V #H @(csx_ind … H) -V #V #_ #IHV #T1 #H @(csx_ind … H) -T1 #T1 #H1T1 #IHT1 #H2T1 #H3T1
 125 @csx_intro #X #HL #H
 126 elim (cpx_inv_appl1_simple … HL) -HL //
 127 #V0 #T0 #HLV0 #HLT10 #H0 destruct
 128 elim (eq_false_inv_tpair_sn … H) -H
 129 [ -IHT1 #HV0
 130   @(csx_cpx_trans … (ⓐV0.T1)) /2 width=1 by cpx_flat/ -HLT10
 131   @IHV -IHV /4 width=3 by csx_cpx_trans, cpx_pair_sn/
 132 | -IHV -H1T1 -HLV0 * #H #H1T10 destruct
 133   elim (tsts_dec T1 T0) #H2T10
 134   [ @IHT1 -IHT1 /4 width=3 by cpxs_strap2, cpxs_strap1, tsts_canc_sn, simple_tsts_repl_dx/
 135   | -IHT1 -H3T1 -H1T10 /3 width=1 by cpx_cpxs/
 136   ]
 137 ]
 138 qed.