matita/matita/contribs/lambdadelta/basic_2A/computation/lsubc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_6_3.ma".
  16 include "ground_2/xoa/ex_7_4.ma".
  17 include "basic_2A/notation/relations/lrsubeqc_4.ma".
  18 include "basic_2A/static/lsubr.ma".
  19 include "basic_2A/static/aaa.ma".
  20 include "basic_2A/computation/gcp_cr.ma".
  21
  22 (* LOCAL ENVIRONMENT REFINEMENT FOR GENERIC REDUCIBILITY ********************)
  23
  24 inductive lsubc (RP) (G): relation lenv ≝
  25 | lsubc_atom: lsubc RP G (⋆) (⋆)
  26 | lsubc_pair: ∀I,L1,L2,V. lsubc RP G L1 L2 → lsubc RP G (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  27 | lsubc_beta: ∀L1,L2,V,W,A. ⦃G, L1, V⦄ ϵ[RP] 〚A〛 → ⦃G, L1, W⦄ ϵ[RP] 〚A〛 → ⦃G, L2⦄ ⊢ W ⁝ A →
  28               lsubc RP G L1 L2 → lsubc RP G (L1. ⓓⓝW.V) (L2.ⓛW)
  29 .
  30
  31 interpretation
  32   "local environment refinement (generic reducibility)"
  33   'LRSubEqC RP G L1 L2 = (lsubc RP G L1 L2).
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 fact lsubc_inv_atom1_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → L1 = ⋆ → L2 = ⋆.
  38 #RP #G #L1 #L2 * -L1 -L2
  39 [ //
  40 | #I #L1 #L2 #V #_ #H destruct
  41 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  42 ]
  43 qed-.
  44
  45 (* Basic_1: was just: csubc_gen_sort_r *)
  46 lemma lsubc_inv_atom1: ∀RP,G,L2. G ⊢ ⋆ ⫃[RP] L2 → L2 = ⋆.
  47 /2 width=5 by lsubc_inv_atom1_aux/ qed-.
  48
  49 fact lsubc_inv_pair1_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → ∀I,K1,X. L1 = K1.ⓑ{I}X →
  50                           (∃∃K2. G ⊢ K1 ⫃[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  51                           ∃∃K2,V,W,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  52                                       G ⊢ K1 ⫃[RP] K2 &
  53                                       L2 = K2. ⓛW & X = ⓝW.V & I = Abbr.
  54 #RP #G #L1 #L2 * -L1 -L2
  55 [ #I #K1 #V #H destruct
  56 | #J #L1 #L2 #V #HL12 #I #K1 #W #H destruct /3 width=3 by ex2_intro, or_introl/
  57 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K1 #V #H destruct /3 width=10 by ex7_4_intro, or_intror/
  58 ]
  59 qed-.
  60
  61 (* Basic_1: was: csubc_gen_head_r *)
  62 lemma lsubc_inv_pair1: ∀RP,I,G,K1,L2,X. G ⊢ K1.ⓑ{I}X ⫃[RP] L2 →
  63                        (∃∃K2. G ⊢ K1 ⫃[RP] K2 & L2 = K2.ⓑ{I}X) ∨
  64                        ∃∃K2,V,W,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  65                                    G ⊢ K1 ⫃[RP] K2 &
  66                                    L2 = K2.ⓛW & X = ⓝW.V & I = Abbr.
  67 /2 width=3 by lsubc_inv_pair1_aux/ qed-.
  68
  69 fact lsubc_inv_atom2_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → L2 = ⋆ → L1 = ⋆.
  70 #RP #G #L1 #L2 * -L1 -L2
  71 [ //
  72 | #I #L1 #L2 #V #_ #H destruct
  73 | #L1 #L2 #V #W #A #_ #_ #_ #_ #H destruct
  74 ]
  75 qed-.
  76
  77 (* Basic_1: was just: csubc_gen_sort_l *)
  78 lemma lsubc_inv_atom2: ∀RP,G,L1. G ⊢ L1 ⫃[RP] ⋆ → L1 = ⋆.
  79 /2 width=5 by lsubc_inv_atom2_aux/ qed-.
  80
  81 fact lsubc_inv_pair2_aux: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → ∀I,K2,W. L2 = K2.ⓑ{I} W →
  82                           (∃∃K1. G ⊢ K1 ⫃[RP] K2 & L1 = K1. ⓑ{I} W) ∨
  83                           ∃∃K1,V,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  84                                     G ⊢ K1 ⫃[RP] K2 &
  85                                     L1 = K1.ⓓⓝW.V & I = Abst.
  86 #RP #G #L1 #L2 * -L1 -L2
  87 [ #I #K2 #W #H destruct
  88 | #J #L1 #L2 #V #HL12 #I #K2 #W #H destruct /3 width=3 by ex2_intro, or_introl/
  89 | #L1 #L2 #V1 #W2 #A #HV1 #H1W2 #H2W2 #HL12 #I #K2 #W #H destruct /3 width=8 by ex6_3_intro, or_intror/
  90 ]
  91 qed-.
  92
  93 (* Basic_1: was just: csubc_gen_head_l *)
  94 lemma lsubc_inv_pair2: ∀RP,I,G,L1,K2,W. G ⊢ L1 ⫃[RP] K2.ⓑ{I} W →
  95                        (∃∃K1. G ⊢ K1 ⫃[RP] K2 & L1 = K1.ⓑ{I} W) ∨
  96                        ∃∃K1,V,A. ⦃G, K1, V⦄ ϵ[RP] 〚A〛 & ⦃G, K1, W⦄ ϵ[RP] 〚A〛 & ⦃G, K2⦄ ⊢ W ⁝ A &
  97                                  G ⊢ K1 ⫃[RP] K2 &
  98                                  L1 = K1.ⓓⓝW.V & I = Abst.
  99 /2 width=3 by lsubc_inv_pair2_aux/ qed-.
 100
 101 (* Basic forward lemmas *****************************************************)
 102
 103 lemma lsubc_fwd_lsubr: ∀RP,G,L1,L2. G ⊢ L1 ⫃[RP] L2 → L1 ⫃ L2.
 104 #RP #G #L1 #L2 #H elim H -L1 -L2 /2 width=1 by lsubr_pair, lsubr_beta/
 105 qed-.
 106
 107 (* Basic properties *********************************************************)
 108
 109 (* Basic_1: was just: csubc_refl *)
 110 lemma lsubc_refl: ∀RP,G,L. G ⊢ L ⫃[RP] L.
 111 #RP #G #L elim L -L /2 width=1 by lsubc_pair/
 112 qed.
 113
 114 (* Basic_1: removed theorems 3:
 115             csubc_clear_conf csubc_getl_conf csubc_csuba
 116 *)