matita/matita/contribs/lambdadelta/basic_2A/etc/cpr/ltpr_tpss.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/ltpss_dx_ltpss_dx.ma".
  16 include "basic_2/reducibility/ltpr_tps.ma".
  17
  18 (* CONTEXT-FREE PARALLEL REDUCTION ON LOCAL ENVIRONMENTS ********************)
  19
  20 (* Properties on partial unfold for terms ***********************************)
  21
  22 (* Basic_1: was: pr0_subst1 *)
  23 lemma ltpr_tpr_tps_conf: ∀T1,T2. T1 ➡ T2 →
  24                          ∀L1,d,e,U1. L1 ⊢ T1 ▶ [d, e] U1 →
  25                          ∀L2. L1 ➡ L2 →
  26                          ∃∃U2. U1 ➡ U2 & L2 ⊢ T2 ▶* [d, e] U2.
  27 #T1 #T2 #H elim H -T1 -T2
  28 [ #I #L1 #d #e #U1 #H #L2 #HL12
  29   elim (ltpr_tps_conf … H … HL12) -L1 /3 width=3/
  30 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #d #e #X #H #L2 #HL12
  31   elim (tps_inv_flat1 … H) -H #W1 #U1 #HVW1 #HTU1 #H destruct
  32   elim (IHV12 … HVW1 … HL12) -V1
  33   elim (IHT12 … HTU1 … HL12) -T1 -HL12 /3 width=5/
  34 | #a #V1 #V2 #W #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #d #e #X #H #L2 #HL12
  35   elim (tps_inv_flat1 … H) -H #VV1 #Y #HVV1 #HY #HX destruct
  36   elim (tps_inv_bind1 … HY) -HY #WW #TT1 #_ #HTT1 #H destruct
  37   elim (IHV12 … HVV1 … HL12) -V1 #VV2 #HVV12 #HVV2
  38   elim (IHT12 … HTT1 (L2. ⓛWW) ?) -T1 /2 width=1/ -HL12 #TT2 #HTT12 #HTT2
  39   lapply (tpss_lsubr_trans … HTT2 (L2. ⓓVV2) ?) -HTT2 /3 width=5/
  40 | #a #I #V1 #V2 #T1 #T #T2 #HV12 #_ #HT2 #IHV12 #IHT1 #L1 #d #e #X #H #L2 #HL12
  41   elim (tps_inv_bind1 … H) -H #W1 #U1 #HVW1 #HTU1 #H destruct
  42   elim (IHV12 … HVW1 … HL12) -V1 #W2 #HW12 #HVW2
  43   elim (IHT1 … HTU1 (L2. ⓑ{I} W2) ?) -T1 /2 width=1/ -HL12 #U #HU1 #HTU
  44   elim (tpss_strip_neq … HTU … HT2 ?) -T /2 width=1/ #U2 #HU2 #HTU2
  45   lapply (tps_lsubr_trans … HU2 (L2. ⓑ{I} V2) ?) -HU2 /2 width=1/ #HU2
  46   elim (ltpss_dx_tps_conf … HU2 (L2. ⓑ{I} W2) (d + 1) e ?) -HU2 /2 width=1/ #U3 #HU3 #HU23
  47   lapply (tps_lsubr_trans … HU3 (⋆. ⓑ{I} W2) ?) -HU3 /2 width=1/ #HU3
  48   lapply (tpss_lsubr_trans … HU23 (L2. ⓑ{I} W2) ?) -HU23 /2 width=1/ #HU23
  49   lapply (tpss_trans_eq … HTU2 … HU23) -U2 /3 width=5/
  50 | #a #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #L1 #d #e #X #H #L2 #HL12
  51   elim (tps_inv_flat1 … H) -H #VV1 #Y #HVV1 #HY #HX destruct
  52   elim (tps_inv_bind1 … HY) -HY #WW1 #TT1 #HWW1 #HTT1 #H destruct
  53   elim (IHV12 … HVV1 … HL12) -V1 #VV2 #HVV12 #HVV2
  54   elim (IHW12 … HWW1 … HL12) -W1 #WW2 #HWW12 #HWW2
  55   elim (IHT12 … HTT1 (L2. ⓓWW2) ?) -T1 /2 width=1/ -HL12 #TT2 #HTT12 #HTT2
  56   elim (lift_total VV2 0 1) #VV #H2VV
  57   lapply (tpss_lift_ge … HVV2 (L2. ⓓWW2) … HV2 … H2VV) -V2 /2 width=1/ #HVV
  58   @ex2_intro [2: @tpr_theta |1: skip |3: @tpss_bind [2: @tpss_flat ] ] /width=11/ (**) (* /4 width=11/ is too slow *)
  59 | #V #T1 #T #T2 #_ #HT2 #IHT1 #L1 #d #e #X #H #L2 #HL12
  60   elim (tps_inv_bind1 … H) -H #W #U1 #_ #HTU1 #H destruct -V
  61   elim (IHT1 … HTU1 (L2.ⓓW) ?) -T1 /2 width=1/ -HL12 #U #HU1 #HTU
  62   elim (tpss_inv_lift1_ge … HTU L2 … HT2 ?) -T <minus_plus_m_m /3 width=3/
  63 | #V1 #T1 #T2 #_ #IHT12 #L1 #d #e #X #H #L2 #HL12
  64   elim (tps_inv_flat1 … H) -H #VV1 #TT1 #HVV1 #HTT1 #H destruct
  65   elim (IHT12 … HTT1 … HL12) -T1 -HL12 /3 width=3/
  66 ]
  67 qed-.
  68
  69 lemma tpr_tps_conf_bind: ∀I,V1,V2,T1,T2,U1. V1 ➡ V2 → T1 ➡ T2 →
  70                          ⋆. ⓑ{I} V1 ⊢ T1 ▶ [0, 1] U1 →
  71                          ∃∃U2. U1 ➡ U2 & ⋆. ⓑ{I} V2 ⊢ T2 ▶ [0, 1] U2.
  72 #I #V1 #V2 #T1 #T2 #U1 #HV12 #HT12 #HTU1
  73 elim (ltpr_tpr_tps_conf … HT12 … HTU1 (⋆. ⓑ{I} V2) ?) -T1 /2 width=1/ -V1 #U2 #HU12 #HTU2
  74 lapply (tpss_inv_SO2 … HTU2) -HTU2 /2 width=3/
  75 qed-.
  76
  77 lemma ltpr_tpr_tpss_conf: ∀L1,L2. L1 ➡ L2 → ∀T1,T2. T1 ➡ T2 →
  78                           ∀d,e,U1. L1 ⊢ T1 ▶* [d, e] U1 →
  79                           ∃∃U2. U1 ➡ U2 & L2 ⊢ T2 ▶* [d, e] U2.
  80 #L1 #L2 #HL12 #T1 #T2 #HT12 #d #e #U1 #HTU1 @(tpss_ind … HTU1) -U1
  81 [ /2 width=3/
  82 | -HT12 #U #U1 #_ #HU1 * #T #HUT #HT2
  83   elim (ltpr_tpr_tps_conf … HUT … HU1 … HL12) -U -HL12 #U2 #HU12 #HTU2
  84   lapply (tpss_trans_eq … HT2 … HTU2) -T /2 width=3/
  85 ]
  86 qed-.
  87
  88 lemma tpr_tpss_conf: ∀T1,T2. T1 ➡ T2 →
  89                      ∀L,U1,d,e. L ⊢ T1 ▶* [d, e] U1 →
  90                      ∃∃U2. U1 ➡ U2 & L ⊢ T2 ▶* [d, e] U2.
  91 /2 width=5 by ltpr_tpr_tpss_conf/ qed-.