matita/matita/contribs/lambdadelta/basic_2A/equivalence/cpcs_cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/computation/cprs.ma".
  16 include "basic_2A/equivalence/cpcs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  19
  20 (* Properties about context sensitive computation on terms ******************)
  21
  22 (* Basic_1: was: pc3_pr3_r *)
  23 lemma cpcs_cprs_dx: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  24 #G #L #T1 #T2 #H @(cprs_ind … H) -T2
  25 /3 width=3 by cpcs_cpr_strap1, cpcs_strap1, cpc_cpcs/
  26 qed.
  27
  28 (* Basic_1: was: pc3_pr3_x *)
  29 lemma cpcs_cprs_sn: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T2 ➡* T1 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  30 #G #L #T1 #T2 #H @(cprs_ind_dx … H) -T2
  31 /3 width=3 by cpcs_cpr_div, cpcs_strap1, cpcs_cprs_dx/
  32 qed.
  33
  34 lemma cpcs_cprs_strap1: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ⬌* T → ∀T2. ⦃G, L⦄ ⊢ T ➡* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  35 #G #L #T1 #T #HT1 #T2 #H @(cprs_ind … H) -T2 /2 width=3 by cpcs_cpr_strap1/
  36 qed-.
  37
  38 lemma cpcs_cprs_strap2: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡* T → ∀T2. ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  39 #G #L #T1 #T #H #T2 #HT2 @(cprs_ind_dx … H) -T1 /2 width=3 by cpcs_cpr_strap2/
  40 qed-.
  41
  42 lemma cpcs_cprs_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ⬌* T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡* T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  43 #G #L #T1 #T #HT1 #T2 #H @(cprs_ind_dx … H) -T2 /2 width=3 by cpcs_cpr_div/
  44 qed-.
  45
  46 (* Basic_1: was: pc3_pr3_conf *)
  47 lemma cpcs_cprs_conf: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T ➡* T1 → ∀T2. ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  48 #G #L #T1 #T #H #T2 #HT2 @(cprs_ind … H) -T1 /2 width=3 by cpcs_cpr_conf/
  49 qed-.
  50
  51 (* Basic_1: was: pc3_pr3_t *)
  52 (* Basic_1: note: pc3_pr3_t should be renamed *)
  53 lemma cprs_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡* T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡* T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  54 #G #L #T1 #T #HT1 #T2 #H @(cprs_ind_dx … H) -T2
  55 /2 width=3 by cpcs_cpr_div, cpcs_cprs_dx/
  56 qed.
  57
  58 lemma cprs_cpr_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡* T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡ T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  59 /3 width=5 by cpr_cprs, cprs_div/ qed-.
  60
  61 lemma cpr_cprs_div: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡ T → ∀T2. ⦃G, L⦄ ⊢ T2 ➡* T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  62 /3 width=3 by cpr_cprs, cprs_div/ qed-.