matita/matita/contribs/lambdadelta/basic_2A/computation/csx_vector.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/grammar/term_vector.ma".
  16 include "basic_2A/computation/csx.ma".
  17
  18 (* CONTEXT-SENSITIVE EXTENDED STRONGLY NORMALIZING TERM VECTORS *************)
  19
  20 definition csxv: ∀h. sd h → relation3 genv lenv (list term) ≝
  21                  λh,g,G,L. all … (csx h g G L).
  22
  23 interpretation
  24    "context-sensitive strong normalization (term vector)"
  25    'SN h g G L Ts = (csxv h g G L Ts).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 lemma csxv_inv_cons: ∀h,g,G,L,T,Ts. ⦃G, L⦄ ⊢ ⬊*[h, g] T @ Ts →
  30                      ⦃G, L⦄ ⊢ ⬊*[h, g] T ∧ ⦃G, L⦄ ⊢ ⬊*[h, g] Ts.
  31 normalize // qed-.
  32
  33 (* Basic forward lemmas *****************************************************)
  34
  35 lemma csx_fwd_applv: ∀h,g,G,L,T,Vs. ⦃G, L⦄ ⊢ ⬊*[h, g] Ⓐ Vs.T →
  36                      ⦃G, L⦄ ⊢ ⬊*[h, g] Vs ∧ ⦃G, L⦄ ⊢ ⬊*[h, g] T.
  37 #h #g #G #L #T #Vs elim Vs -Vs /2 width=1 by conj/
  38 #V #Vs #IHVs #HVs
  39 lapply (csx_fwd_pair_sn … HVs) #HV
  40 lapply (csx_fwd_flat_dx … HVs) -HVs #HVs
  41 elim (IHVs HVs) -IHVs -HVs /3 width=1 by conj/
  42 qed-.