matita/matita/contribs/lambdadelta/basic_2A/etc/cpr/ldrop_lpx.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_px.ma".
  16 include "basic_2/relocation/ldrop.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Properties on pointwise extension ****************************************)
  21
  22 lemma lpx_deliftable_dropable: ∀R. t_deliftable_sn R → dropable_sn (lpx R).
  23 #R #HR #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  24 [ #d #e #X #H >(lpx_inv_atom1 … H) -H /2 width=3/
  25 | #K1 #I #V1 #X #H
  26   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct /3 width=5/
  27 | #L1 #K1 #I #V1 #e #_ #IHLK1 #X #H
  28   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  29   elim (IHLK1 … HL12) -L1 /3 width=3/
  30 | #L1 #K1 #I #V1 #W1 #d #e #_ #HWV1 #IHLK1 #X #H
  31   elim (lpx_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  32   elim (HR … HV12 … HWV1) -V1
  33   elim (IHLK1 … HL12) -L1 /3 width=5/
  34 ]
  35 qed.
  36
  37 lemma lpx_liftable_dedropable: ∀R. reflexive ? R →
  38                                t_liftable R → dedropable_sn (lpx R).
  39 #R #H1R #H2R #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  40 [ #d #e #X #H >(lpx_inv_atom1 … H) -H /2 width=3/
  41 | #K1 #I #V1 #X #H
  42   elim (lpx_inv_pair1 … H) -H #K2 #V2 #HK12 #HV12 #H destruct /3 width=5/
  43 | #L1 #K1 #I #V1 #e #_ #IHLK1 #K2 #HK12
  44   elim (IHLK1 … HK12) -K1 /3 width=5/
  45 | #L1 #K1 #I #V1 #W1 #d #e #_ #HWV1 #IHLK1 #X #H
  46   elim (lpx_inv_pair1 … H) -H #K2 #W2 #HK12 #HW12 #H destruct
  47   elim (lift_total W2 d e) #V2 #HWV2
  48   lapply (H2R … HW12 … HWV1 … HWV2) -W1
  49   elim (IHLK1 … HK12) -K1 /3 width=5/
  50 ]
  51 qed.
  52
  53 fact lpx_dropable_aux: ∀R,L2,K2,d,e. ⇩[d, e] L2 ≡ K2 → ∀L1. lpx R L1 L2 →
  54                        d = 0 → ∃∃K1. ⇩[0, e] L1 ≡ K1 & lpx R K1 K2.
  55 #R #L2 #K2 #d #e #H elim H -L2 -K2 -d -e
  56 [ #d #e #X #H >(lpx_inv_atom2 … H) -H /2 width=3/
  57 | #K2 #I #V2 #X #H
  58   elim (lpx_inv_pair2 … H) -H #K1 #V1 #HK12 #HV12 #H destruct /3 width=5/
  59 | #L2 #K2 #I #V2 #e #_ #IHLK2 #X #H #_
  60   elim (lpx_inv_pair2 … H) -H #L1 #V1 #HL12 #HV12 #H destruct
  61   elim (IHLK2 … HL12 ?) -L2 // /3 width=3/
  62 | #L2 #K2 #I #V2 #W2 #d #e #_ #_ #_ #L1 #_
  63   >commutative_plus normalize #H destruct
  64 ]
  65 qed-.
  66
  67 lemma lpx_dropable: ∀R. dropable_dx (lpx R).
  68 /2 width=5 by lpx_dropable_aux/ qed.