matita/matita/contribs/lambdadelta/basic_2A/etc/fpbc/fpbg.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazybtpredstarproper_8.ma".
  16 include "basic_2/reduction/fpbc.ma".
  17
  18 (* "QRST" PROPER PARALLEL COMPUTATION FOR CLOSURES **************************)
  19
  20 definition fpbg: ∀h. sd h → tri_relation genv lenv term ≝
  21                  λh,g. tri_TC … (fpbc h g).
  22
  23 interpretation "'qrst' proper parallel computation (closure)"
  24    'LazyBTPRedStarProper h g G1 L1 T1 G2 L2 T2 = (fpbg h g G1 L1 T1 G2 L2 T2).
  25
  26 (* Basic properties *********************************************************)
  27
  28 lemma fpbc_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻≡[h, g] ⦃G2, L2, T2⦄ →
  29                  ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  30 /2 width=1 by tri_inj/ qed.
  31
  32 lemma fpbg_strap1: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2.
  33                    ⦃G1, L1, T1⦄ >≡[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≻≡[h, g] ⦃G2, L2, T2⦄ →
  34                    ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  35 /2 width=5 by tri_step/ qed.
  36
  37 lemma fpbg_strap2: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2.
  38                    ⦃G1, L1, T1⦄ ≻≡[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ >≡[h, g] ⦃G2, L2, T2⦄ →
  39                    ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  40 /2 width=5 by tri_TC_strap/ qed.
  41
  42 lemma fpbu_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h,g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  43 /3 width=1 by fpbu_fpbc, fpbc_fpbg/ qed.
  44
  45 (* Basic eliminators ********************************************************)
  46
  47 lemma fpbg_ind: ∀h,g,G1,L1,T1. ∀R:relation3 ….
  48                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ ≻≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  49                 (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≻≡[h, g] ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  50                 ∀G2,L2,T2. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G2 L2 T2.
  51 #h #g #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  52 @(tri_TC_ind … IH1 IH2 G2 L2 T2 H)
  53 qed-.
  54
  55 lemma fpbg_ind_dx: ∀h,g,G2,L2,T2. ∀R:relation3 ….
  56                    (∀G1,L1,T1. ⦃G1, L1, T1⦄ ≻≡[h, g] ⦃G2, L2, T2⦄ → R G1 L1 T1) →
  57                    (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≻≡[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  58                    ∀G1,L1,T1. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄ → R G1 L1 T1.
  59 #h #g #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  60 @(tri_TC_ind_dx … IH1 IH2 G1 L1 T1 H)
  61 qed-.