matita/matita/contribs/lambdadelta/basic_2A/computation/gcp_cr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/ineint_5.ma".
  16 include "basic_2A/grammar/aarity.ma".
  17 include "basic_2A/multiple/mr2_mr2.ma".
  18 include "basic_2A/multiple/lifts_lift_vector.ma".
  19 include "basic_2A/multiple/drops_drop.ma".
  20 include "basic_2A/computation/gcp.ma".
  21
  22 (* GENERIC COMPUTATION PROPERTIES *******************************************)
  23
  24 (* Note: this is Girard's CR1 *)
  25 definition S1 ≝ λRP,C:candidate.
  26                 ∀G,L,T. C G L T → RP G L T.
  27
  28 (* Note: this is Tait's iii, or Girard's CR4 *)
  29 definition S2 ≝ λRR:relation4 genv lenv term term. λRS:relation term. λRP,C:candidate.
  30                 ∀G,L,Vs. all … (RP G L) Vs →
  31                 ∀T. 𝐒⦃T⦄ → NF … (RR G L) RS T → C G L (ⒶVs.T).
  32
  33 (* Note: this generalizes Tait's ii *)
  34 definition S3 ≝ λC:candidate.
  35                 ∀a,G,L,Vs,V,T,W.
  36                 C G L (ⒶVs.ⓓ{a}ⓝW.V.T) → C G L (ⒶVs.ⓐV.ⓛ{a}W.T).
  37
  38 definition S4 ≝ λRP,C:candidate.
  39                 ∀G,L,Vs. all … (RP G L) Vs → ∀k. C G L (ⒶVs.⋆k).
  40
  41 definition S5 ≝ λC:candidate. ∀I,G,L,K,Vs,V1,V2,i.
  42                 C G L (ⒶVs.V2) → ⬆[0, i+1] V1 ≡ V2 →
  43                 ⬇[i] L ≡ K.ⓑ{I}V1 → C G L (ⒶVs.#i).
  44
  45 definition S6 ≝ λRP,C:candidate.
  46                 ∀G,L,V1s,V2s. ⬆[0, 1] V1s ≡ V2s →
  47                 ∀a,V,T. C G (L.ⓓV) (ⒶV2s.T) → RP G L V → C G L (ⒶV1s.ⓓ{a}V.T).
  48
  49 definition S7 ≝ λC:candidate.
  50                 ∀G,L,Vs,T,W. C G L (ⒶVs.T) → C G L (ⒶVs.W) → C G L (ⒶVs.ⓝW.T).
  51
  52 (* requirements for the generic reducibility candidate *)
  53 record gcr (RR:relation4 genv lenv term term) (RS:relation term) (RP,C:candidate) : Prop ≝
  54 { s1: S1 RP C;
  55   s2: S2 RR RS RP C;
  56   s3: S3 C;
  57   s4: S4 RP C;
  58   s5: S5 C;
  59   s6: S6 RP C;
  60   s7: S7 C
  61 }.
  62
  63 (* the functional construction for candidates *)
  64 definition cfun: candidate → candidate → candidate ≝
  65                  λC1,C2,G,K,T. ∀L,W,U,cs.
  66                  ⬇*[Ⓕ, cs] L ≡ K → ⬆*[cs] T ≡ U → C1 G L W → C2 G L (ⓐW.U).
  67
  68 (* the reducibility candidate associated to an atomic arity *)
  69 let rec acr (RP:candidate) (A:aarity) on A: candidate ≝
  70 match A with
  71 [ AAtom     ⇒ RP
  72 | APair B A ⇒ cfun (acr RP B) (acr RP A)
  73 ].
  74
  75 interpretation
  76    "candidate of reducibility of an atomic arity (abstract)"
  77    'InEInt RP G L T A = (acr RP A G L T).
  78
  79 (* Basic properties *********************************************************)
  80
  81 (* Basic 1: was: sc3_lift *)
  82 lemma gcr_lift: ∀RR,RS,RP. gcp RR RS RP → ∀A,G. d_liftable1 (acr RP A G) (Ⓕ).
  83 #RR #RS #RP #H #A elim A -A
  84 /3 width=8 by cp2, drops_cons, lifts_cons/
  85 qed.
  86
  87 (* Basic_1: was: sc3_lift1 *)
  88 lemma gcr_lifts: ∀RR,RS,RP. gcp RR RS RP → ∀A,G. d_liftables1 (acr RP A G) (Ⓕ).
  89 #RR #RS #RP #H #A #G @d1_liftable_liftables /2 width=7 by gcr_lift/
  90 qed.
  91
  92 (* Basic_1: was:
  93    sc3_sn3 sc3_abst sc3_appl sc3_abbr sc3_bind sc3_cast
  94 *)
  95 lemma acr_gcr: ∀RR,RS,RP. gcp RR RS RP → gcr RR RS RP RP →
  96                ∀A. gcr RR RS RP (acr RP A).
  97 #RR #RS #RP #H1RP #H2RP #A elim A -A //
  98 #B #A #IHB #IHA @mk_gcr
  99 [ #G #L #T #H
 100   elim (cp1 … H1RP G L) #k #HK
 101   lapply (H L (⋆k) T (◊) ? ? ?) -H //
 102   [ lapply (s2 … IHB G L (◊) … HK) //
 103   | /3 width=6 by s1, cp3/
 104   ]
 105 | #G #L #Vs #HVs #T #H1T #H2T #L0 #V0 #X #cs #HL0 #H #HB
 106   elim (lifts_inv_applv1 … H) -H #V0s #T0 #HV0s #HT0 #H destruct
 107   lapply (s1 … IHB … HB) #HV0
 108   @(s2 … IHA … (V0 @ V0s))
 109   /3 width=14 by gcp2_lifts_all, gcp2_lifts, gcp0_lifts, lifts_simple_dx, conj/
 110 | #a #G #L #Vs #U #T #W #HA #L0 #V0 #X #cs #HL0 #H #HB
 111   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 112   elim (lifts_inv_flat1 … HY) -HY #U0 #X #HU0 #HX #H destruct
 113   elim (lifts_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT0 #H destruct
 114   @(s3 … IHA … (V0 @ V0s)) /5 width=6 by lifts_applv, lifts_flat, lifts_bind/
 115 | #G #L #Vs #HVs #k #L0 #V0 #X #cs #HL0 #H #HB
 116   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 117   >(lifts_inv_sort1 … HY) -Y
 118   lapply (s1 … IHB … HB) #HV0
 119   @(s4 … IHA … (V0 @ V0s)) /3 width=7 by gcp2_lifts_all, conj/
 120 | #I #G #L #K #Vs #V1 #V2 #i #HA #HV12 #HLK #L0 #V0 #X #cs #HL0 #H #HB
 121   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 122   elim (lifts_inv_lref1 … HY) -HY #i0 #Hi0 #H destruct
 123   elim (drops_drop_trans … HL0 … HLK) #X #cs0 #i1 #HL02 #H #Hi1 #Hcs0
 124   >(at_mono … Hi1 … Hi0) in HL02; -i1 #HL02
 125   elim (drops_inv_skip2 … Hcs0 … H) -H -cs0 #L2 #W1 #cs0 #Hcs0 #HLK #HVW1 #H destruct
 126   elim (lift_total W1 0 (i0 + 1)) #W2 #HW12
 127   elim (lifts_lift_trans  … Hcs0 … HVW1 … HW12) // -Hcs0 -Hi0 #V3 #HV13 #HVW2
 128   >(lift_mono … HV13 … HV12) in HVW2; -V3 #HVW2
 129   @(s5 … IHA … (V0 @ V0s) … HW12 HL02) /3 width=5 by lifts_applv/
 130 | #G #L #V1s #V2s #HV12s #a #V #T #HA #HV #L0 #V10 #X #cs #HL0 #H #HB
 131   elim (lifts_inv_applv1 … H) -H #V10s #Y #HV10s #HY #H destruct
 132   elim (lifts_inv_bind1 … HY) -HY #V0 #T0 #HV0 #HT0 #H destruct
 133   elim (lift_total V10 0 1) #V20 #HV120
 134   elim (liftv_total 0 1 V10s) #V20s #HV120s
 135   @(s6 … IHA … (V10 @ V10s) (V20 @ V20s)) /3 width=7 by gcp2_lifts, liftv_cons/
 136   @(HA … (cs + 1)) /2 width=2 by drops_skip/
 137   [ @lifts_applv //
 138     elim (liftsv_liftv_trans_le … HV10s … HV120s) -V10s #V10s #HV10s #HV120s
 139     >(liftv_mono … HV12s … HV10s) -V1s //
 140   | @(gcr_lift … H1RP … HB … HV120) /2 width=2 by drop_drop/
 141   ]
 142 | #G #L #Vs #T #W #HA #HW #L0 #V0 #X #cs #HL0 #H #HB
 143   elim (lifts_inv_applv1 … H) -H #V0s #Y #HV0s #HY #H destruct
 144   elim (lifts_inv_flat1 … HY) -HY #W0 #T0 #HW0 #HT0 #H destruct
 145   @(s7 … IHA … (V0 @ V0s)) /3 width=5 by lifts_applv/
 146 ]
 147 qed.
 148
 149 lemma acr_abst: ∀RR,RS,RP. gcp RR RS RP → gcr RR RS RP RP →
 150                 ∀a,G,L,W,T,A,B. ⦃G, L, W⦄ ϵ[RP] 〚B〛 → (
 151                    ∀L0,V0,W0,T0,cs. ⬇*[Ⓕ, cs] L0 ≡ L → ⬆*[cs] W ≡ W0 → ⬆*[cs + 1] T ≡ T0 →
 152                                    ⦃G, L0, V0⦄ ϵ[RP] 〚B〛 → ⦃G, L0, W0⦄ ϵ[RP] 〚B〛 → ⦃G, L0.ⓓⓝW0.V0, T0⦄ ϵ[RP] 〚A〛
 153                 ) →
 154                 ⦃G, L, ⓛ{a}W.T⦄ ϵ[RP] 〚②B.A〛.
 155 #RR #RS #RP #H1RP #H2RP #a #G #L #W #T #A #B #HW #HA #L0 #V0 #X #cs #HL0 #H #HB
 156 lapply (acr_gcr … H1RP H2RP A) #HCA
 157 lapply (acr_gcr … H1RP H2RP B) #HCB
 158 elim (lifts_inv_bind1 … H) -H #W0 #T0 #HW0 #HT0 #H destruct
 159 lapply (gcr_lifts … H1RP … HL0 … HW0 HW) -HW #HW0
 160 lapply (s3 … HCA … a G L0 (◊)) #H @H -H
 161 lapply (s6 … HCA G L0 (◊) (◊) ?) // #H @H -H
 162 [ @(HA … HL0) //
 163 | lapply (s1 … HCB) -HCB #HCB
 164   lapply (s7 … H2RP G L0 (◊)) /3 width=1 by/
 165 ]
 166 qed.
 167
 168 (* Basic_1: removed theorems 2: sc3_arity_gen sc3_repl *)
 169 (* Basic_1: removed local theorems 1: sc3_sn3_abst *)