matita/matita/contribs/lambdadelta/basic_2A/computation/fsb_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/btsnalt_5.ma".
  16 include "basic_2A/computation/fpbg_fpbs.ma".
  17 include "basic_2A/computation/fsb.ma".
  18
  19 (* "QRST" STRONGLY NORMALIZING CLOSURES *************************************)
  20
  21 (* Note: alternative definition of fsb *)
  22 inductive fsba (h) (g): relation3 genv lenv term ≝
  23 | fsba_intro: ∀G1,L1,T1. (
  24                  ∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → fsba h g G2 L2 T2
  25               ) → fsba h g G1 L1 T1.
  26
  27 interpretation
  28    "'big tree' strong normalization (closure) alternative"
  29    'BTSNAlt h g G L T = (fsba h g G L T).
  30
  31 (* Basic eliminators ********************************************************)
  32
  33 lemma fsba_ind_alt: ∀h,g. ∀R: relation3 …. (
  34                        ∀G1,L1,T1. ⦥⦥[h,g] ⦃G1, L1, T1⦄ → (
  35                           ∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2
  36                        ) → R G1 L1 T1
  37                     ) →
  38                     ∀G,L,T. ⦥⦥[h, g] ⦃G, L, T⦄ → R G L T.
  39 #h #g #R #IH #G #L #T #H elim H -G -L -T
  40 /4 width=1 by fsba_intro/
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma fsba_fpbs_trans: ∀h,g,G1,L1,T1. ⦥⦥[h, g] ⦃G1, L1, T1⦄ →
  46                        ∀G2,L2,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦥⦥[h, g] ⦃G2, L2, T2⦄.
  47 #h #g #G1 #L1 #T1 #H @(fsba_ind_alt … H) -G1 -L1 -T1
  48 /4 width=5 by fsba_intro, fpbs_fpbg_trans/
  49 qed-.
  50
  51 (* Main properties **********************************************************)
  52
  53 theorem fsb_fsba: ∀h,g,G,L,T. ⦥[h, g] ⦃G, L, T⦄  → ⦥⦥[h, g] ⦃G, L, T⦄.
  54 #h #g #G #L #T #H @(fsb_ind_alt … H) -G -L -T
  55 #G1 #L1 #T1 #_ #IH @fsba_intro
  56 #G2 #L2 #T2 * /3 width=5 by fsba_fpbs_trans/
  57 qed.
  58
  59 (* Main inversion lemmas ****************************************************)
  60
  61 theorem fsba_inv_fsb: ∀h,g,G,L,T. ⦥⦥[h, g] ⦃G, L, T⦄ → ⦥[h, g] ⦃G, L, T⦄.
  62 #h #g #G #L #T #H @(fsba_ind_alt … H) -G -L -T
  63 /4 width=1 by fsb_intro, fpb_fpbg/
  64 qed-.
  65
  66 (* Advanced properties ******************************************************)
  67
  68 lemma fsb_fpbs_trans: ∀h,g,G1,L1,T1. ⦥[h, g] ⦃G1, L1, T1⦄ →
  69                       ∀G2,L2,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦥[h, g] ⦃G2, L2, T2⦄.
  70 /4 width=5 by fsba_inv_fsb, fsb_fsba, fsba_fpbs_trans/ qed-.
  71
  72 (* Advanced eliminators *****************************************************)
  73
  74 lemma fsb_ind_fpbg: ∀h,g. ∀R:relation3 genv lenv term.
  75                     (∀G1,L1,T1. ⦥[h, g] ⦃G1, L1, T1⦄ →
  76                                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  77                                 R G1 L1 T1
  78                     ) →
  79                     ∀G1,L1,T1. ⦥[h, g] ⦃G1, L1, T1⦄ → R G1 L1 T1.
  80 #h #g #R #IH #G1 #L1 #T1 #H @(fsba_ind_alt h g … G1 L1 T1)
  81 /3 width=1 by fsba_inv_fsb, fsb_fsba/
  82 qed-.