matita/matita/contribs/lambdadelta/basic_2A/etc/llpr/cpcs_cpcs.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/llprs_cprs.ma".
  16 include "basic_2/conversion/cpc_cpc.ma".
  17 include "basic_2/equivalence/cpcs_cprs.ma".
  18
  19 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  20
  21 (* Advanced inversion lemmas ************************************************)
  22
  23 lemma cpcs_inv_cprs: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬌* T2 →
  24                      ∃∃T. ⦃G, L⦄ ⊢ T1 ➡* T & ⦃G, L⦄ ⊢ T2 ➡* T.
  25 #G #L #T1 #T2 #H @(cpcs_ind … H) -T2
  26 [ /3 width=3 by ex2_intro/
  27 | #T #T2 #_ #HT2 * #T0 #HT10 elim HT2 -HT2 #HT2 #HT0
  28   [ elim (cprs_strip … HT0 … HT2) -T /3 width=3 by cprs_strap1, ex2_intro/
  29   | /3 width=5 by cprs_strap2, ex2_intro/
  30   ]
  31 ]
  32 qed-.
  33
  34 (* Basic_1: was: pc3_gen_sort *)
  35 lemma cpcs_inv_sort: ∀G,L,k1,k2. ⦃G, L⦄ ⊢ ⋆k1 ⬌* ⋆k2 → k1 = k2.
  36 #G #L #k1 #k2 #H elim (cpcs_inv_cprs … H) -H
  37 #T #H1 >(cprs_inv_sort1 … H1) -T #H2
  38 lapply (cprs_inv_sort1 … H2) -L #H destruct //
  39 qed-.
  40
  41 lemma cpcs_inv_abst1: ∀a,G,L,W1,T1,T. ⦃G, L⦄ ⊢ ⓛ{a}W1.T1 ⬌* T →
  42                       ∃∃W2,T2. ⦃G, L⦄ ⊢ T ➡* ⓛ{a}W2.T2 & ⦃G, L⦄ ⊢ ⓛ{a}W1.T1 ➡* ⓛ{a}W2.T2.
  43 #a #G #L #W1 #T1 #T #H
  44 elim (cpcs_inv_cprs … H) -H #X #H1 #H2
  45 elim (cprs_inv_abst1 … H1) -H1 #W2 #T2 #HW12 #HT12 #H destruct
  46 /3 width=6 by cprs_bind, ex2_2_intro/
  47 qed-.
  48
  49 lemma cpcs_inv_abst2: ∀a,G,L,W1,T1,T. ⦃G, L⦄ ⊢ T ⬌* ⓛ{a}W1.T1 →
  50                       ∃∃W2,T2. ⦃G, L⦄ ⊢ T ➡* ⓛ{a}W2.T2 & ⦃G, L⦄ ⊢ ⓛ{a}W1.T1 ➡* ⓛ{a}W2.T2.
  51 /3 width=1 by cpcs_inv_abst1, cpcs_sym/ qed-.
  52
  53 (* Basic_1: was: pc3_gen_sort_abst *)
  54 lemma cpcs_inv_sort_abst: ∀a,G,L,W,T,k. ⦃G, L⦄ ⊢ ⋆k ⬌* ⓛ{a}W.T → ⊥.
  55 #a #G #L #W #T #k #H
  56 elim (cpcs_inv_cprs … H) -H #X #H1
  57 >(cprs_inv_sort1 … H1) -X #H2
  58 elim (cprs_inv_abst1 … H2) -H2 #W0 #T0 #_ #_ #H destruct
  59 qed-.
  60
  61 (* Basic_1: was: pc3_gen_lift *)
  62 lemma cpcs_inv_lift: ∀G,L,K,s,d,e. ⇩[s, d, e] L ≡ K →
  63                      ∀T1,U1. ⇧[d, e] T1 ≡ U1 → ∀T2,U2. ⇧[d, e] T2 ≡ U2 →
  64                      ⦃G, L⦄ ⊢ U1 ⬌* U2 → ⦃G, K⦄ ⊢ T1 ⬌* T2.
  65 #G #L #K #s #d #e #HLK #T1 #U1 #HTU1 #T2 #U2 #HTU2 #HU12
  66 elim (cpcs_inv_cprs … HU12) -HU12 #U #HU1 #HU2
  67 elim (cprs_inv_lift1 … HU1 … HLK … HTU1) -U1 #T #HTU #HT1
  68 elim (cprs_inv_lift1 … HU2 … HLK … HTU2) -L -U2 #X #HXU
  69 >(lift_inj … HXU … HTU) -X -U -d -e /2 width=3 by cprs_div/
  70 qed-.
  71
  72 (* Advanced properties ******************************************************)
  73
  74 lemma llpr_cpcs_trans: ∀G,L1,L2,T1,T2. ⦃G, L1⦄ ⊢ ➡[T1, 0] L2 → ⦃G, L1⦄ ⊢ ➡[T2, 0] L2 →
  75                        ⦃G, L2⦄ ⊢ T1 ⬌* T2 → ⦃G, L1⦄ ⊢ T1 ⬌* T2.
  76 #G #L1 #L2 #T1 #T2 #HT1 #HT2 #H elim (cpcs_inv_cprs … H) -H
  77 /4 width=5 by cprs_div, cprs_llpr_trans/
  78 qed-.
  79
  80 lemma llprs_cpcs_trans: ∀G,L1,L2,T1,T2. ⦃G, L1⦄ ⊢ ➡*[T1, 0] L2 → ⦃G, L1⦄ ⊢ ➡*[T2, 0] L2 →
  81                         ⦃G, L2⦄ ⊢ T1 ⬌* T2 → ⦃G, L1⦄ ⊢ T1 ⬌* T2.
  82 #G #L1 #L2 #T1 #T2 #HT1 #HT2 #H elim (cpcs_inv_cprs … H) -H
  83 /4 width=5 by cprs_div, llprs_cprs_trans/
  84 qed-.
  85
  86 lemma cpr_cprs_conf_cpcs: ∀G,L,T,T1,T2. ⦃G, L⦄ ⊢ T ➡* T1 → ⦃G, L⦄ ⊢ T ➡ T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  87 #G #L #T #T1 #T2 #HT1 #HT2 elim (cprs_strip … HT1 … HT2) -HT1 -HT2
  88 /2 width=3 by cpr_cprs_div/
  89 qed-.
  90
  91 lemma cprs_cpr_conf_cpcs: ∀G,L,T,T1,T2. ⦃G, L⦄ ⊢ T ➡* T1 → ⦃G, L⦄ ⊢ T ➡ T2 → ⦃G, L⦄ ⊢ T2 ⬌* T1.
  92 #G #L #T #T1 #T2 #HT1 #HT2 elim (cprs_strip … HT1 … HT2) -HT1 -HT2
  93 /2 width=3 by cprs_cpr_div/
  94 qed-.
  95
  96 lemma cprs_conf_cpcs: ∀G,L,T,T1,T2. ⦃G, L⦄ ⊢ T ➡* T1 → ⦃G, L⦄ ⊢ T ➡* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
  97 #G #L #T #T1 #T2 #HT1 #HT2 elim (cprs_conf … HT1 … HT2) -HT1 -HT2
  98 /2 width=3 by cprs_div/
  99 qed-.
 100
 101 (* Basic_1: was: pc3_wcpr0_t *)
 102 (* Basic_1: note: pc3_wcpr0_t should be renamed *)
 103 lemma llpr_cprs_conf: ∀G,L1,L2,T1. ⦃G, L1⦄ ⊢ ➡[T1, 0] L2 →
 104                       ∀T2. ⦃G, L1⦄ ⊢ T1 ➡* T2 → ⦃G, L2⦄ ⊢ T1 ⬌* T2.
 105 #G #L1 #L2 #T1 #HL12 #T2 #HT12 elim (cprs_llpr_conf_dx … HT12 … HL12) -L1
 106 /2 width=3 by cprs_div/
 107 qed-.
 108
 109 (* Basic_1: was only: pc3_pr0_pr2_t *)
 110 (* Basic_1: note: pc3_pr0_pr2_t should be renamed *)
 111 lemma llpr_cpr_conf: ∀G,L1,L2,T1. ⦃G, L1⦄ ⊢ ➡[T1, 0] L2 →
 112                      ∀T2. ⦃G, L1⦄ ⊢ T1 ➡ T2 → ⦃G, L2⦄ ⊢ T1 ⬌* T2.
 113 /3 width=5 by llpr_cprs_conf, cpr_cprs/ qed-.
 114
 115 (* Basic_1: was only: pc3_thin_dx *)
 116 lemma cpcs_flat: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬌* V2 → ∀T1,T2. ⦃G, L⦄ ⊢ T1 ⬌* T2 →
 117                  ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ⬌* ⓕ{I}V2.T2.
 118 #G #L #V1 #V2 #HV12 #T1 #T2 #HT12
 119 elim (cpcs_inv_cprs … HV12) -HV12
 120 elim (cpcs_inv_cprs … HT12) -HT12
 121 /3 width=5 by cprs_flat, cprs_div/
 122 qed.
 123
 124 lemma cpcs_flat_dx_cpr_rev: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V2 ➡ V1 → ∀T1,T2. ⦃G, L⦄ ⊢ T1 ⬌* T2 →
 125                             ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ⬌* ⓕ{I}V2.T2.
 126 /3 width=1 by cpr_cpcs_sn, cpcs_flat/ qed.
 127
 128 lemma cpcs_bind_dx: ∀a,I,G,L,V,T1,T2. ⦃G, L.ⓑ{I}V⦄ ⊢ T1 ⬌* T2 →
 129                     ⦃G, L⦄ ⊢ ⓑ{a,I}V.T1 ⬌* ⓑ{a,I}V.T2.
 130 #a #I #G #L #V #T1 #T2 #HT12 elim (cpcs_inv_cprs … HT12) -HT12
 131 /3 width=5 by cprs_div, cprs_bind/
 132 qed.
 133
 134 lemma cpcs_bind_sn: ∀a,I,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ⬌* V2 → ⦃G, L⦄ ⊢ ⓑ{a,I}V1. T ⬌* ⓑ{a,I}V2. T.
 135 #a #I #G #L #V1 #V2 #T #HV12 elim (cpcs_inv_cprs … HV12) -HV12
 136 /3 width=5 by cprs_div, cprs_bind/
 137 qed.
 138
 139 lemma lsubr_cpcs_trans: ∀G,L1,T1,T2. ⦃G, L1⦄ ⊢ T1 ⬌* T2 →
 140                         ∀L2. L2 ⊑ L1 → ⦃G, L2⦄ ⊢ T1 ⬌* T2.
 141 #G #L1 #T1 #T2 #HT12 elim (cpcs_inv_cprs … HT12) -HT12
 142 /3 width=5 by cprs_div, lsubr_cprs_trans/
 143 qed-.
 144
 145 (* Basic_1: was: pc3_lift *)
 146 lemma cpcs_lift: ∀G,L,K,s,d,e. ⇩[s, d, e] L ≡ K →
 147                  ∀T1,U1. ⇧[d, e] T1 ≡ U1 → ∀T2,U2. ⇧[d, e] T2 ≡ U2 →
 148                  ⦃G, K⦄ ⊢ T1 ⬌* T2 → ⦃G, L⦄ ⊢ U1 ⬌* U2.
 149 #G #L #K #s #d #e #HLK #T1 #U1 #HTU1 #T2 #U2 #HTU2 #HT12
 150 elim (cpcs_inv_cprs … HT12) -HT12 #T #HT1 #HT2
 151 elim (lift_total T d e) /3 width=12 by cprs_div, cprs_lift/
 152 qed.
 153
 154 lemma cpcs_strip: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T ⬌* T1 → ∀T2. ⦃G, L⦄ ⊢ T ⬌ T2 →
 155                   ∃∃T0. ⦃G, L⦄ ⊢ T1 ⬌ T0 & ⦃G, L⦄ ⊢ T2 ⬌* T0.
 156 #G #L #T1 #T @TC_strip1 /2 width=3 by cpc_conf/ qed-.
 157
 158 (* More inversion lemmas ****************************************************)
 159
 160 axiom cpcs_inv_abst_sn: ∀a1,a2,G,L,W1,W2,T1,T2. ⦃G, L⦄ ⊢ ⓛ{a1}W1.T1 ⬌* ⓛ{a2}W2.T2 →
 161                         ∧∧ ⦃G, L⦄ ⊢ W1 ⬌* W2 & ⦃G, L.ⓛW1⦄ ⊢ T1 ⬌* T2 & a1 = a2.
 162 (*
 163 #a1 #a2 #G #L #W1 #W2 #T1 #T2 #H
 164 elim (cpcs_inv_cprs … H) -H #T #H1 #H2
 165 elim (cprs_inv_abst1 … H1) -H1 #W0 #T0 #HW10 #HT10 #H destruct
 166 elim (cprs_inv_abst1 … H2) -H2 #W #T #HW2 #HT2 #H destruct
 167 lapply (llprs_cprs_conf … (L.ⓛW) … HT2) /2 width=1 by llprs_pair/ -HT2 #HT2
 168 lapply (llprs_cpcs_trans … (L.ⓛW1) … HT2) /2 width=1 by llprs_pair/ -HT2 #HT2
 169 /4 width=3 by and3_intro, cprs_div, cpcs_cprs_div, cpcs_sym/
 170 qed-.
 171 *)
 172 lemma cpcs_inv_abst_dx: ∀a1,a2,G,L,W1,W2,T1,T2. ⦃G, L⦄ ⊢ ⓛ{a1}W1.T1 ⬌* ⓛ{a2}W2.T2 →
 173                         ∧∧ ⦃G, L⦄ ⊢ W1 ⬌* W2 & ⦃G, L.ⓛW2⦄ ⊢ T1 ⬌* T2 & a1 = a2.
 174 #a1 #a2 #G #L #W1 #W2 #T1 #T2 #HT12 lapply (cpcs_sym … HT12) -HT12
 175 #HT12 elim (cpcs_inv_abst_sn … HT12) -HT12 /3 width=1 by cpcs_sym, and3_intro/
 176 qed-.
 177
 178 (* Main properties **********************************************************)
 179
 180 (* Basic_1: was pc3_t *)
 181 theorem cpcs_trans: ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ⬌* T → ∀T2. ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
 182 #G #L #T1 #T #HT1 #T2 @(trans_TC … HT1) qed-.
 183
 184 theorem cpcs_canc_sn: ∀G,L,T,T1,T2. ⦃G, L⦄ ⊢ T ⬌* T1 → ⦃G, L⦄ ⊢ T ⬌* T2 → ⦃G, L⦄ ⊢ T1 ⬌* T2.
 185 /3 width=3 by cpcs_trans, cpcs_sym/ qed-.
 186
 187 theorem cpcs_canc_dx: ∀G,L,T,T1,T2. ⦃G, L⦄ ⊢ T1 ⬌* T → ⦃G, L⦄ ⊢ T2 ⬌* T → ⦃G, L⦄ ⊢ T1 ⬌* T2.
 188 /3 width=3 by cpcs_trans, cpcs_sym/ qed-.
 189
 190 lemma cpcs_bind1: ∀a,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬌* V2 →
 191                   ∀T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬌* T2 →
 192                   ⦃G, L⦄ ⊢ ⓑ{a,I}V1. T1 ⬌* ⓑ{a,I}V2. T2.
 193 /3 width=3 by cpcs_trans, cpcs_bind_sn, cpcs_bind_dx/ qed.
 194
 195 lemma cpcs_bind2: ∀a,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬌* V2 →
 196                   ∀T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬌* T2 →
 197                   ⦃G, L⦄ ⊢ ⓑ{a,I}V1. T1 ⬌* ⓑ{a,I}V2. T2.
 198 /3 width=3 by cpcs_trans, cpcs_bind_sn, cpcs_bind_dx/ qed.
 199
 200 (* Basic_1: was: pc3_wcpr0 *)
 201 lemma llpr_cpcs_conf: ∀G,L1,L2,T1,T2. ⦃G, L1⦄ ⊢ ➡[T1, 0] L2 → ⦃G, L1⦄ ⊢ ➡[T2, 0] L2 →
 202                       ⦃G, L1⦄ ⊢ T1 ⬌* T2 → ⦃G, L2⦄ ⊢ T1 ⬌* T2.
 203 #G #L1 #L2 #T1 #T2 #HT1 #HT2 #H elim (cpcs_inv_cprs … H) -H
 204 /3 width=5 by cpcs_canc_dx, llpr_cprs_conf/
 205 qed-.