matita/matita/contribs/lambdadelta/basic_2A/equivalence/scpes_scpes.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2A/computation/scpds_scpds.ma".
  16 include "basic_2A/equivalence/scpes.ma".
  17
  18 (* STRATIFIED DECOMPOSED PARALLEL EQUIVALENCE FOR TERMS *********************)
  19
  20 (* Advanced inversion lemmas ************************************************)
  21
  22 lemma scpes_inv_abst2: ∀h,g,a,G,L,T1,T2,W2,d1,d2. ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d2] ⓛ{a}W2.T2 →
  23                        ∃∃W,T. ⦃G, L⦄ ⊢ T1 •*➡*[h, g, d1] ⓛ{a}W.T & ⦃G, L⦄ ⊢ W2 ➡* W &
  24                               ⦃G, L.ⓛW2⦄ ⊢ T2 •*➡*[h, g, d2] T.
  25 #h #g #a #G #L #T1 #T2 #W2 #d1 #d2 * #T0 #HT10 #H
  26 elim (scpds_inv_abst1 … H) -H #W #T #HW2 #HT2 #H destruct /2 width=5 by ex3_2_intro/
  27 qed-.
  28
  29 (* Advanced properties ******************************************************)
  30
  31 lemma scpes_refl: ∀h,g,G,L,T,d1,d2. d2 ≤ d1 → ⦃G, L⦄ ⊢ T ▪[h, g] d1 →
  32                   ⦃G, L⦄ ⊢ T •*⬌*[h, g, d2, d2] T.
  33 #h #g #G #L #T #d1 #d2 #Hd21 #Hd1
  34 elim (da_lstas … Hd1 … d2) #U #HTU #_
  35 /3 width=3 by scpds_div, lstas_scpds/
  36 qed.
  37
  38 lemma lstas_scpes_trans: ∀h,g,G,L,T1,d0,d1. ⦃G, L⦄ ⊢ T1 ▪[h, g] d0 → d1 ≤ d0 →
  39                          ∀T. ⦃G, L⦄ ⊢ T1 •*[h, d1] T →
  40                          ∀T2,d,d2. ⦃G, L⦄ ⊢ T •*⬌*[h,g,d,d2] T2 → ⦃G, L⦄ ⊢ T1 •*⬌*[h,g,d1+d,d2] T2.
  41 #h #g #G #L #T1 #d0 #d1 #Hd0 #Hd10 #T #HT1 #T2 #d #d2 *
  42 /3 width=3 by scpds_div, lstas_scpds_trans/ qed-.
  43
  44 (* Properties on parallel computation for terms *****************************)
  45
  46 lemma cprs_scpds_div: ∀h,g,G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡* T →
  47                       ∀d. ⦃G, L⦄ ⊢ T1 ▪[h, g] d →
  48                       ∀T2,d2. ⦃G, L⦄ ⊢ T2 •*➡*[h, g, d2] T →
  49                       ⦃G, L⦄⊢ T1 •*⬌*[h, g, 0, d2] T2.
  50 #h #g #G #L #T1 #T #HT1 #d #Hd elim (da_lstas … Hd 0)
  51 #X1 #HTX1 #_ elim (cprs_strip … HT1 X1) -HT1
  52 /3 width=5 by scpds_strap1, scpds_div, lstas_cpr, ex4_2_intro/
  53 qed.
  54
  55 (* Main properties **********************************************************)
  56
  57 theorem scpes_trans: ∀h,g,G,L,T1,T,d1,d. ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d] T →
  58                      ∀T2,d2. ⦃G, L⦄ ⊢ T •*⬌*[h, g, d, d2] T2 → ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d2] T2.
  59 #h #g #G #L #T1 #T #d1 #d * #X1 #HT1X1 #HTX1 #T2 #d2 * #X2 #HTX2 #HT2X2
  60 elim (scpds_conf_eq … HTX1 … HTX2) -T -d /3 width=5 by scpds_cprs_trans, scpds_div/
  61 qed-.
  62
  63 theorem scpes_canc_sn: ∀h,g,G,L,T,T1,d,d1. ⦃G, L⦄ ⊢ T •*⬌*[h, g, d, d1] T1 →
  64                        ∀T2,d2. ⦃G, L⦄ ⊢ T •*⬌*[h, g, d, d2] T2 → ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d2] T2.
  65 /3 width=4 by scpes_trans, scpes_sym/ qed-.
  66
  67 theorem scpes_canc_dx: ∀h,g,G,L,T1,T,d1,d. ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d] T →
  68                        ∀T2,d2. ⦃G, L⦄ ⊢ T2 •*⬌*[h, g, d2, d] T → ⦃G, L⦄ ⊢ T1 •*⬌*[h, g, d1, d2] T2.
  69 /3 width=4 by scpes_trans, scpes_sym/ qed-.