matita/matita/contribs/lambdadelta/basic_2A/etc/fpa/fpas.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rajuststar_5.ma".
  16 include "basic_2/substitution/fpa.ma".
  17
  18 (* MULTIPLE AJUSTMENT *******************************************************)
  19
  20 definition fpas: bool → bi_relation lenv term ≝ λs. bi_TC … (fpa s).
  21
  22 interpretation
  23    "multiple ajustment (restricted closure)"
  24    'RAjustStar L1 T1 s L2 T2 = (fpas s L1 T1 L2 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma fpas_ind: ∀L1,T1,s. ∀R:relation2 …. R L1 T1 →
  29                 (∀L,L2,T,T2. ⦃L1, T1⦄ ⇳*[s] ⦃L, T⦄ → ⦃L, T⦄ ⇳[s] ⦃L2, T2⦄ → R L T → R L2 T2) →
  30                 ∀L2,T2. ⦃L1, T1⦄ ⇳*[s] ⦃L2, T2⦄ → R L2 T2.
  31 #L1 #T1 #s #R #IH1 #IH2 #L2 #T2 #H
  32 @(bi_TC_star_ind … IH1 IH2 L2 T2 H) //
  33 qed-.
  34
  35 lemma fpas_ind_dx: ∀L2,T2,s. ∀R:relation2 …. R L2 T2 →
  36                    (∀L1,L,T1,T. ⦃L1, T1⦄ ⇳[s] ⦃L, T⦄ → ⦃L, T⦄ ⇳*[s] ⦃L2, T2⦄ → R L T → R L1 T1) →
  37                    ∀L1,T1. ⦃L1, T1⦄ ⇳*[s] ⦃L2, T2⦄ → R L1 T1.
  38 #L2 #T2 #s #R #IH1 #IH2 #L1 #T1 #H
  39 @(bi_TC_star_ind_dx … IH1 IH2 L1 T1 H) //
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma fpas_refl: ∀s. bi_reflexive … (fpas s).
  45 /2 width=1 by bi_inj/ qed.
  46
  47 lemma fpas_sym: ∀s. bi_symmetric … (fpas s).
  48 /3 width=1 by fpa_sym, bi_TC_symmetric/ qed-.
  49
  50 lemma fpa_fpas: ∀L1,L2,T1,T2,s. ⦃L1, T1⦄ ⇳[s] ⦃L2, T2⦄ → ⦃L1, T1⦄ ⇳*[s] ⦃L2, T2⦄.
  51 /2 width=1 by bi_inj/ qed.
  52
  53 lemma fpas_strap1: ∀L1,L,L2,T1,T,T2,s. ⦃L1, T1⦄ ⇳*[s] ⦃L, T⦄ → ⦃L, T⦄ ⇳[s] ⦃L2, T2⦄ →
  54                    ⦃L1, T1⦄ ⇳*[s] ⦃L2, T2⦄.
  55 /2 width=4 by bi_step/ qed-.
  56
  57 lemma fpas_strap2: ∀L1,L,L2,T1,T,T2,s. ⦃L1, T1⦄ ⇳[s] ⦃L, T⦄ → ⦃L, T⦄ ⇳*[s] ⦃L2, T2⦄ →
  58                    ⦃L1, T1⦄ ⇳*[s] ⦃L2, T2⦄.
  59 /2 width=4 by bi_TC_strap/ qed-.