matita/matita/contribs/lambdadelta/basic_2A/etc/cpr/ltpss_dx.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 notation "hvbox( T1 break ▶ * [ term 46 d , break term 46 e ] break term 46 T2 )"
  16    non associative with precedence 45
  17    for @{ 'PSubstStar $T1 $d $e $T2 }.
  18
  19 include "basic_2/unfold/tpss.ma".
  20
  21 (* DX PARALLEL UNFOLD ON LOCAL ENVIRONMENTS *********************************)
  22
  23 (* Basic_1: includes: csubst1_bind *)
  24 inductive ltpss_dx: nat → nat → relation lenv ≝
  25 | ltpss_dx_atom : ∀d,e. ltpss_dx d e (⋆) (⋆)
  26 | ltpss_dx_pair : ∀L,I,V. ltpss_dx 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  27 | ltpss_dx_tpss2: ∀L1,L2,I,V1,V2,e.
  28                   ltpss_dx 0 e L1 L2 → L2 ⊢ V1 ▶* [0, e] V2 →
  29                   ltpss_dx 0 (e + 1) (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  30 | ltpss_dx_tpss1: ∀L1,L2,I,V1,V2,d,e.
  31                   ltpss_dx d e L1 L2 → L2 ⊢ V1 ▶* [d, e] V2 →
  32                   ltpss_dx (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  33 .
  34
  35 interpretation "parallel unfold (local environment, dx variant)"
  36    'PSubstStar L1 d e L2 = (ltpss_dx d e L1 L2).
  37
  38 (* Basic inversion lemmas ***************************************************)
  39
  40 fact ltpss_dx_inv_refl_O2_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → e = 0 → L1 = L2.
  41 #d #e #L1 #L2 #H elim H -d -e -L1 -L2 //
  42 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ >commutative_plus normalize #H destruct
  43 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct
  44   >(IHL12 ?) -IHL12 // >(tpss_inv_refl_O2 … HV12) //
  45 ]
  46 qed.
  47
  48 lemma ltpss_dx_inv_refl_O2: ∀d,L1,L2. L1 ▶* [d, 0] L2 → L1 = L2.
  49 /2 width=4/ qed-.
  50
  51 fact ltpss_dx_inv_atom1_aux: ∀d,e,L1,L2.
  52                              L1 ▶* [d, e] L2 → L1 = ⋆ → L2 = ⋆.
  53 #d #e #L1 #L2 * -d -e -L1 -L2
  54 [ //
  55 | #L #I #V #H destruct
  56 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
  57 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  58 ]
  59 qed.
  60
  61 lemma ltpss_dx_inv_atom1: ∀d,e,L2. ⋆ ▶* [d, e] L2 → L2 = ⋆.
  62 /2 width=5/ qed-.
  63
  64 fact ltpss_dx_inv_tpss21_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → d = 0 → 0 < e →
  65                               ∀K1,I,V1. L1 = K1. ⓑ{I} V1 →
  66                               ∃∃K2,V2. K1 ▶* [0, e - 1] K2 &
  67                                        K2 ⊢ V1 ▶* [0, e - 1] V2 &
  68                                        L2 = K2. ⓑ{I} V2.
  69 #d #e #L1 #L2 * -d -e -L1 -L2
  70 [ #d #e #_ #_ #K1 #I #V1 #H destruct
  71 | #L1 #I #V #_ #H elim (lt_refl_false … H)
  72 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct /2 width=5/
  73 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  74 ]
  75 qed.
  76
  77 lemma ltpss_dx_inv_tpss21: ∀e,K1,I,V1,L2. K1. ⓑ{I} V1 ▶* [0, e] L2 → 0 < e →
  78                            ∃∃K2,V2. K1 ▶* [0, e - 1] K2 &
  79                                     K2 ⊢ V1 ▶* [0, e - 1] V2 &
  80                                     L2 = K2. ⓑ{I} V2.
  81 /2 width=5/ qed-.
  82
  83 fact ltpss_dx_inv_tpss11_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → 0 < d →
  84                               ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
  85                               ∃∃K2,V2. K1 ▶* [d - 1, e] K2 &
  86                                        K2 ⊢ V1 ▶* [d - 1, e] V2 &
  87                                        L2 = K2. ⓑ{I} V2.
  88 #d #e #L1 #L2 * -d -e -L1 -L2
  89 [ #d #e #_ #I #K1 #V1 #H destruct
  90 | #L #I #V #H elim (lt_refl_false … H)
  91 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
  92 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct /2 width=5/
  93 ]
  94 qed.
  95
  96 lemma ltpss_dx_inv_tpss11: ∀d,e,I,K1,V1,L2. K1. ⓑ{I} V1 ▶* [d, e] L2 → 0 < d →
  97                            ∃∃K2,V2. K1 ▶* [d - 1, e] K2 &
  98                                     K2 ⊢ V1 ▶* [d - 1, e] V2 &
  99                                     L2 = K2. ⓑ{I} V2.
 100 /2 width=3/ qed-.
 101
 102 fact ltpss_dx_inv_atom2_aux: ∀d,e,L1,L2.
 103                              L1 ▶* [d, e] L2 → L2 = ⋆ → L1 = ⋆.
 104 #d #e #L1 #L2 * -d -e -L1 -L2
 105 [ //
 106 | #L #I #V #H destruct
 107 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 108 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 109 ]
 110 qed.
 111
 112 lemma ltpss_dx_inv_atom2: ∀d,e,L1. L1 ▶* [d, e] ⋆ → L1 = ⋆.
 113 /2 width=5/ qed-.
 114
 115 fact ltpss_dx_inv_tpss22_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → d = 0 → 0 < e →
 116                               ∀K2,I,V2. L2 = K2. ⓑ{I} V2 →
 117                               ∃∃K1,V1. K1 ▶* [0, e - 1] K2 &
 118                                        K2 ⊢ V1 ▶* [0, e - 1] V2 &
 119                                        L1 = K1. ⓑ{I} V1.
 120 #d #e #L1 #L2 * -d -e -L1 -L2
 121 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 122 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 123 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct /2 width=5/
 124 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 125 ]
 126 qed.
 127
 128 lemma ltpss_dx_inv_tpss22: ∀e,L1,K2,I,V2. L1 ▶* [0, e] K2. ⓑ{I} V2 → 0 < e →
 129                            ∃∃K1,V1. K1 ▶* [0, e - 1] K2 &
 130                                     K2 ⊢ V1 ▶* [0, e - 1] V2 &
 131                                     L1 = K1. ⓑ{I} V1.
 132 /2 width=5/ qed-.
 133
 134 fact ltpss_dx_inv_tpss12_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → 0 < d →
 135                               ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 136                               ∃∃K1,V1. K1 ▶* [d - 1, e] K2 &
 137                                        K2 ⊢ V1 ▶* [d - 1, e] V2 &
 138                                        L1 = K1. ⓑ{I} V1.
 139 #d #e #L1 #L2 * -d -e -L1 -L2
 140 [ #d #e #_ #I #K2 #V2 #H destruct
 141 | #L #I #V #H elim (lt_refl_false … H)
 142 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 143 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct /2 width=5/
 144 ]
 145 qed.
 146
 147 lemma ltpss_dx_inv_tpss12: ∀L1,K2,I,V2,d,e. L1 ▶* [d, e] K2. ⓑ{I} V2 → 0 < d →
 148                            ∃∃K1,V1. K1 ▶* [d - 1, e] K2 &
 149                                     K2 ⊢ V1 ▶* [d - 1, e] V2 &
 150                                     L1 = K1. ⓑ{I} V1.
 151 /2 width=3/ qed-.
 152
 153 (* Basic properties *********************************************************)
 154
 155 lemma ltpss_dx_tps2: ∀L1,L2,I,V1,V2,e.
 156                      L1 ▶* [0, e] L2 → L2 ⊢ V1 ▶ [0, e] V2 →
 157                      L1. ⓑ{I} V1 ▶* [0, e + 1] L2. ⓑ{I} V2.
 158 /3 width=1/ qed.
 159
 160 lemma ltpss_dx_tps1: ∀L1,L2,I,V1,V2,d,e.
 161                      L1 ▶* [d, e] L2 → L2 ⊢ V1 ▶ [d, e] V2 →
 162                      L1. ⓑ{I} V1 ▶* [d + 1, e] L2. ⓑ{I} V2.
 163 /3 width=1/ qed.
 164
 165 lemma ltpss_dx_tpss2_lt: ∀L1,L2,I,V1,V2,e.
 166                          L1 ▶* [0, e - 1] L2 → L2 ⊢ V1 ▶* [0, e - 1] V2 →
 167                          0 < e → L1. ⓑ{I} V1 ▶* [0, e] L2. ⓑ{I} V2.
 168 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
 169 >(plus_minus_m_m e 1) /2 width=1/
 170 qed.
 171
 172 lemma ltpss_dx_tpss1_lt: ∀L1,L2,I,V1,V2,d,e.
 173                          L1 ▶* [d - 1, e] L2 → L2 ⊢ V1 ▶* [d - 1, e] V2 →
 174                          0 < d → L1. ⓑ{I} V1 ▶* [d, e] L2. ⓑ{I} V2.
 175 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
 176 >(plus_minus_m_m d 1) /2 width=1/
 177 qed.
 178
 179 lemma ltpss_dx_tps2_lt: ∀L1,L2,I,V1,V2,e.
 180                         L1 ▶* [0, e - 1] L2 → L2 ⊢ V1 ▶ [0, e - 1] V2 →
 181                         0 < e → L1. ⓑ{I} V1 ▶* [0, e] L2. ⓑ{I} V2.
 182 /3 width=1/ qed.
 183
 184 lemma ltpss_dx_tps1_lt: ∀L1,L2,I,V1,V2,d,e.
 185                         L1 ▶* [d - 1, e] L2 → L2 ⊢ V1 ▶ [d - 1, e] V2 →
 186                         0 < d → L1. ⓑ{I} V1 ▶* [d, e] L2. ⓑ{I} V2.
 187 /3 width=1/ qed.
 188
 189 (* Basic_1: was by definition: csubst1_refl *)
 190 lemma ltpss_dx_refl: ∀L,d,e. L ▶* [d, e] L.
 191 #L elim L -L //
 192 #L #I #V #IHL * /2 width=1/ * /2 width=1/
 193 qed.
 194
 195 lemma ltpss_dx_weak: ∀L1,L2,d1,e1. L1 ▶* [d1, e1] L2 →
 196                      ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 → L1 ▶* [d2, e2] L2.
 197 #L1 #L2 #d1 #e1 #H elim H -L1 -L2 -d1 -e1 //
 198 [ #L1 #L2 #I #V1 #V2 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd2 #Hde2
 199   lapply (le_n_O_to_eq … Hd2) #H destruct normalize in Hde2;
 200   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 201   lapply (le_plus_to_minus_r … Hde2) -Hde2 /3 width=5/
 202 | #L1 #L2 #I #V1 #V2 #d1 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd21 #Hde12
 203   >plus_plus_comm_23 in Hde12; #Hde12
 204   elim (le_to_or_lt_eq 0 d2 ?) // #H destruct
 205   [ lapply (le_plus_to_minus_r … Hde12) -Hde12 <plus_minus // #Hde12
 206     lapply (le_plus_to_minus … Hd21) -Hd21 #Hd21 /3 width=5/
 207   | -Hd21 normalize in Hde12;
 208     lapply (lt_to_le_to_lt 0 … Hde12) // #He2
 209     lapply (le_plus_to_minus_r … Hde12) -Hde12
 210     /3 width=5 by ltpss_dx_tpss2_lt, tpss_weak/ (**) (* /3 width=5/ used to work *)
 211   ]
 212 ]
 213 qed.
 214
 215 lemma ltpss_dx_weak_full: ∀L1,L2,d,e. L1 ▶* [d, e] L2 → L1 ▶* [0, |L2|] L2.
 216 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 217 // /3 width=2/ /3 width=3/
 218 qed.
 219
 220 fact ltpss_dx_append_le_aux: ∀K1,K2,d,x. K1 ▶* [d, x] K2 → x = |K1| - d →
 221                              ∀L1,L2,e. L1 ▶* [0, e] L2 → d ≤ |K1| →
 222                              L1 @@ K1 ▶* [d, x + e] L2 @@ K2.
 223 #K1 #K2 #d #x #H elim H -K1 -K2 -d -x
 224 [ #d #x #H1 #L1 #L2 #e #HL12 #H2 destruct
 225   lapply (le_n_O_to_eq … H2) -H2 #H destruct //
 226 | #K #I #V <minus_n_O normalize <plus_n_Sm #H destruct
 227 | #K1 #K2 #I #V1 #V2 #x #_ #HV12 <minus_n_O #IHK12 <minus_n_O #H #L1 #L2 #e #HL12 #_
 228   lapply (injective_plus_l … H) -H #H destruct >plus_plus_comm_23
 229   /4 width=5 by ltpss_dx_tpss2, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 230 | #K1 #K2 #I #V1 #V2 #d #x #_ #HV12 #IHK12 normalize <minus_le_minus_minus_comm // <minus_plus_m_m #H1 #L1 #L2 #e #HL12 #H2 destruct
 231   lapply (le_plus_to_le_r … H2) -H2 #Hd
 232   /4 width=5 by ltpss_dx_tpss1, tpss_append, tpss_weak, monotonic_le_plus_r/ (**) (* too slow without trace *)
 233 ]
 234 qed-.
 235
 236 lemma ltpss_dx_append_le: ∀K1,K2,d. K1 ▶* [d, |K1| - d] K2 →
 237                           ∀L1,L2,e. L1 ▶* [0, e] L2 → d ≤ |K1| →
 238                           L1 @@ K1 ▶* [d, |K1| - d + e] L2 @@ K2.
 239 /2 width=1 by ltpss_dx_append_le_aux/ qed.
 240
 241 lemma ltpss_dx_append_zero: ∀K1,K2. K1 ▶* [0, |K1|] K2 →
 242                             ∀L1,L2,e. L1 ▶* [0, e] L2 →
 243                             L1 @@ K1 ▶* [0, |K1| + e] L2 @@ K2.
 244 /2 width=1/ qed.
 245
 246 lemma ltpss_dx_append_ge: ∀K1,K2,d,e. K1 ▶* [d, e] K2 →
 247                           ∀L1,L2. L1 ▶* [d - |K1|, e] L2 → |K1| ≤ d →
 248                           L1 @@ K1 ▶* [d, e] L2 @@ K2.
 249 #K1 #K2 #d #e #H elim H -K1 -K2 -d -e
 250 [ #d #e #L1 #L2 <minus_n_O //
 251 | #K #I #V #L1 #L2 #_ #H
 252   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 253 | #K1 #K2 #I #V1 #V2 #e #_ #_ #_ #L1 #L2 #_ #H
 254   lapply (le_n_O_to_eq … H) -H normalize <plus_n_Sm #H destruct
 255 | #K1 #K2 #I #V1 #V2 #d #e #_ #HV12 #IHK12 #L1 #L2
 256   normalize <minus_le_minus_minus_comm // <minus_plus_m_m #HL12 #H
 257   lapply (le_plus_to_le_r … H) -H /3 width=1/
 258 ]
 259 qed.
 260
 261 (* Basic forward lemmas *****************************************************)
 262
 263 lemma ltpss_dx_fwd_length: ∀L1,L2,d,e. L1 ▶* [d, e] L2 → |L1| = |L2|.
 264 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 265 normalize //
 266 qed-.
 267
 268 (* Basic_1: removed theorems 28:
 269             csubst0_clear_O csubst0_drop_lt csubst0_drop_gt csubst0_drop_eq
 270             csubst0_clear_O_back csubst0_clear_S csubst0_clear_trans
 271             csubst0_drop_gt_back csubst0_drop_eq_back csubst0_drop_lt_back
 272             csubst0_gen_sort csubst0_gen_head csubst0_getl_ge csubst0_getl_lt
 273             csubst0_gen_S_bind_2 csubst0_getl_ge_back csubst0_getl_lt_back
 274             csubst0_snd_bind csubst0_fst_bind csubst0_both_bind
 275             csubst1_head csubst1_flat csubst1_gen_head
 276             csubst1_getl_ge csubst1_getl_lt csubst1_getl_ge_back getl_csubst1
 277             fsubst0_gen_base
 278 *)