matita/matita/contribs/lambdadelta/basic_2A/etc/cpr/dxprs_ltpss_dx.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unwind/sstas_ltpss_dx.ma".
  16 include "basic_2/computation/cprs_ltpss_dx.ma".
  17 include "basic_2/computation/dxprs.ma".
  18
  19 (* DECOMPOSED EXTENDED PARALLEL COMPUTATION ON TERMS ************************)
  20
  21 (* Properties about dx parallel unfold **************************************)
  22
  23 lemma dxprs_ltpss_dx_conf: ∀h,g,L1,T,U1. ⦃h, L1⦄ ⊢ T •*➡*[g] U1 →
  24                            ∀L2,d,e. L1 ▶* [d, e] L2 →
  25                            ∃∃U2. ⦃h, L2⦄ ⊢ T •*➡*[g] U2 & L2 ⊢ U1 ▶* [d, e] U2.
  26 #h #g #L1 #T #U1 * #U #HTU #HU1 #L2 #d #e #HL12
  27 elim (sstas_ltpss_dx_conf … HTU … HL12) -HTU #U0 #HTU0 #HU0
  28 elim (cprs_ltpss_dx_conf … HU1 … HL12) -L1 #U2 #HU2 #HU12
  29 elim (cprs_tpss_conf … HU2 … HU0) -U #U #HU2 #HU0
  30 lapply (tpss_trans_eq … HU12 HU2) -U2 /3 width=3/
  31 qed-.
  32
  33 lemma dxprs_tpss_conf: ∀h,g,L,T1,U1. ⦃h, L⦄ ⊢ T1 •*➡*[g] U1 →
  34                        ∀T2,d,e. L ⊢ T1 ▶* [d, e] T2 →
  35                        ∃∃U2. ⦃h, L⦄ ⊢ T2 •*➡*[g] U2 & L ⊢ U1 ▶* [d, e] U2.
  36 #h #g #L #T1 #U1 * #W1 #HTW1 #HWU1 #T2 #d #e #HT12
  37 elim (sstas_tpss_conf … HTW1 … HT12) -T1 #W2 #HTW2 #HW12
  38 elim (cprs_tpss_conf … HWU1 … HW12) -W1 /3 width=3/
  39 qed-.
  40
  41 lemma dxprs_ltpss_dx_tpss_conf: ∀h,g,L1,T1,U1. ⦃h, L1⦄ ⊢ T1 •*➡*[g] U1 →
  42                                 ∀L2,d,e. L1 ▶* [d, e] L2 →
  43                                 ∀T2. L2 ⊢ T1 ▶* [d, e] T2 →
  44                                 ∃∃U2. ⦃h, L2⦄ ⊢ T2 •*➡*[g] U2 &
  45                                       L2 ⊢ U1 ▶* [d, e] U2.
  46 #h #g #L1 #T1 #U1 #HTU1 #L2 #d #e #HL12 #T2 #HT12
  47 elim (dxprs_ltpss_dx_conf … HTU1 … HL12) -L1 #U #HT1U #HU1
  48 elim (dxprs_tpss_conf … HT1U … HT12) -T1 #U2 #HTU2 #HU2
  49 lapply (tpss_trans_eq … HU1 HU2) -U /2 width=3/
  50 qed-.