matita/matita/contribs/lambdadelta/basic_2A/equivalence/cpcs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/notation/relations/pconvstar_4.ma".
  16 include "basic_2A/conversion/cpc.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  19
  20 definition cpcs: relation4 genv lenv term term ≝
  21            λG. LTC … (cpc G).
  22
  23 interpretation "context-sensitive parallel equivalence (term)"
  24    'PConvStar G L T1 T2 = (cpcs G L T1 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma cpcs_ind: ∀G,L,T1. ∀R:predicate term. R T1 →
  29                 (∀T,T2. ⦃G, L⦄ ⊢ T1 ⬌* T → ⦃G, L⦄ ⊢ T ⬌ T2 → R T → R T2) →
  30                 ∀T2. ⦃G, L⦄ ⊢ T1 ⬌* T2 → R T2.
  31 normalize /3 width=6 by TC_star_ind/
  32 qed-.
  33
  34 lemma cpcs_ind_dx: ∀G,L,T2. ∀R:predicate term. R T2 →
  35                    (∀T1,T. ⦃G, L⦄ ⊢ T1 ⬌ T → ⦃G, L⦄ ⊢ T ⬌* T2 → R T → R T1) →
  36                    ∀T1. ⦃G, L⦄ ⊢ T1 ⬌* T2 → R T1.
  37 normalize /3 width=6 by TC_star_ind_dx/
  38 qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 (* Basic_1: was: pc3_refl *)
  43 lemma cpcs_refl: ∀G,L. reflexive … (cpcs G L).
  44 /2 width=1 by inj/ qed.
  45
  46 (* Basic_1: was: pc3_s *)
  47 lemma cpcs_sym: ∀G,L. symmetric … (cpcs G L).
  48 normalize /3 width=1 by cpc_sym, TC_symmetric/
  49 qed-.
  50
  51 lemma cpc_cpcs: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬌ T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  52 /2 width=1 by inj/ qed.
  53
  54 lemma cpcs_strap1: ∀G,L,T1,T,T2. ⦃G, L⦄ ⊢ T1 ⬌* T → ⦃G, L⦄ ⊢ T ⬌ T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  55 normalize /2 width=3 by step/
  56 qed-.
  57
  58 lemma cpcs_strap2: ∀G,L,T1,T,T2. ⦃G, L⦄ ⊢ T1 ⬌ T → ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  59 normalize /2 width=3 by TC_strap/
  60 qed-.
  61
  62 (* Basic_1: was: pc3_pr2_r *)
  63 lemma cpr_cpcs_dx: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  64 /3 width=1 by cpc_cpcs, or_introl/ qed.
  65
  66 (* Basic_1: was: pc3_pr2_x *)
  67 lemma cpr_cpcs_sn: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T2 ➡ T1 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  68 /3 width=1 by cpc_cpcs, or_intror/ qed.
  69
  70 lemma cpcs_cpr_strap1: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ⬌* T → ∀T2. ⦃G, L⦄ ⊢ T ➡ T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  71 /3 width=3 by cpcs_strap1, or_introl/ qed-.
  72
  73 (* Basic_1: was: pc3_pr2_u *)
  74 lemma cpcs_cpr_strap2: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡ T → ∀T2. ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  75 /3 width=3 by cpcs_strap2, or_introl/ qed-.
  76
  77 lemma cpcs_cpr_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ⬌* T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡ T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  78 /3 width=3 by cpcs_strap1, or_intror/ qed-.
  79
  80 lemma cpr_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡ T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡ T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  81 /3 width=3 by cpr_cpcs_dx, cpcs_strap1, or_intror/ qed-.
  82
  83 (* Basic_1: was: pc3_pr2_u2 *)
  84 lemma cpcs_cpr_conf: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T ➡ T1 → ∀T2. ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  85 /3 width=3 by cpcs_strap2, or_intror/ qed-.
  86
  87 (* Basic_1: removed theorems 9:
  88             clear_pc3_trans pc3_ind_left
  89             pc3_head_1 pc3_head_2 pc3_head_12 pc3_head_21
  90             pc3_pr2_fqubst0 pc3_pr2_fqubst0_back pc3_fqubst0
  91             pc3_gen_abst pc3_gen_abst_shift
  92 *)
  93 (* Basic_1: removed local theorems 6:
  94             pc3_left_pr3 pc3_left_trans pc3_left_sym pc3_left_pc3 pc3_pc3_left
  95             pc3_wcpr0_t_aux
  96 *)