matita/matita/contribs/lambdadelta/basic_2A/etc/fpbc/fpbg_fpbs.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/lpxs_lleq.ma".
  16 include "basic_2/computation/fpbs_lift.ma".
  17 include "basic_2/computation/fpbg_fleq.ma".
  18
  19 (* "QRST" PROPER PARALLEL COMPUTATION FOR CLOSURES **************************)
  20
  21 (* Properties on "qrst" parallel reduction on closures **********************)
  22
  23 lemma fpbg_fpb_trans: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2.
  24                       ⦃G1, L1, T1⦄ >≡[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≽[h, g] ⦃G2, L2, T2⦄ →
  25                       ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  26 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2 elim (fpb_fpbu … H2) -H2
  27 /3 width=5 by fpbg_fleq_trans, fpbg_strap1, fpbu_fpbc/
  28 qed-.
  29
  30 lemma fpb_fpbg_trans: ∀h,g,G1,G,G2,L1,L,L2,T1,T,T2.
  31                       ⦃G1, L1, T1⦄ ≽[h, g] ⦃G, L, T⦄ → ⦃G, L, T⦄ >≡[h, g] ⦃G2, L2, T2⦄ →
  32                       ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  33 #h #g #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 elim (fpb_fpbu … H1) -H1
  34 /3 width=5 by fleq_fpbg_trans, fpbg_strap2, fpbu_fpbc/
  35 qed-.
  36
  37 (* Properties on "qrst" parallel compuutation on closures *******************)
  38
  39 lemma fpbs_fpbg_trans: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G, L, T⦄ →
  40                        ∀G2,L2,T2. ⦃G, L, T⦄ >≡[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  41 #h #g #G1 #G #L1 #L #T1 #T #H @(fpbs_ind … H) -G -L -T /3 width=5 by fpb_fpbg_trans/
  42 qed-.
  43
  44 (* Note: this is used in the closure proof *)
  45 lemma fpbg_fpbs_trans: ∀h,g,G,G2,L,L2,T,T2. ⦃G, L, T⦄ ≥[h, g] ⦃G2, L2, T2⦄ →
  46                        ∀G1,L1,T1. ⦃G1, L1, T1⦄ >≡[h, g] ⦃G, L, T⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  47 #h #g #G #G2 #L #L2 #T #T2 #H @(fpbs_ind_dx … H) -G -L -T /3 width=5 by fpbg_fpb_trans/
  48 qed-.
  49
  50 lemma fpbu_fpbs_fpbg: ∀h,g,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ≻[h, g] ⦃G, L, T⦄ →
  51                       ∀G2,L2,T2. ⦃G, L, T⦄ ≥[h, g] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  52 /3 width=5 by fpbg_fpbs_trans, fpbu_fpbg/ qed.
  53
  54 (* Note: this is used in the closure proof *)
  55 lemma fqup_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  56 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim (fqup_inv_step_sn … H) -H
  57 /3 width=5 by fqus_fpbs, fpbu_fqu, fpbu_fpbs_fpbg/
  58 qed.
  59
  60 lemma cpxs_fpbg: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  61                  (T1 = T2 → ⊥) → ⦃G, L, T1⦄ >≡[h, g] ⦃G, L, T2⦄.
  62 #h #g #G #L #T1 #T2 #H #H0 elim (cpxs_neq_inv_step_sn … H … H0) -H -H0
  63 /4 width=5 by cpxs_fpbs, fpbu_cpx, fpbu_fpbs_fpbg/
  64 qed.
  65
  66 lemma lstas_fpbg: ∀h,g,G,L,T1,T2,l2. ⦃G, L⦄ ⊢ T1 •*[h, l2] T2 → (T1 = T2 → ⊥) →
  67                   ∀l1. l2 ≤ l1 → ⦃G, L⦄ ⊢ T1 ▪[h, g] l1 → ⦃G, L, T1⦄ >≡[h, g] ⦃G, L, T2⦄.
  68 /3 width=5 by lstas_cpxs, cpxs_fpbg/ qed.
  69
  70 lemma lpxs_fpbg: ∀h,g,G,L1,L2,T. ⦃G, L1⦄ ⊢ ➡*[h, g] L2 →
  71                  (L1 ≡[T, 0] L2 → ⊥) → ⦃G, L1, T⦄ >≡[h, g] ⦃G, L2, T⦄.
  72 #h #g #G #L1 #L2 #T #H #H0 elim (lpxs_nlleq_inv_step_sn … H … H0) -H -H0
  73 /4 width=5 by fpbu_fpbs_fpbg, fpbu_lpx, lpxs_lleq_fpbs/
  74 qed.
  75
  76 lemma fpbs_fpbg: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, g] ⦃G2, L2, T2⦄ →
  77                  ⦃G1, L1, T1⦄ ≡[0] ⦃G2, L2, T2⦄ ∨
  78                  ⦃G1, L1, T1⦄ >≡[h, g] ⦃G2, L2, T2⦄.
  79 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind … H) -G2 -L2 -T2
  80 [ /2 width=1 by or_introl/
  81 | #G #G2 #L #L2 #T #T2 #_ #H2 * #H1 elim (fpb_fpbu … H2) -H2 #H2
  82   [ /3 width=5 by fleq_trans, or_introl/
  83   | /5 width=5 by fpbc_fpbg, fleq_fpbc_trans, fpbu_fpbc, or_intror/
  84   | /3 width=5 by fpbg_fleq_trans, or_intror/
  85   | /4 width=5 by fpbg_strap1, fpbu_fpbc, or_intror/
  86   ]
  87 ]
  88 qed-.