matita/matita/contribs/lambdadelta/basic_2A/dynamic/lsubsv_lstas.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/equivalence/scpes_cpcs.ma".
  16 include "basic_2A/dynamic/lsubsv.ma".
  17
  18 (* LOCAL ENVIRONMENT REFINEMENT FOR STRATIFIED NATIVE VALIDITY **************)
  19
  20 (* Properties on nat-iterated static type assignment ************************)
  21
  22 lemma lsubsv_lstas_trans: ∀h,g,G,L2,T,U2,d2. ⦃G, L2⦄ ⊢ T •*[h, d2] U2 →
  23                           ∀d1. d2 ≤ d1 → ⦃G, L2⦄ ⊢ T ▪[h, g] d1 →
  24                           ∀L1. G ⊢ L1 ⫃¡[h, g] L2 →
  25                           ∃∃U1. ⦃G, L1⦄ ⊢ T •*[h, d2] U1 & ⦃G, L1⦄ ⊢ U1 ⬌* U2.
  26 #h #g #G #L2 #T #U #d2 #H elim H -G -L2 -T -U -d2
  27 [ /2 width=3 by ex2_intro/
  28 | #G #L2 #K2 #V #W #U #i #d2 #HLK2 #_ #HWU #IHVW #d1 #Hd21 #Hd1 #L1 #HL12
  29   elim (da_inv_lref … Hd1) -Hd1 * #K0 #V0 [| #d0 ] #HK0 #HV0
  30   lapply (drop_mono … HK0 … HLK2) -HK0 #H destruct
  31   elim (lsubsv_drop_O1_trans … HL12 … HLK2) -L2 #Y #H #HLK1
  32   elim (lsubsv_inv_pair2 … H) -H * #K1 [ | -HWU -IHVW -HLK1 ]
  33   [ #HK12 #H destruct
  34     elim (IHVW … Hd21 HV0 … HK12) -K2 -d1 #T #HVT #HTW
  35     lapply (drop_fwd_drop2 … HLK1) #H
  36     elim (lift_total T 0 (i+1))
  37     /3 width=12 by lstas_ldef, cpcs_lift, ex2_intro/
  38   | #V0 #d0 #_ #_ #_ #_ #_ #H destruct
  39   ]
  40 | #G #L2 #K2 #V #W #i #HLK2 #_ #IHVW #d1 #_ #Hd1 #L1 #HL12
  41   elim (da_inv_lref … Hd1) -Hd1 * #K0 #V0 [| #d0 ] #HK0 #HV0 [| #H1 ]
  42   lapply (drop_mono … HK0 … HLK2) -HK0 #H2 destruct
  43   elim (lsubsv_drop_O1_trans … HL12 … HLK2) -L2 #Y #H #HLK1
  44   elim (lsubsv_inv_pair2 … H) -H * #K1
  45   [ #HK12 #H destruct
  46     elim (IHVW … HV0 … HK12) -K2 /3 width=5 by lstas_zero, ex2_intro/
  47   | #V1 #d1 #_ #_ #HV1 #HV #HK12 #_ #H destruct
  48     lapply (da_mono … HV0 … HV) -HV #H destruct
  49     elim (da_lstas … HV1 0) -HV1 #W1 #HVW1 #_
  50     elim (lift_total W1 0 (i+1)) #U1 #HWU1
  51     elim (IHVW … HV0 … HK12) -K2 // #X #HVX #_ -W
  52     @(ex2_intro … U1) /3 width=6 by lstas_cast, lstas_ldef/ (**) (* full auto too slow *)
  53     @cpcs_cprs_sn @(cprs_delta … HLK1 … HWU1)
  54     /4 width=2 by cprs_strap1, cpr_cprs, lstas_cpr, cpr_eps/
  55   ]
  56 | #G #L2 #K2 #V #W #U #i #d2 #HLK2 #_ #HWU #IHVW #d1 #Hd21 #Hd1 #L1 #HL12
  57   elim (da_inv_lref … Hd1) -Hd1 * #K0 #V0 [| #d0 ] #HK0 #HV0 [| #H1 ]
  58   lapply (drop_mono … HK0 … HLK2) -HK0 #H2 destruct
  59   lapply (le_plus_to_le_r … Hd21) -Hd21 #Hd21
  60   elim (lsubsv_drop_O1_trans … HL12 … HLK2) -L2 #Y #H #HLK1
  61   elim (lsubsv_inv_pair2 … H) -H * #K1
  62   [ #HK12 #H destruct
  63     elim (IHVW … Hd21 HV0 … HK12) -K2 -Hd21 #X
  64     lapply (drop_fwd_drop2 … HLK1)
  65     elim (lift_total X 0 (i+1))
  66     /3 width=12 by lstas_succ, cpcs_lift, ex2_intro/
  67   | #V1 #d1 #H0 #_ #HV1 #HV #HK12 #_ #H destruct
  68     lapply (da_mono … HV0 … HV) -HV #H destruct
  69     elim (shnv_inv_cast … H0) -H0 #_ #_ #H
  70     lapply (H … Hd21) -H #HVV1
  71     elim (IHVW … Hd21 HV0 … HK12) -K2 -Hd21 #X #HVX #HXW
  72     elim (da_lstas … HV1 (d2+1)) -HV1 #X1 #HVX1 #_
  73     lapply (scpes_inv_lstas_eq … HVV1 … HVX … HVX1) -HVV1 -HVX #HXX1
  74     lapply (cpcs_canc_sn … HXX1 … HXW) -X
  75     elim (lift_total X1 0 (i+1))
  76     lapply (drop_fwd_drop2 … HLK1)
  77     /4 width=12 by cpcs_lift, lstas_cast, lstas_ldef, ex2_intro/
  78   ]
  79 | #a #I #G #L2 #V2 #T2 #U2 #d1 #_ #IHTU2 #d2 #Hd12 #Hd2 #L1 #HL12
  80   lapply (da_inv_bind … Hd2) -Hd2 #Hd2
  81   elim (IHTU2 … Hd2 (L1.ⓑ{I}V2) …)
  82   /3 width=3 by lsubsv_pair, lstas_bind, cpcs_bind_dx, ex2_intro/
  83 | #G #L2 #V2 #T2 #U2 #d1 #_ #IHTU2 #d2 #Hd12 #Hd2 #L1 #HL12
  84   lapply (da_inv_flat … Hd2) -Hd2 #Hd2
  85   elim (IHTU2 … Hd2 … HL12) -L2
  86   /3 width=5 by lstas_appl, cpcs_flat, ex2_intro/
  87 | #G #L2 #W2 #T2 #U2 #d1 #_ #IHTU2 #d2 #Hd12 #Hd2 #L1 #HL12
  88   lapply (da_inv_flat … Hd2) -Hd2 #Hd2
  89   elim (IHTU2 … Hd2 … HL12) -L2
  90   /3 width=3 by lstas_cast, ex2_intro/
  91 ]
  92 qed-.
  93
  94 lemma lsubsv_sta_trans: ∀h,g,G,L2,T,U2. ⦃G, L2⦄ ⊢ T •*[h, 1] U2 →
  95                         ∀d. ⦃G, L2⦄ ⊢ T ▪[h, g] d+1 →
  96                         ∀L1. G ⊢ L1 ⫃¡[h, g] L2 →
  97                         ∃∃U1. ⦃G, L1⦄ ⊢ T •*[h, 1] U1 & ⦃G, L1⦄ ⊢ U1 ⬌* U2.
  98 /2 width=7 by lsubsv_lstas_trans/ qed-.