matita/matita/contribs/lambdadelta/basic_2A/computation/fpbg_fleq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/multiple/fleq_fleq.ma".
  16 include "basic_2A/reduction/fpbq_alt.ma".
  17 include "basic_2A/computation/fpbg.ma".
  18
  19 (* "QRST" PROPER PARALLEL COMPUTATION FOR CLOSURES **************************)
  20
  21 (* Properties on lazy equivalence for closures ******************************)
  22
  23 lemma fpbg_fleq_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G, L, T⦄ →
  24                        ∀G2,L2,T2. ⦃G, L, T⦄ ≡[0] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  25 /3 width=5 by fpbg_fpbq_trans, fleq_fpbq/ qed-.
  26
  27 lemma fleq_fpbg_trans: ∀h,g,G,G2,L,L2,T,T2. ⦃G, L, T⦄ >≡[h, g] ⦃G2, L2, T2⦄ →
  28                        ∀G1,L1,T1. ⦃G1, L1, T1⦄ ≡[0] ⦃G, L, T⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  29 #h #g #G #G2 #L #L2 #T #T2 * #G0 #L0 #T0 #H0 #H02 #G1 #L1 #T1 #H1
  30 elim (fleq_fpb_trans …  H1 … H0) -G -L -T
  31 /4 width=9 by fpbs_strap2, fleq_fpbq, ex2_3_intro/
  32 qed-.
  33
  34 (* alternative definition of fpbs *******************************************)
  35
  36 lemma fleq_fpbs: ∀h,g,G1,G2,L1,L2,T1,T2.
  37                  ⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  38 #h #g #G1 #G2 #L1 #L2 #T1 #T2 * /2 width=1 by lleq_fpbs/
  39 qed.
  40
  41 lemma fpbg_fwd_fpbs: ∀h,g,G1,G2,L1,L2,T1,T2.
  42                      ⦃G1, L1, T1⦄ >≡[h,g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄.
  43 #h #g #G1 #G2 #L1 #L2 #T1 #T2 *
  44 /3 width=5 by fpbs_strap2, fpb_fpbq/
  45 qed-.
  46
  47 lemma fpbs_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ →
  48                  ⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ ∨
  49                  ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  50 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind … H) -G2 -L2 -T2
  51 [ /2 width=1 by or_introl/
  52 | #G #G2 #L #L2 #T #T2 #_ #H2 * #H1 @(fpbq_ind_alt … H2) -H2 #H2
  53   [ /3 width=5 by fleq_trans, or_introl/
  54   | elim (fleq_fpb_trans … H1 … H2) -G -L -T
  55     /4 width=5 by ex2_3_intro, or_intror, fleq_fpbs/
  56   | /3 width=5 by fpbg_fleq_trans, or_intror/
  57   | /4 width=5 by fpbg_fpbq_trans, fpb_fpbq, or_intror/
  58   ]
  59 ]
  60 qed-.
  61
  62 (* Advanced properties of "qrst" parallel computation on closures ***********)
  63
  64 lemma fpbs_fpb_trans: ∀h,g,F1,F2,K1,K2,T1,T2. ⦃F1, K1, T1⦄ ≥[h, g] ⦃F2, K2, T2⦄ →
  65                       ∀G2,L2,U2. ⦃F2, K2, T2⦄ ≻[h, g] ⦃G2, L2, U2⦄ →
  66                       ∃∃G1,L1,U1. ⦃F1, K1, T1⦄ ≻[h, g] ⦃G1, L1, U1⦄ & ⦃G1, L1, U1⦄ ≥[h, g] ⦃G2, L2, U2⦄.
  67 #h #g #F1 #F2 #K1 #K2 #T1 #T2 #H elim (fpbs_fpbg … H) -H
  68 [ #H12 #G2 #L2 #U2 #H2 elim (fleq_fpb_trans … H12 … H2) -F2 -K2 -T2
  69   /3 width=5 by fleq_fpbs, ex2_3_intro/
  70 | * #H1 #H2 #H3 #H4 #H5 #H6 #H7 #H8 #H9
  71   @(ex2_3_intro … H4) -H4 /3 width=5 by fpbs_strap1, fpb_fpbq/
  72 ]
  73 qed-.