matita/matita/contribs/lambdadelta/basic_2A/computation/gcp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/grammar/genv.ma".
  16 include "basic_2A/multiple/drops.ma".
  17
  18 (* GENERIC COMPUTATION PROPERTIES *******************************************)
  19
  20 definition nf ≝ λRR:relation4 genv lenv term term. λRS:relation term.
  21                 λG,L,T. NF … (RR G L) RS T.
  22
  23 definition candidate: Type[0] ≝ relation3 genv lenv term.
  24
  25 definition CP0 ≝ λRR:relation4 genv lenv term term. λRS:relation term.
  26                  ∀G. d_liftable1 (nf RR RS G) (Ⓕ).
  27
  28 definition CP1 ≝ λRR:relation4 genv lenv term term. λRS:relation term.
  29                  ∀G,L. ∃k. NF … (RR G L) RS (⋆k).
  30
  31 definition CP2 ≝ λRP:candidate. ∀G. d_liftable1 (RP G) (Ⓕ).
  32
  33 definition CP3 ≝ λRP:candidate.
  34                  ∀G,L,T,k. RP G L (ⓐ⋆k.T) → RP G L T.
  35
  36 (* requirements for generic computation properties *)
  37 record gcp (RR:relation4 genv lenv term term) (RS:relation term) (RP:candidate) : Prop ≝
  38 { cp0: CP0 RR RS;
  39   cp1: CP1 RR RS;
  40   cp2: CP2 RP;
  41   cp3: CP3 RP
  42 }.
  43
  44 (* Basic properties *********************************************************)
  45
  46 (* Basic_1: was: nf2_lift1 *)
  47 lemma gcp0_lifts: ∀RR,RS,RP. gcp RR RS RP → ∀G. d_liftables1 (nf RR RS G) (Ⓕ).
  48 #RR #RS #RP #H #G @d1_liftable_liftables @(cp0 … H)
  49 qed.
  50
  51 lemma gcp2_lifts: ∀RR,RS,RP. gcp RR RS RP → ∀G. d_liftables1 (RP G) (Ⓕ).
  52 #RR #RS #RP #H #G @d1_liftable_liftables @(cp2 … H)
  53 qed.
  54
  55 (* Basic_1: was only: sns3_lifts1 *)
  56 lemma gcp2_lifts_all: ∀RR,RS,RP. gcp RR RS RP → ∀G. d_liftables1_all (RP G) (Ⓕ).
  57 #RR #RS #RP #H #G @d1_liftables_liftables_all /2 width=7 by gcp2_lifts/
  58 qed.