matita/matita/contribs/lambdadelta/basic_2A/dynamic/snv.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/nativevalid_5.ma".
  16 include "basic_2A/computation/scpds.ma".
  17
  18 (* STRATIFIED NATIVE VALIDITY FOR TERMS *************************************)
  19
  20 (* activate genv *)
  21 inductive snv (h) (g): relation3 genv lenv term ≝
  22 | snv_sort: ∀G,L,k. snv h g G L (⋆k)
  23 | snv_lref: ∀I,G,L,K,V,i. ⬇[i] L ≡ K.ⓑ{I}V → snv h g G K V → snv h g G L (#i)
  24 | snv_bind: ∀a,I,G,L,V,T. snv h g G L V → snv h g G (L.ⓑ{I}V) T → snv h g G L (ⓑ{a,I}V.T)
  25 | snv_appl: ∀a,G,L,V,W0,T,U0,d. snv h g G L V → snv h g G L T →
  26             ⦃G, L⦄ ⊢ V •*➡*[h, g, 1] W0 → ⦃G, L⦄ ⊢ T •*➡*[h, g, d] ⓛ{a}W0.U0 → snv h g G L (ⓐV.T)
  27 | snv_cast: ∀G,L,U,T,U0. snv h g G L U → snv h g G L T →
  28             ⦃G, L⦄ ⊢ U •*➡*[h, g, 0] U0 → ⦃G, L⦄ ⊢ T •*➡*[h, g, 1] U0 → snv h g G L (ⓝU.T)
  29 .
  30
  31 interpretation "stratified native validity (term)"
  32    'NativeValid h g G L T = (snv h g G L T).
  33
  34 (* Basic inversion lemmas ***************************************************)
  35
  36 fact snv_inv_lref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀i. X = #i →
  37                        ∃∃I,K,V. ⬇[i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  38 #h #g #G #L #X * -G -L -X
  39 [ #G #L #k #i #H destruct
  40 | #I #G #L #K #V #i0 #HLK #HV #i #H destruct /2 width=5 by ex2_3_intro/
  41 | #a #I #G #L #V #T #_ #_ #i #H destruct
  42 | #a #G #L #V #W0 #T #U0 #d #_ #_ #_ #_ #i #H destruct
  43 | #G #L #U #T #U0 #_ #_ #_ #_ #i #H destruct
  44 ]
  45 qed-.
  46
  47 lemma snv_inv_lref: ∀h,g,G,L,i. ⦃G, L⦄ ⊢ #i ¡[h, g] →
  48                     ∃∃I,K,V. ⬇[i] L ≡ K.ⓑ{I}V & ⦃G, K⦄ ⊢ V ¡[h, g].
  49 /2 width=3 by snv_inv_lref_aux/ qed-.
  50
  51 fact snv_inv_gref_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀p. X = §p → ⊥.
  52 #h #g #G #L #X * -G -L -X
  53 [ #G #L #k #p #H destruct
  54 | #I #G #L #K #V #i #_ #_ #p #H destruct
  55 | #a #I #G #L #V #T #_ #_ #p #H destruct
  56 | #a #G #L #V #W0 #T #U0 #d #_ #_ #_ #_ #p #H destruct
  57 | #G #L #U #T #U0 #_ #_ #_ #_ #p #H destruct
  58 ]
  59 qed-.
  60
  61 lemma snv_inv_gref: ∀h,g,G,L,p. ⦃G, L⦄ ⊢ §p ¡[h, g] → ⊥.
  62 /2 width=8 by snv_inv_gref_aux/ qed-.
  63
  64 fact snv_inv_bind_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀a,I,V,T. X = ⓑ{a,I}V.T →
  65                        ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  66 #h #g #G #L #X * -G -L -X
  67 [ #G #L #k #b #Z #X1 #X2 #H destruct
  68 | #I #G #L #K #V #i #_ #_ #b #Z #X1 #X2 #H destruct
  69 | #a #I #G #L #V #T #HV #HT #b #Z #X1 #X2 #H destruct /2 width=1 by conj/
  70 | #a #G #L #V #W0 #T #U0 #d #_ #_ #_ #_ #b #Z #X1 #X2 #H destruct
  71 | #G #L #U #T #U0 #_ #_ #_ #_ #b #Z #X1 #X2 #H destruct
  72 ]
  73 qed-.
  74
  75 lemma snv_inv_bind: ∀h,g,a,I,G,L,V,T. ⦃G, L⦄ ⊢ ⓑ{a,I}V.T ¡[h, g] →
  76                     ⦃G, L⦄ ⊢ V ¡[h, g] ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ T ¡[h, g].
  77 /2 width=4 by snv_inv_bind_aux/ qed-.
  78
  79 fact snv_inv_appl_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀V,T. X = ⓐV.T →
  80                        ∃∃a,W0,U0,d. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  81                                     ⦃G, L⦄ ⊢ V •*➡*[h, g, 1] W0 & ⦃G, L⦄ ⊢ T •*➡*[h, g, d] ⓛ{a}W0.U0.
  82 #h #g #G #L #X * -L -X
  83 [ #G #L #k #X1 #X2 #H destruct
  84 | #I #G #L #K #V #i #_ #_ #X1 #X2 #H destruct
  85 | #a #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
  86 | #a #G #L #V #W0 #T #U0 #d #HV #HT #HVW0 #HTU0 #X1 #X2 #H destruct /2 width=6 by ex4_4_intro/
  87 | #G #L #U #T #U0 #_ #_ #_ #_ #X1 #X2 #H destruct
  88 ]
  89 qed-.
  90
  91 lemma snv_inv_appl: ∀h,g,G,L,V,T. ⦃G, L⦄ ⊢ ⓐV.T ¡[h, g] →
  92                     ∃∃a,W0,U0,d. ⦃G, L⦄ ⊢ V ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  93                                  ⦃G, L⦄ ⊢ V •*➡*[h, g, 1] W0 & ⦃G, L⦄ ⊢ T •*➡*[h, g, d] ⓛ{a}W0.U0.
  94 /2 width=3 by snv_inv_appl_aux/ qed-.
  95
  96 fact snv_inv_cast_aux: ∀h,g,G,L,X. ⦃G, L⦄ ⊢ X ¡[h, g] → ∀U,T. X = ⓝU.T →
  97                        ∃∃U0. ⦃G, L⦄ ⊢ U ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
  98                              ⦃G, L⦄ ⊢ U •*➡*[h, g, 0] U0 & ⦃G, L⦄ ⊢ T •*➡*[h, g, 1] U0.
  99 #h #g #G #L #X * -G -L -X
 100 [ #G #L #k #X1 #X2 #H destruct
 101 | #I #G #L #K #V #i #_ #_ #X1 #X2 #H destruct
 102 | #a #I #G #L #V #T #_ #_ #X1 #X2 #H destruct
 103 | #a #G #L #V #W0 #T #U0 #d #_ #_ #_ #_ #X1 #X2 #H destruct
 104 | #G #L #U #T #U0 #HV #HT #HU0 #HTU0 #X1 #X2 #H destruct /2 width=3 by ex4_intro/
 105 ]
 106 qed-.
 107
 108 lemma snv_inv_cast: ∀h,g,G,L,U,T. ⦃G, L⦄ ⊢ ⓝU.T ¡[h, g] →
 109                     ∃∃U0. ⦃G, L⦄ ⊢ U ¡[h, g] & ⦃G, L⦄ ⊢ T ¡[h, g] &
 110                           ⦃G, L⦄ ⊢ U •*➡*[h, g, 0] U0 & ⦃G, L⦄ ⊢ T •*➡*[h, g, 1] U0.
 111 /2 width=3 by snv_inv_cast_aux/ qed-.