matita/matita/contribs/lambdadelta/basic_2A/dynamic/lsubsv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_7_3.ma".
  16 include "ground_2/xoa/ex_8_4.ma".
  17 include "basic_2A/notation/relations/lrsubeqv_5.ma".
  18 include "basic_2A/dynamic/shnv.ma".
  19
  20 (* LOCAL ENVIRONMENT REFINEMENT FOR STRATIFIED NATIVE VALIDITY **************)
  21
  22 (* Note: this is not transitive *)
  23 inductive lsubsv (h) (g) (G): relation lenv ≝
  24 | lsubsv_atom: lsubsv h g G (⋆) (⋆)
  25 | lsubsv_pair: ∀I,L1,L2,V. lsubsv h g G L1 L2 →
  26                lsubsv h g G (L1.ⓑ{I}V) (L2.ⓑ{I}V)
  27 | lsubsv_beta: ∀L1,L2,W,V,d1. ⦃G, L1⦄ ⊢ ⓝW.V ¡[h, g, d1] → ⦃G, L2⦄ ⊢ W ¡[h, g] →
  28                ⦃G, L1⦄ ⊢ V ▪[h, g] d1+1 → ⦃G, L2⦄ ⊢ W ▪[h, g] d1 →
  29                lsubsv h g G L1 L2 → lsubsv h g G (L1.ⓓⓝW.V) (L2.ⓛW)
  30 .
  31
  32 interpretation
  33   "local environment refinement (stratified native validity)"
  34   'LRSubEqV h g G L1 L2 = (lsubsv h g G L1 L2).
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 fact lsubsv_inv_atom1_aux: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 → L1 = ⋆ → L2 = ⋆.
  39 #h #g #G #L1 #L2 * -L1 -L2
  40 [ //
  41 | #I #L1 #L2 #V #_ #H destruct
  42 | #L1 #L2 #W #V #d1 #_ #_ #_ #_ #_ #H destruct
  43 ]
  44 qed-.
  45
  46 lemma lsubsv_inv_atom1: ∀h,g,G,L2. G ⊢ ⋆ ⫃¡[h, g] L2 → L2 = ⋆.
  47 /2 width=6 by lsubsv_inv_atom1_aux/ qed-.
  48
  49 fact lsubsv_inv_pair1_aux: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 →
  50                            ∀I,K1,X. L1 = K1.ⓑ{I}X →
  51                            (∃∃K2. G ⊢ K1 ⫃¡[h, g] K2 & L2 = K2.ⓑ{I}X) ∨
  52                            ∃∃K2,W,V,d1. ⦃G, K1⦄ ⊢ ⓝW.V ¡[h, g, d1] & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  53                                        ⦃G, K1⦄ ⊢ V ▪[h, g] d1+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] d1 &
  54                                         G ⊢ K1 ⫃¡[h, g] K2 &
  55                                         I = Abbr & L2 = K2.ⓛW & X = ⓝW.V.
  56 #h #g #G #L1 #L2 * -L1 -L2
  57 [ #J #K1 #X #H destruct
  58 | #I #L1 #L2 #V #HL12 #J #K1 #X #H destruct /3 width=3 by ex2_intro, or_introl/
  59 | #L1 #L2 #W #V #d1 #HWV #HW #HVd1 #HWd1 #HL12 #J #K1 #X #H destruct /3 width=11 by or_intror, ex8_4_intro/
  60 ]
  61 qed-.
  62
  63 lemma lsubsv_inv_pair1: ∀h,g,I,G,K1,L2,X. G ⊢ K1.ⓑ{I}X ⫃¡[h, g] L2 →
  64                         (∃∃K2. G ⊢ K1 ⫃¡[h, g] K2 & L2 = K2.ⓑ{I}X) ∨
  65                         ∃∃K2,W,V,d1. ⦃G, K1⦄ ⊢ ⓝW.V ¡[h, g, d1] & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  66                                      ⦃G, K1⦄ ⊢ V ▪[h, g] d1+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] d1 &
  67                                      G ⊢ K1 ⫃¡[h, g] K2 &
  68                                      I = Abbr & L2 = K2.ⓛW & X = ⓝW.V.
  69 /2 width=3 by lsubsv_inv_pair1_aux/ qed-.
  70
  71 fact lsubsv_inv_atom2_aux: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 → L2 = ⋆ → L1 = ⋆.
  72 #h #g #G #L1 #L2 * -L1 -L2
  73 [ //
  74 | #I #L1 #L2 #V #_ #H destruct
  75 | #L1 #L2 #W #V #d1 #_ #_ #_ #_ #_ #H destruct
  76 ]
  77 qed-.
  78
  79 lemma lsubsv_inv_atom2: ∀h,g,G,L1. G ⊢ L1 ⫃¡[h, g] ⋆ → L1 = ⋆.
  80 /2 width=6 by lsubsv_inv_atom2_aux/ qed-.
  81
  82 fact lsubsv_inv_pair2_aux: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 →
  83                            ∀I,K2,W. L2 = K2.ⓑ{I}W →
  84                            (∃∃K1. G ⊢ K1 ⫃¡[h, g] K2 & L1 = K1.ⓑ{I}W) ∨
  85                            ∃∃K1,V,d1. ⦃G, K1⦄ ⊢ ⓝW.V ¡[h, g, d1] & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  86                                       ⦃G, K1⦄ ⊢ V ▪[h, g] d1+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] d1 &
  87                                       G ⊢ K1 ⫃¡[h, g] K2 & I = Abst & L1 = K1.ⓓⓝW.V.
  88 #h #g #G #L1 #L2 * -L1 -L2
  89 [ #J #K2 #U #H destruct
  90 | #I #L1 #L2 #V #HL12 #J #K2 #U #H destruct /3 width=3 by ex2_intro, or_introl/
  91 | #L1 #L2 #W #V #d1 #HWV #HW #HVd1 #HWd1 #HL12 #J #K2 #U #H destruct /3 width=8 by or_intror, ex7_3_intro/
  92 ]
  93 qed-.
  94
  95 lemma lsubsv_inv_pair2: ∀h,g,I,G,L1,K2,W. G ⊢ L1 ⫃¡[h, g] K2.ⓑ{I}W →
  96                         (∃∃K1. G ⊢ K1 ⫃¡[h, g] K2 & L1 = K1.ⓑ{I}W) ∨
  97                         ∃∃K1,V,d1. ⦃G, K1⦄ ⊢ ⓝW.V ¡[h, g, d1] & ⦃G, K2⦄ ⊢ W ¡[h, g] &
  98                                    ⦃G, K1⦄ ⊢ V ▪[h, g] d1+1 & ⦃G, K2⦄ ⊢ W ▪[h, g] d1 &
  99                                    G ⊢ K1 ⫃¡[h, g] K2 & I = Abst & L1 = K1.ⓓⓝW.V.
 100 /2 width=3 by lsubsv_inv_pair2_aux/ qed-.
 101
 102 (* Basic forward lemmas *****************************************************)
 103
 104 lemma lsubsv_fwd_lsubr: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 → L1 ⫃ L2.
 105 #h #g #G #L1 #L2 #H elim H -L1 -L2 /2 width=1 by lsubr_pair, lsubr_beta/
 106 qed-.
 107
 108 (* Basic properties *********************************************************)
 109
 110 lemma lsubsv_refl: ∀h,g,G,L. G ⊢ L ⫃¡[h, g] L.
 111 #h #g #G #L elim L -L /2 width=1 by lsubsv_pair/
 112 qed.
 113
 114 lemma lsubsv_cprs_trans: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 →
 115                          ∀T1,T2. ⦃G, L2⦄ ⊢ T1 ➡* T2 → ⦃G, L1⦄ ⊢ T1 ➡* T2.
 116 /3 width=6 by lsubsv_fwd_lsubr, lsubr_cprs_trans/
 117 qed-.
 118
 119 (* Note: the constant 0 cannot be generalized *)
 120 lemma lsubsv_drop_O1_conf: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 →
 121                            ∀K1,s,m. ⬇[s, 0, m] L1 ≡ K1 →
 122                            ∃∃K2. G ⊢ K1 ⫃¡[h, g] K2 & ⬇[s, 0, m] L2 ≡ K2.
 123 #h #g #G #L1 #L2 #H elim H -L1 -L2
 124 [ /2 width=3 by ex2_intro/
 125 | #I #L1 #L2 #V #_ #IHL12 #K1 #s #m #H
 126   elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK1
 127   [ destruct
 128     elim (IHL12 L1 s 0) -IHL12 // #X #HL12 #H
 129     <(drop_inv_O2 … H) in HL12; -H /3 width=3 by lsubsv_pair, drop_pair, ex2_intro/
 130   | elim (IHL12 … HLK1) -L1 /3 width=3 by drop_drop_lt, ex2_intro/
 131   ]
 132 | #L1 #L2 #W #V #d1 #HWV #HW #HVd1 #HWd1 #_ #IHL12 #K1 #s #m #H
 133   elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK1
 134   [ destruct
 135     elim (IHL12 L1 s 0) -IHL12 // #X #HL12 #H
 136     <(drop_inv_O2 … H) in HL12; -H /3 width=4 by lsubsv_beta, drop_pair, ex2_intro/
 137   | elim (IHL12 … HLK1) -L1 /3 width=3 by drop_drop_lt, ex2_intro/
 138   ]
 139 ]
 140 qed-.
 141
 142 (* Note: the constant 0 cannot be generalized *)
 143 lemma lsubsv_drop_O1_trans: ∀h,g,G,L1,L2. G ⊢ L1 ⫃¡[h, g] L2 →
 144                             ∀K2,s, m. ⬇[s, 0, m] L2 ≡ K2 →
 145                             ∃∃K1. G ⊢ K1 ⫃¡[h, g] K2 & ⬇[s, 0, m] L1 ≡ K1.
 146 #h #g #G #L1 #L2 #H elim H -L1 -L2
 147 [ /2 width=3 by ex2_intro/
 148 | #I #L1 #L2 #V #_ #IHL12 #K2 #s #m #H
 149   elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK2
 150   [ destruct
 151     elim (IHL12 L2 s 0) -IHL12 // #X #HL12 #H
 152     <(drop_inv_O2 … H) in HL12; -H /3 width=3 by lsubsv_pair, drop_pair, ex2_intro/
 153   | elim (IHL12 … HLK2) -L2 /3 width=3 by drop_drop_lt, ex2_intro/
 154   ]
 155 | #L1 #L2 #W #V #d1 #HWV #HW #HVd1 #HWd1 #_ #IHL12 #K2 #s #m #H
 156   elim (drop_inv_O1_pair1 … H) -H * #Hm #HLK2
 157   [ destruct
 158     elim (IHL12 L2 s 0) -IHL12 // #X #HL12 #H
 159     <(drop_inv_O2 … H) in HL12; -H /3 width=4 by lsubsv_beta, drop_pair, ex2_intro/
 160   | elim (IHL12 … HLK2) -L2 /3 width=3 by drop_drop_lt, ex2_intro/
 161   ]
 162 ]
 163 qed-.